configure.ac

   1 # configure script for pywebkitgtk
   2
   3 m4_define([pywebkitgtk_major_version], [1])
   4 m4_define([pywebkitgtk_minor_version], [0])
   5 m4_define([pywebkitgtk_micro_version], [2])
   6
   7 m4_define([pywebkitgtk_version],
   8           [pywebkitgtk_major_version.pywebkitgtk_minor_version.pywebkitgtk_micro_version])
   9
  10 AC_INIT([pywebkitgtk],
  11         [pywebkitgtk_version],
  12         [http://code.google.com/p/pywebkitgtk/issues])
  13
  14 AC_PREREQ([2.59])
  15 AC_CONFIG_MACRO_DIR([m4])
  16 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I .")
  17
  18 AC_CONFIG_SRCDIR([configure.ac])
  19 AC_CONFIG_HEADERS([config.h])
  20
  21 AC_DEFINE_UNQUOTED(PYWEBKITGTK_VERSION, pywebkitgtk_version,
  22                    [The release version of Python WebKit Gtk+])
  23 AC_DEFINE_UNQUOTED(PYWEBKITGTK_MAJOR_VERSION, pywebkitgtk_major_version,
  24                    [The major version of Python WebKit Gtk+.])
  25 AC_DEFINE_UNQUOTED(PYWEBKITGTK_MINOR_VERSION, pywebkitgtk_minor_version,
  26                    [The minor version of Python WebKit Gtk+.])
  27 AC_DEFINE_UNQUOTED(PYWEBKITGTK_MICRO_VERSION, pywebkitgtk_micro_version,
  28                    [The micro version of Python WebKit Gtk+.])
  29
  30 AM_INIT_AUTOMAKE([foreign subdir-objects])
  31
  32 AM_PROG_CC_C_O
  33 AC_PROG_LIBTOOL
  34
  35 dnl check for python
  36 AM_PATH_PYTHON(2.4)
  37 AM_CHECK_PYTHON_HEADERS(,[AC_MSG_ERROR(could not find Python headers)])
  38 py_prefix=`$PYTHON -c "import sys; print sys.prefix"`
  39 PYTHON_INCLUDES="-I${py_prefix}/include/python${PYTHON_VERSION}"
  40
  41 dnl from pygtk: get rid of -export-dynamic stuff from the configure flags...
  42 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
  43
  44 dnl check for dependencies
  45 dnl Check for libxslt until upstream WebKit checks for it as this is a webkit
  46 dnl dep and not pywebkitgtk's.
  47 PKG_CHECK_MODULES(DEPS,
  48                   [libxslt,
  49                   pygtk-2.0,
  50                   webkit-1.0])
  51 AC_SUBST(DEPS_CFLAGS)
  52 AC_SUBST(DEPS_LIBS)
  53 AC_SUBST(DEPS_CPPFLAGS)
  54
  55 dnl python code gen
  56 AC_PATH_PROGS(PYGOBJECT_CODEGEN, pygobject-codegen-2.0 pygtk-codegen-2.0, no)
  57 if test "x$PYGOBJECT_CODEGEN" = xno; then
  58    AC_MSG_ERROR(could not find pygobject-codegen-2.0 script)
  59 fi
  60
  61 dnl check for pygtk defsdir
  62 AC_MSG_CHECKING(for pygtk defs)
  63 PYGTK_DEFSDIR=`$PKG_CONFIG --variable=defsdir pygtk-2.0`
  64 AC_SUBST(PYGTK_DEFSDIR)
  65 AC_MSG_RESULT($PYGTK_DEFSDIR)
  66
  67 dnl output
  68 AC_CONFIG_FILES([
  69 Makefile
  70 pywebkitgtk-1.0.pc:pywebkitgtk.pc.in
  71 ])
  72
  73 AC_OUTPUT