configure.ac

   1 -*- mode: m4 -*-
   2 AC_PREREQ([2.68])
   3
   4 # The version of python used is determined by the executable pointed to by the
   5 # --with-python switch, or if that's not set, by the PYTHON environment
   6 # variable.  For instance if your system installs Python 3 as python3 to
   7 # configure to compile pygobject under Python 3 you would do this:
   8 #   $ ./configure --with-python=python3
   9 # or
  10 #   $ PYTHON=python3 ./configure
  11 #
  12 # You can also build against a full interpreter path, such as
  13 #   $ ./configure --with-python=~/my-patched-python/python
  14
  15 m4_define(python_min_ver, 2.7)
  16 m4_define(python3_min_ver, 3.3)
  17
  18 dnl the pygobject version number
  19 m4_define(pygobject_major_version, 3)
  20 m4_define(pygobject_minor_version, 25)
  21 m4_define(pygobject_micro_version, 0)
  22 m4_define(pygobject_version, pygobject_major_version.pygobject_minor_version.pygobject_micro_version)
  23
  24 dnl versions of packages we require ...
  25 m4_define(introspection_required_version, 1.46.0)
  26 m4_define(py2cairo_required_version, 1.2.0)
  27 m4_define(py3cairo_required_version, 1.10.0)
  28 m4_define(glib_required_version, 2.38.0)
  29 m4_define(gio_required_version, 2.38.0)
  30
  31 AC_INIT([pygobject],[pygobject_version],
  32         [http://bugzilla.gnome.org/enter_bug.cgi?product=pygobject],
  33         [pygobject],[https://wiki.gnome.org/Projects/PyGObject/])
  34 AX_IS_RELEASE([minor-version])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR([gi/gimodule.c])
  37
  38 AC_DEFINE(PYGOBJECT_MAJOR_VERSION, pygobject_major_version, [pygobject major version])
  39 AC_SUBST(PYGOBJECT_MAJOR_VERSION, pygobject_major_version)
  40 AC_DEFINE(PYGOBJECT_MINOR_VERSION, pygobject_minor_version, [pygobject minor version])
  41 AC_SUBST(PYGOBJECT_MINOR_VERSION, pygobject_minor_version)
  42 AC_DEFINE(PYGOBJECT_MICRO_VERSION, pygobject_micro_version, [pygobject micro version])
  43 AC_SUBST(PYGOBJECT_MICRO_VERSION, pygobject_micro_version)
  44
  45 AC_CONFIG_HEADERS(config.h)
  46 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
  47 AM_INIT_AUTOMAKE([1.13 foreign no-dist-gzip dist-xz])
  48
  49 AC_CANONICAL_BUILD
  50 AC_CANONICAL_HOST
  51 AC_MSG_CHECKING([for build time linking with Python (Win32)])
  52 case "$host" in
  53   *-*-mingw*|*-*-cygwin*)
  54     os_win32=yes
  55     link_python_libs=yes
  56     OS_EXT=dll
  57     ;;
  58   *-*-darwin*)
  59     os_win32=no
  60     link_python_libs=no
  61     OS_EXT=dylib
  62     ;;
  63   *)
  64     os_win32=no
  65     link_python_libs=no
  66     OS_EXT=so
  67     ;;
  68 esac
  69 AC_MSG_RESULT([$link_python_libs])
  70 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  71
  72 AC_SUBST(OS_EXT)
  73 AC_DEFINE_UNQUOTED(OS_EXT, "$OS_EXT", [Define shared library extension])
  74
  75 LT_PREREQ([2.2.6])
  76 LT_INIT([dlopen win32-dll disable-static])
  77
  78 AC_SEARCH_LIBS([strerror],[cposix])
  79 AC_PROG_CC
  80 AM_PROG_CC_C_O
  81
  82 # option to specify python interpreter to use; this just sets $PYTHON, so that
  83 # we will fallback to reading $PYTHON if --with-python is not given, and
  84 # python.m4 will get the expected input
  85 AC_ARG_WITH(python,
  86   AS_HELP_STRING([--with-python=PATH],[Path to Python interpreter; searches $PATH if only a program name is given; if not given, searches for a few standard names such as "python3" or "python2"]),
  87   [PYTHON="$withval"], [])
  88 if test x"$PYTHON" = xyes; then
  89         AC_MSG_ERROR([--with-python option requires a path or program argument])
  90 fi
  91 if test -n "$PYTHON" && ! which "$PYTHON"; then
  92         AC_MSG_ERROR([Python interpreter $PYTHON does not exist])
  93 fi
  94
  95 # check that we have the minimum version of python necessary to build
  96 JD_PATH_PYTHON(python_min_ver)
  97
  98 # check if we are building for python 3
  99 AM_PYTHON_CHECK_VERSION([$PYTHON], [3.0],
 100                          build_py3k=true,
 101                          build_py3k=false)
 102
 103 # if building for python 3 make sure we have the minimum version supported
 104 if test $build_py3k = true ; then
 105   AC_MSG_CHECKING([for $PYTHON >=] python3_min_ver)
 106   AM_PYTHON_CHECK_VERSION([$PYTHON], python3_min_ver,
 107                           [AC_MSG_RESULT(yes)],
 108                           [AC_MSG_ERROR(too old)])
 109 fi
 110
 111 # - 'SO' for PyPy, CPython 2.7-3.2
 112 # - 'EXT_SUFFIX' for CPython3.3+ (http://bugs.python.org/issue16754)
 113 # - fallback to '.so'
 114 PYTHON_SO=`$PYTHON -c "import distutils.sysconfig, sys; get = distutils.sysconfig.get_config_var; sys.stdout.write(get('EXT_SUFFIX') or get('SO') or '.so');"`
 115 AC_SUBST(PYTHON_SO)
 116
 117 PYG_CHECK_PYTHON_HEADERS(, AC_MSG_ERROR([Python headers not found]))
 118 if test "x$link_python_libs" = "xyes"; then
 119   PYG_CHECK_PYTHON_LIBS(, AC_MSG_ERROR([Python libs not found. Windows requires Python modules to be explicitly linked to libpython.]))
 120 fi
 121
 122 PLATFORM=`$PYTHON -c "import sys; from distutils import util; sys.stdout.write(util.get_platform())"`
 123 AC_SUBST(PLATFORM)
 124
 125 dnl get rid of the -export-dynamic stuff from the configure flags ...
 126 export_dynamic=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
 127
 128 dnl glib
 129 AM_PATH_GLIB_2_0(glib_required_version,,[AC_MSG_ERROR(maybe you want the pygobject-2-4 branch?)],gobject $extra_mods)
 130 if test -n "$export_dynamic"; then
 131   GLIB_LIBS=`echo $GLIB_LIBS | sed -e "s/$export_dynamic//"`
 132 fi
 133
 134 PYTHON_VALGRIND_SUPP=`$PYTHON -c "import sys; sys.stdout.write('python' + sys.version.__getitem__(0))"`
 135 AC_SUBST([PYTHON_VALGRIND_SUPP])
 136
 137 dnl libffi
 138 PKG_CHECK_MODULES(FFI, libffi >= 3.0)
 139 LIBFFI_PC=libffi
 140
 141 AC_SUBST(FFI_CFLAGS)
 142 AC_SUBST(FFI_LIBS)
 143 AC_SUBST(LIBFFI_PC)
 144
 145 dnl gio
 146 PKG_CHECK_MODULES(GIO, gio-2.0 >= gio_required_version)
 147
 148 AC_ARG_ENABLE(cairo,
 149     AS_HELP_STRING([--enable-cairo],[Enable Cairo bindings using introspection information]),
 150     enable_cairo=$enableval,
 151     enable_cairo=yes)
 152
 153 PKG_CHECK_MODULES(GI,
 154     glib-2.0 >= glib_required_version
 155     gobject-introspection-1.0 >= introspection_required_version
 156 )
 157
 158 GOBJECT_INTROSPECTION_CHECK(introspection_required_version)
 159
 160 GI_DATADIR=$($PKG_CONFIG --variable=gidatadir gobject-introspection-1.0)
 161 AC_SUBST(GI_DATADIR)
 162
 163 if test "$enable_cairo" != no; then
 164     PKG_CHECK_MODULES(CAIRO, cairo cairo-gobject)
 165
 166     if test $build_py3k = true; then
 167         PKG_CHECK_MODULES(PYCAIRO,
 168             py3cairo >= py3cairo_required_version
 169         )
 170     else
 171         PKG_CHECK_MODULES(PYCAIRO,
 172             pycairo >= py2cairo_required_version
 173         )
 174     fi
 175 fi
 176 AM_CONDITIONAL(ENABLE_CAIRO, test "$enable_cairo" = "yes")
 177
 178 AC_ARG_WITH(common,
 179     AS_HELP_STRING([--without-common],
 180         [For package maintainers: do not install Python version independent files]),
 181     with_common=$enableval,
 182     with_common=yes)
 183 AM_CONDITIONAL(WITH_COMMON, test "$with_common" = "yes")
 184
 185 AX_COMPILER_FLAGS()
 186 # Disable some warnings, either because they get generated by headers of
 187 # dependencies we don't control or because it was hard to fix them.
 188 # Feel free and try to get rid of them.
 189 # For clang only:
 190 AX_APPEND_COMPILE_FLAGS([-Wno-unknown-warning-option -Wno-incompatible-pointer-types-discards-qualifiers -Wno-cast-align])
 191 # For gcc + clang:
 192 AX_APPEND_COMPILE_FLAGS([-Wno-discarded-qualifiers -Wno-redundant-decls -Wno-switch-enum -Wno-undef])
 193
 194 AX_CODE_COVERAGE()
 195
 196 AC_CONFIG_FILES(
 197   Makefile
 198   pygobject-3.0.pc
 199   pygobject-3.0-uninstalled.pc
 200   gi/Makefile
 201   gi/repository/Makefile
 202   gi/overrides/Makefile
 203   examples/Makefile
 204   tests/Makefile
 205   pygtkcompat/Makefile
 206   PKG-INFO)
 207 AC_OUTPUT
 208
 209 AC_MSG_RESULT([
 210         pygobject $VERSION
 211
 212         Is release:                     $ax_is_release
 213         Using python interpreter:       $PYTHON
 214         cairo support:                  $enable_cairo
 215         code coverage support:          $enable_code_coverage
 216 ])
 217