ui/meson.build

   1 softmmu_ss.add(pixman)
   2 specific_ss.add(when: ['CONFIG_SOFTMMU'], if_true: pixman)   # for the include path
   3 specific_ss.add(when: ['CONFIG_SOFTMMU'], if_true: opengl)   # for the include path
   4
   5 softmmu_ss.add(files(
   6   'clipboard.c',
   7   'console.c',
   8   'cursor.c',
   9   'input-keymap.c',
  10   'input-legacy.c',
  11   'input-barrier.c',
  12   'input.c',
  13   'kbd-state.c',
  14   'keymaps.c',
  15   'qemu-pixman.c',
  16   'util.c',
  17 ))
  18 if dbus_display
  19   softmmu_ss.add(files('dbus-module.c'))
  20 endif
  21 softmmu_ss.add([spice_headers, files('spice-module.c')])
  22 softmmu_ss.add(when: spice_protocol, if_true: files('vdagent.c'))
  23
  24 softmmu_ss.add(when: 'CONFIG_LINUX', if_true: files(
  25   'input-linux.c',
  26   'udmabuf.c',
  27 ))
  28 softmmu_ss.add(when: cocoa, if_true: files('cocoa.m'))
  29
  30 vnc_ss = ss.source_set()
  31 vnc_ss.add(files(
  32   'vnc.c',
  33   'vnc-enc-zlib.c',
  34   'vnc-enc-hextile.c',
  35   'vnc-enc-tight.c',
  36   'vnc-palette.c',
  37   'vnc-enc-zrle.c',
  38   'vnc-auth-vencrypt.c',
  39   'vnc-ws.c',
  40   'vnc-jobs.c',
  41   'vnc-clipboard.c',
  42 ))
  43 vnc_ss.add(zlib, png, jpeg, gnutls)
  44 vnc_ss.add(when: sasl, if_true: files('vnc-auth-sasl.c'))
  45 softmmu_ss.add_all(when: vnc, if_true: vnc_ss)
  46 softmmu_ss.add(when: vnc, if_false: files('vnc-stubs.c'))
  47
  48 ui_modules = {}
  49
  50 if curses.found()
  51   curses_ss = ss.source_set()
  52   curses_ss.add(when: [curses, iconv], if_true: [files('curses.c'), pixman])
  53   ui_modules += {'curses' : curses_ss}
  54 endif
  55
  56 softmmu_ss.add(opengl)
  57 if opengl.found()
  58   opengl_ss = ss.source_set()
  59   opengl_ss.add(gbm)
  60   opengl_ss.add(when: [opengl, pixman],
  61                if_true: files('shader.c', 'console-gl.c', 'egl-helpers.c', 'egl-context.c'))
  62   ui_modules += {'opengl' : opengl_ss}
  63 endif
  64
  65 if opengl.found() and gbm.found()
  66   egl_headless_ss = ss.source_set()
  67   egl_headless_ss.add(when: [opengl, gbm, pixman],
  68                       if_true: files('egl-headless.c'))
  69   ui_modules += {'egl-headless' : egl_headless_ss}
  70 endif
  71
  72 if dbus_display
  73   dbus_ss = ss.source_set()
  74   dbus_display1 = custom_target('dbus-display gdbus-codegen',
  75                                 output: ['dbus-display1.h', 'dbus-display1.c'],
  76                                 input: files('dbus-display1.xml'),
  77                                 command: [gdbus_codegen, '@INPUT@',
  78                                           '--glib-min-required', '2.64',
  79                                           '--output-directory', meson.current_build_dir(),
  80                                           '--interface-prefix', 'org.qemu.',
  81                                           '--c-namespace', 'QemuDBus',
  82                                           '--generate-c-code', '@BASENAME@'])
  83   dbus_ss.add(when: [gio, pixman, opengl],
  84               if_true: [files(
  85                 'dbus-chardev.c',
  86                 'dbus-clipboard.c',
  87                 'dbus-console.c',
  88                 'dbus-error.c',
  89                 'dbus-listener.c',
  90                 'dbus.c',
  91               ), dbus_display1])
  92   ui_modules += {'dbus' : dbus_ss}
  93 endif
  94
  95 if gtk.found()
  96   softmmu_ss.add(when: 'CONFIG_WIN32', if_true: files('win32-kbd-hook.c'))
  97
  98   gtk_ss = ss.source_set()
  99   gtk_ss.add(gtk, vte, pixman, files('gtk.c', 'gtk-clipboard.c'))
 100   gtk_ss.add(when: x11, if_true: files('x_keymap.c'))
 101   gtk_ss.add(when: opengl, if_true: files('gtk-gl-area.c'))
 102   gtk_ss.add(when: [x11, opengl], if_true: files('gtk-egl.c'))
 103   ui_modules += {'gtk' : gtk_ss}
 104 endif
 105
 106 if sdl.found()
 107   softmmu_ss.add(when: 'CONFIG_WIN32', if_true: files('win32-kbd-hook.c'))
 108
 109   sdl_ss = ss.source_set()
 110   sdl_ss.add(sdl, sdl_image, pixman, glib, files(
 111     'sdl2-2d.c',
 112     'sdl2-input.c',
 113     'sdl2.c',
 114   ))
 115   sdl_ss.add(when: opengl, if_true: files('sdl2-gl.c'))
 116   sdl_ss.add(when: x11, if_true: files('x_keymap.c'))
 117   ui_modules += {'sdl' : sdl_ss}
 118 endif
 119
 120 if spice.found()
 121   spice_core_ss = ss.source_set()
 122   spice_core_ss.add(spice, pixman, files(
 123     'spice-core.c',
 124     'spice-input.c',
 125     'spice-display.c'
 126   ))
 127   ui_modules += {'spice-core' : spice_core_ss}
 128 endif
 129
 130 if spice.found() and gio.found()
 131   spice_ss = ss.source_set()
 132   spice_ss.add(spice, gio, pixman, files('spice-app.c'))
 133   ui_modules += {'spice-app': spice_ss}
 134 endif
 135
 136 keymaps = [
 137   ['atset1', 'qcode'],
 138   ['linux', 'qcode'],
 139   ['qcode', 'atset1'],
 140   ['qcode', 'atset2'],
 141   ['qcode', 'atset3'],
 142   ['qcode', 'linux'],
 143   ['qcode', 'qnum'],
 144   ['qcode', 'sun'],
 145   ['qnum', 'qcode'],
 146   ['usb', 'qcode'],
 147   ['win32', 'qcode'],
 148   ['x11', 'qcode'],
 149   ['xorgevdev', 'qcode'],
 150   ['xorgkbd', 'qcode'],
 151   ['xorgxquartz', 'qcode'],
 152   ['xorgxwin', 'qcode'],
 153   ['osx', 'qcode'],
 154 ]
 155
 156 if have_system or xkbcommon.found()
 157   foreach e : keymaps
 158     output = 'input-keymap-@0@-to-@1@.c.inc'.format(e[0], e[1])
 159     genh += custom_target(output,
 160                   output: output,
 161                   capture: true,
 162                   input: files('keycodemapdb/data/keymaps.csv'),
 163                   command: [python, files('keycodemapdb/tools/keymap-gen'),
 164                             'code-map',
 165                             '--lang', 'glib2',
 166                             '--varname', 'qemu_input_map_@0@_to_@1@'.format(e[0], e[1]),
 167                             '@INPUT0@', e[0], e[1]])
 168   endforeach
 169 endif
 170
 171 subdir('shader')
 172
 173 if have_system
 174   subdir('icons')
 175
 176   install_data('qemu.desktop', install_dir: qemu_desktopdir)
 177 endif
 178
 179 modules += {'ui': ui_modules}