Modules/_ctypes/libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2 #
   3 # file from libffi - slightly patched for ctypes
   4 #
   5
   6 AC_PREREQ(2.59)
   7
   8 AC_INIT([libffi], [3.0.5], [http://gcc.gnu.org/bugs.html])
   9 AC_CONFIG_HEADERS([fficonfig.h])
  10
  11 AC_CANONICAL_SYSTEM
  12 target_alias=${target_alias-$host_alias}
  13
  14 . ${srcdir}/configure.host
  15
  16 AM_INIT_AUTOMAKE
  17
  18 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  19 # We must force CC to /not/ be precious variables; otherwise
  20 # the wrong, non-multilib-adjusted value will be used in multilibs.
  21 # As a side effect, we have to subst CFLAGS ourselves.
  22
  23 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  24 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  25 AC_PROG_CC
  26 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  27
  28 AC_SUBST(CFLAGS)
  29
  30 AM_PROG_AS
  31 AM_PROG_CC_C_O
  32 AC_PROG_LIBTOOL
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_CHECK_HEADERS(sys/mman.h)
  37 AC_CHECK_FUNCS(mmap)
  38 AC_FUNC_MMAP_BLACKLIST
  39
  40 dnl The -no-testsuite modules omit the test subdir.
  41 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  42
  43 TARGETDIR="unknown"
  44 case "$host" in
  45   alpha*-*-*)
  46         TARGET=ALPHA; TARGETDIR=alpha;
  47         # Support 128-bit long double, changable via command-line switch.
  48         HAVE_LONG_DOUBLE='defined(__LONG_DOUBLE_128__)'
  49         ;;
  50
  51   arm*-*-*)
  52         TARGET=ARM; TARGETDIR=arm
  53         ;;
  54
  55   amd64-*-freebsd*)
  56         TARGET=X86_64; TARGETDIR=x86
  57         ;;
  58
  59   cris-*-*)
  60         TARGET=LIBFFI_CRIS; TARGETDIR=cris
  61         ;;
  62
  63   frv-*-*)
  64         TARGET=FRV; TARGETDIR=frv
  65         ;;
  66
  67   hppa*-*-linux* | parisc*-*-linux*)
  68         TARGET=PA_LINUX; TARGETDIR=pa
  69         ;;
  70   hppa*64-*-hpux*)
  71         TARGET=PA64_HPUX; TARGETDIR=pa
  72         ;;
  73   hppa*-*-hpux*)
  74         TARGET=PA_HPUX; TARGETDIR=pa
  75         ;;
  76
  77   i386-*-freebsd* | i386-*-openbsd*)
  78         TARGET=X86_FREEBSD; TARGETDIR=x86
  79         ;;
  80   i?86-win32* | i?86-*-cygwin* | i?86-*-mingw*)
  81         TARGET=X86_WIN32; TARGETDIR=x86
  82         ;;
  83   i?86-*-darwin*)
  84         TARGET=X86_DARWIN; TARGETDIR=x86
  85         ;;
  86   i?86-*-solaris2.1[[0-9]]*)
  87         TARGET=X86_64; TARGETDIR=x86
  88         ;;
  89   i*86-*-nto-qnx*)
  90         TARGET=X86; TARGETDIR=x86
  91         ;;
  92   i?86-*-*)
  93         TARGET=X86; TARGETDIR=x86
  94         ;;
  95
  96   ia64*-*-*)
  97         TARGET=IA64; TARGETDIR=ia64
  98         ;;
  99
 100   m32r*-*-*)
 101         TARGET=M32R; TARGETDIR=m32r
 102         ;;
 103
 104   m68k-*-*)
 105         TARGET=M68K; TARGETDIR=m68k
 106         ;;
 107
 108   mips-sgi-irix5.* | mips-sgi-irix6.*)
 109         TARGET=MIPS; TARGETDIR=mips
 110         ;;
 111   mips*-*-linux*)
 112         TARGET=MIPS; TARGETDIR=mips
 113         ;;
 114
 115   powerpc*-*-linux* | powerpc-*-sysv*)
 116         TARGET=POWERPC; TARGETDIR=powerpc
 117         ;;
 118   powerpc-*-beos*)
 119         TARGET=POWERPC; TARGETDIR=powerpc
 120         ;;
 121   powerpc-*-darwin*)
 122         TARGET=POWERPC_DARWIN; TARGETDIR=powerpc
 123         ;;
 124   powerpc-*-aix* | rs6000-*-aix*)
 125         TARGET=POWERPC_AIX; TARGETDIR=powerpc
 126         ;;
 127   powerpc-*-freebsd*)
 128         TARGET=POWERPC_FREEBSD; TARGETDIR=powerpc
 129         ;;
 130   powerpc*-*-rtems*)
 131         TARGET=POWERPC; TARGETDIR=powerpc
 132         ;;
 133
 134   s390-*-* | s390x-*-*)
 135         TARGET=S390; TARGETDIR=s390
 136         ;;
 137
 138   sh-*-* | sh[[34]]*-*-*)
 139         TARGET=SH; TARGETDIR=sh
 140         ;;
 141   sh64-*-* | sh5*-*-*)
 142         TARGET=SH64; TARGETDIR=sh64
 143         ;;
 144
 145   sparc*-*-*)
 146         TARGET=SPARC; TARGETDIR=sparc
 147         ;;
 148
 149   x86_64-*-darwin*)
 150         TARGET=X86_DARWIN; TARGETDIR=x86
 151         ;;
 152   x86_64-*-cygwin* | x86_64-*-mingw*)
 153         ;;
 154   x86_64-*-*)
 155         TARGET=X86_64; TARGETDIR=x86
 156         ;;
 157 esac
 158
 159 AC_SUBST(AM_RUNTESTFLAGS)
 160
 161 if test $TARGETDIR = unknown; then
 162   AC_MSG_ERROR(["libffi has not been ported to $host."])
 163 fi
 164
 165 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
 166 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 167 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 168 AM_CONDITIONAL(X86_FREEBSD, test x$TARGET = xX86_FREEBSD)
 169 AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32)
 170 AM_CONDITIONAL(X86_DARWIN, test x$TARGET = xX86_DARWIN)
 171 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 172 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
 173 AM_CONDITIONAL(M32R, test x$TARGET = xM32R)
 174 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 175 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 176 AM_CONDITIONAL(POWERPC_AIX, test x$TARGET = xPOWERPC_AIX)
 177 AM_CONDITIONAL(POWERPC_DARWIN, test x$TARGET = xPOWERPC_DARWIN)
 178 AM_CONDITIONAL(POWERPC_FREEBSD, test x$TARGET = xPOWERPC_FREEBSD)
 179 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 180 AM_CONDITIONAL(LIBFFI_CRIS, test x$TARGET = xLIBFFI_CRIS)
 181 AM_CONDITIONAL(FRV, test x$TARGET = xFRV)
 182 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 183 AM_CONDITIONAL(X86_64, test x$TARGET = xX86_64)
 184 AM_CONDITIONAL(SH, test x$TARGET = xSH)
 185 AM_CONDITIONAL(SH64, test x$TARGET = xSH64)
 186 AM_CONDITIONAL(PA_LINUX, test x$TARGET = xPA_LINUX)
 187 AM_CONDITIONAL(PA_HPUX, test x$TARGET = xPA_HPUX)
 188 AM_CONDITIONAL(PA64_HPUX, test x$TARGET = xPA64_HPUX)
 189
 190 AC_HEADER_STDC
 191 AC_CHECK_FUNCS(memcpy)
 192 AC_FUNC_ALLOCA
 193
 194 AC_CHECK_SIZEOF(double)
 195 AC_CHECK_SIZEOF(long double)
 196
 197 # Also AC_SUBST this variable for ffi.h.
 198 if test -z "$HAVE_LONG_DOUBLE"; then
 199   HAVE_LONG_DOUBLE=0
 200   if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 201     if test $ac_cv_sizeof_long_double != 0; then
 202       HAVE_LONG_DOUBLE=1
 203       AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 204     fi
 205   fi
 206 fi
 207 AC_SUBST(HAVE_LONG_DOUBLE)
 208
 209 AC_C_BIGENDIAN
 210
 211 AC_CACHE_CHECK([assembler .cfi pseudo-op support],
 212     libffi_cv_as_cfi_pseudo_op, [
 213     libffi_cv_as_cfi_pseudo_op=unknown
 214     AC_TRY_COMPILE([asm (".cfi_startproc\n\t.cfi_endproc");],,
 215                    [libffi_cv_as_cfi_pseudo_op=yes],
 216                    [libffi_cv_as_cfi_pseudo_op=no])
 217 ])
 218 if test "x$libffi_cv_as_cfi_pseudo_op" = xyes; then
 219     AC_DEFINE(HAVE_AS_CFI_PSEUDO_OP, 1,
 220               [Define if your assembler supports .cfi_* directives.])
 221 fi
 222
 223 if test x$TARGET = xSPARC; then
 224     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 225         libffi_cv_as_sparc_ua_pcrel, [
 226         save_CFLAGS="$CFLAGS"
 227         save_LDFLAGS="$LDFLAGS"
 228         CFLAGS="$CFLAGS -fpic"
 229         LDFLAGS="$LDFLAGS -shared"
 230         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 231                     [libffi_cv_as_sparc_ua_pcrel=yes],
 232                     [libffi_cv_as_sparc_ua_pcrel=no])
 233         CFLAGS="$save_CFLAGS"
 234         LDFLAGS="$save_LDFLAGS"])
 235     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 236         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 237                   [Define if your assembler and linker support unaligned PC relative relocs.])
 238     fi
 239
 240     AC_CACHE_CHECK([assembler .register pseudo-op support],
 241        libffi_cv_as_register_pseudo_op, [
 242        libffi_cv_as_register_pseudo_op=unknown
 243        # Check if we have .register
 244        AC_TRY_COMPILE([asm (".register %g2, #scratch");],,
 245                        [libffi_cv_as_register_pseudo_op=yes],
 246                        [libffi_cv_as_register_pseudo_op=no])
 247     ])
 248     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 249        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 250                [Define if your assembler supports .register.])
 251     fi
 252 fi
 253
 254 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 255     libffi_cv_ro_eh_frame, [
 256         libffi_cv_ro_eh_frame=no
 257         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 258         if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 259             if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 260                 libffi_cv_ro_eh_frame=yes
 261             elif grep '.section.*eh_frame.*#alloc' conftest.c \
 262                  | grep -v '#write' > /dev/null; then
 263                 libffi_cv_ro_eh_frame=yes
 264             fi
 265         fi
 266         rm -f conftest.*
 267     ])
 268 if test "x$libffi_cv_ro_eh_frame" = xyes; then
 269     AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 270               [Define if .eh_frame sections should be read-only.])
 271     AC_DEFINE(EH_FRAME_FLAGS, "a",
 272               [Define to the flags needed for the .section .eh_frame directive.])
 273 else
 274     AC_DEFINE(EH_FRAME_FLAGS, "aw",
 275               [Define to the flags needed for the .section .eh_frame directive.])
 276 fi
 277
 278 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 279     libffi_cv_hidden_visibility_attribute, [
 280         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 281         libffi_cv_hidden_visibility_attribute=no
 282         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 283             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 284                 libffi_cv_hidden_visibility_attribute=yes
 285             fi
 286         fi
 287         rm -f conftest.*
 288     ])
 289 if test $libffi_cv_hidden_visibility_attribute = yes; then
 290     AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 291               [Define if __attribute__((visibility("hidden"))) is supported.])
 292 fi
 293
 294 AH_BOTTOM([
 295 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 296 #ifdef LIBFFI_ASM
 297 #define FFI_HIDDEN(name) .hidden name
 298 #else
 299 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 300 #endif
 301 #else
 302 #ifdef LIBFFI_ASM
 303 #define FFI_HIDDEN(name)
 304 #else
 305 #define FFI_HIDDEN
 306 #endif
 307 #endif
 308 ])
 309
 310 AC_SUBST(TARGET)
 311 AC_SUBST(TARGETDIR)
 312
 313 AC_SUBST(SHELL)
 314
 315 AC_ARG_ENABLE(debug,
 316 [  --enable-debug          debugging mode],
 317   if test "$enable_debug" = "yes"; then
 318     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 319   fi)
 320
 321 AC_ARG_ENABLE(structs,
 322 [  --disable-structs       omit code for struct support],
 323   if test "$enable_structs" = "no"; then
 324     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this is you do not want support for aggregate types.])
 325   fi)
 326
 327 AC_ARG_ENABLE(raw-api,
 328 [  --disable-raw-api       make the raw api unavailable],
 329   if test "$enable_raw_api" = "no"; then
 330     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this is you do not want support for the raw API.])
 331   fi)
 332
 333 AC_ARG_ENABLE(purify-safety,
 334 [  --enable-purify-safety  purify-safe mode],
 335   if test "$enable_purify_safety" = "yes"; then
 336     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 337   fi)
 338
 339 if test -n "$with_cross_host" &&
 340    test x"$with_cross_host" != x"no"; then
 341   toolexecdir='$(exec_prefix)/$(target_alias)'
 342   toolexeclibdir='$(toolexecdir)/lib'
 343 else
 344   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 345   toolexeclibdir='$(libdir)'
 346 fi
 347 multi_os_directory=`$CC -print-multi-os-directory`
 348 case $multi_os_directory in
 349   .) ;; # Avoid trailing /.
 350   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 351 esac
 352 AC_SUBST(toolexecdir)
 353 AC_SUBST(toolexeclibdir)
 354
 355 if test "${multilib}" = "yes"; then
 356   multilib_arg="--enable-multilib"
 357 else
 358   multilib_arg=
 359 fi
 360
 361 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 362 AC_CONFIG_COMMANDS(src, [
 363 test -d src || mkdir src
 364 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 365 ], [TARGETDIR="$TARGETDIR"])
 366
 367 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 368
 369 AC_CONFIG_FILES(include/ffi.h)
 370
 371 AC_CONFIG_LINKS(include/ffi_common.h:include/ffi_common.h)
 372
 373 AC_CONFIG_FILES(fficonfig.py)
 374
 375 AC_OUTPUT