audio/meson.build

   1 softmmu_ss.add([spice_headers, files('audio.c')])
   2 softmmu_ss.add(files(
   3   'audio_legacy.c',
   4   'mixeng.c',
   5   'noaudio.c',
   6   'wavaudio.c',
   7   'wavcapture.c',
   8 ))
   9
  10 softmmu_ss.add(when: coreaudio, if_true: files('coreaudio.m'))
  11 softmmu_ss.add(when: dsound, if_true: files('dsoundaudio.c', 'audio_win_int.c'))
  12
  13 audio_modules = {}
  14 foreach m : [
  15   ['alsa', alsa, files('alsaaudio.c')],
  16   ['oss', oss, files('ossaudio.c')],
  17   ['pa', pulse, files('paaudio.c')],
  18   ['sdl', sdl, files('sdlaudio.c')],
  19   ['jack', jack, files('jackaudio.c')],
  20   ['sndio', sndio, files('sndioaudio.c')],
  21   ['spice', spice, files('spiceaudio.c')]
  22 ]
  23   if m[1].found()
  24     module_ss = ss.source_set()
  25     module_ss.add(m[1], m[2])
  26     audio_modules += {m[0] : module_ss}
  27   endif
  28 endforeach
  29
  30 if dbus_display
  31     module_ss = ss.source_set()
  32     module_ss.add(when: gio, if_true: files('dbusaudio.c'))
  33     audio_modules += {'dbus': module_ss}
  34 endif
  35
  36 modules += {'audio': audio_modules}