acinclude.m4

   1 dnl Available from the GNU Autoconf Macro Archive at:
   2 dnl http://www.gnu.org/software/ac-archive/htmldoc/acx_pthread.html
   3 dnl
   4 AC_DEFUN([ACX_PTHREAD], [
   5 AC_REQUIRE([AC_CANONICAL_HOST])
   6 AC_LANG_SAVE
   7 AC_LANG_C
   8 acx_pthread_ok=no
   9
  10 # We used to check for pthread.h first, but this fails if pthread.h
  11 # requires special compiler flags (e.g. on True64 or Sequent).
  12 # It gets checked for in the link test anyway.
  13
  14 # First of all, check if the user has set any of the PTHREAD_LIBS,
  15 # etcetera environment variables, and if threads linking works using
  16 # them:
  17 if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
  18         save_CFLAGS="$CFLAGS"
  19         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  20         save_LIBS="$LIBS"
  21         LIBS="$PTHREAD_LIBS $LIBS"
  22         AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
  23         AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
  24         AC_MSG_RESULT($acx_pthread_ok)
  25         if test x"$acx_pthread_ok" = xno; then
  26                 PTHREAD_LIBS=""
  27                 PTHREAD_CFLAGS=""
  28         fi
  29         LIBS="$save_LIBS"
  30         CFLAGS="$save_CFLAGS"
  31 fi
  32
  33 # We must check for the threads library under a number of different
  34 # names; the ordering is very important because some systems
  35 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
  36 # libraries is broken (non-POSIX).
  37
  38 # Create a list of thread flags to try.  Items starting with a "-" are
  39 # C compiler flags, and other items are library names, except for "none"
  40 # which indicates that we try without any flags at all, and "pthread-config"
  41 # which is a program returning the flags for the Pth emulation library.
  42
  43 acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
  44
  45 # The ordering *is* (sometimes) important.  Some notes on the
  46 # individual items follow:
  47
  48 # pthreads: AIX (must check this before -lpthread)
  49 # none: in case threads are in libc; should be tried before -Kthread and
  50 #       other compiler flags to prevent continual compiler warnings
  51 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
  52 # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
  53 # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
  54 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
  55 # -pthreads: Solaris/gcc
  56 # -mthreads: Mingw32/gcc, Lynx/gcc
  57 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
  58 #      doesn't hurt to check since this sometimes defines pthreads too;
  59 #      also defines -D_REENTRANT)
  60 # pthread: Linux, etcetera
  61 # --thread-safe: KAI C++
  62 # pthread-config: use pthread-config program (for GNU Pth library)
  63
  64 case "${host_cpu}-${host_os}" in
  65         *solaris*)
  66
  67         # On Solaris (at least, for some versions), libc contains stubbed
  68         # (non-functional) versions of the pthreads routines, so link-based
  69         # tests will erroneously succeed.  (We need to link with -pthread or
  70         # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
  71         # a function called by this macro, so we could check for that, but
  72         # who knows whether they'll stub that too in a future libc.)  So,
  73         # we'll just look for -pthreads and -lpthread first:
  74
  75         acx_pthread_flags="-pthread -pthreads pthread -mt $acx_pthread_flags"
  76         ;;
  77 esac
  78
  79 if test x"$acx_pthread_ok" = xno; then
  80 for flag in $acx_pthread_flags; do
  81
  82         case $flag in
  83                 none)
  84                 AC_MSG_CHECKING([whether pthreads work without any flags])
  85                 ;;
  86
  87                 -*)
  88                 AC_MSG_CHECKING([whether pthreads work with $flag])
  89                 PTHREAD_CFLAGS="$flag"
  90                 ;;
  91
  92                 pthread-config)
  93                 AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
  94                 if test x"$acx_pthread_config" = xno; then continue; fi
  95                 PTHREAD_CFLAGS="`pthread-config --cflags`"
  96                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
  97                 ;;
  98
  99                 *)
 100                 AC_MSG_CHECKING([for the pthreads library -l$flag])
 101                 PTHREAD_LIBS="-l$flag"
 102                 ;;
 103         esac
 104
 105         save_LIBS="$LIBS"
 106         save_CFLAGS="$CFLAGS"
 107         LIBS="$PTHREAD_LIBS $LIBS"
 108         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 109
 110         # Check for various functions.  We must include pthread.h,
 111         # since some functions may be macros.  (On the Sequent, we
 112         # need a special flag -Kthread to make this header compile.)
 113         # We check for pthread_join because it is in -lpthread on IRIX
 114         # while pthread_create is in libc.  We check for pthread_attr_init
 115         # due to DEC craziness with -lpthreads.  We check for
 116         # pthread_cleanup_push because it is one of the few pthread
 117         # functions on Solaris that doesn't have a non-functional libc stub.
 118         # We try pthread_create on general principles.
 119         AC_TRY_LINK([#include <pthread.h>],
 120                     [pthread_t th; pthread_join(th, 0);
 121                      pthread_attr_init(0); pthread_cleanup_push(0, 0);
 122                      pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],
 123                     [acx_pthread_ok=yes])
 124
 125         LIBS="$save_LIBS"
 126         CFLAGS="$save_CFLAGS"
 127
 128         AC_MSG_RESULT($acx_pthread_ok)
 129         if test "x$acx_pthread_ok" = xyes; then
 130                 break;
 131         fi
 132
 133         PTHREAD_LIBS=""
 134         PTHREAD_CFLAGS=""
 135 done
 136 fi
 137
 138 # Various other checks:
 139 if test "x$acx_pthread_ok" = xyes; then
 140         save_LIBS="$LIBS"
 141         LIBS="$PTHREAD_LIBS $LIBS"
 142         save_CFLAGS="$CFLAGS"
 143         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 144
 145         # Detect AIX lossage: threads are created detached by default
 146         # and the JOINABLE attribute has a nonstandard name (UNDETACHED).
 147         AC_MSG_CHECKING([for joinable pthread attribute])
 148         AC_TRY_LINK([#include <pthread.h>],
 149                     [int attr=PTHREAD_CREATE_JOINABLE;],
 150                     ok=PTHREAD_CREATE_JOINABLE, ok=unknown)
 151         if test x"$ok" = xunknown; then
 152                 AC_TRY_LINK([#include <pthread.h>],
 153                             [int attr=PTHREAD_CREATE_UNDETACHED;],
 154                             ok=PTHREAD_CREATE_UNDETACHED, ok=unknown)
 155         fi
 156         if test x"$ok" != xPTHREAD_CREATE_JOINABLE; then
 157                 AC_DEFINE(PTHREAD_CREATE_JOINABLE, $ok,
 158                           [Define to the necessary symbol if this constant
 159                            uses a non-standard name on your system.])
 160         fi
 161         AC_MSG_RESULT(${ok})
 162         if test x"$ok" = xunknown; then
 163                 AC_MSG_WARN([we do not know how to create joinable pthreads])
 164         fi
 165
 166         AC_MSG_CHECKING([if more special flags are required for pthreads])
 167         flag=no
 168         case "${host_cpu}-${host_os}" in
 169                 *-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
 170                 *solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
 171         esac
 172         AC_MSG_RESULT(${flag})
 173         if test "x$flag" != xno; then
 174                 PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
 175         fi
 176
 177         LIBS="$save_LIBS"
 178         CFLAGS="$save_CFLAGS"
 179
 180         # More AIX lossage: must compile with cc_r
 181         AC_CHECK_PROG(PTHREAD_CC, cc_r, cc_r, ${CC})
 182 else
 183         PTHREAD_CC="$CC"
 184 fi
 185
 186 AC_SUBST(PTHREAD_LIBS)
 187 AC_SUBST(PTHREAD_CFLAGS)
 188 AC_SUBST(PTHREAD_CC)
 189
 190 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 191 if test x"$acx_pthread_ok" = xyes; then
 192         ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
 193         :
 194 else
 195         acx_pthread_ok=no
 196         $2
 197 fi
 198 AC_LANG_RESTORE
 199 ])dnl ACX_PTHREAD
 200
 201 AC_DEFUN([AC_CHECK_DEFINE],[
 202 AS_VAR_PUSHDEF([ac_var],[ac_cv_defined_$1])dnl
 203 AC_CACHE_CHECK([for $1 defined], ac_var,
 204 AC_TRY_COMPILE([#include <$2>],[
 205   #ifdef $1
 206   int ok;
 207   #else
 208   choke me
 209   #endif
 210 ],AS_VAR_SET(ac_var, yes),AS_VAR_SET(ac_var, no)))
 211 AS_IF([test AS_VAR_GET(ac_var) != "no"], [$3], [$4])dnl
 212 AS_VAR_POPDEF([ac_var])dnl
 213 ])
 214
 215 AC_DEFUN([ACX_LIBWRAP], [
 216 LIBWRAP_LIBS=
 217 saved_LIBS="$LIBS"
 218 LIBS="$LIBS -lwrap"
 219 AC_MSG_CHECKING([for tcpwrap library and headers])
 220 AC_LINK_IFELSE(
 221 AC_LANG_PROGRAM(
 222 [#include <tcpd.h>
 223 #include <syslog.h>
 224 int allow_severity = LOG_INFO;
 225 int deny_severity = LOG_WARNING;],
 226 [struct request_info *req;
 227 return hosts_access (req);]),
 228 [AC_DEFINE(HAVE_LIBWRAP, [], [Have tcpwrap?])
 229 LIBWRAP_LIBS="-lwrap"
 230 AC_MSG_RESULT(yes)],
 231 [AC_MSG_RESULT(no)])
 232 LIBS="$saved_LIBS"
 233 ])
 234
 235 AC_DEFUN([ACX_LIRC], [
 236 LIRC_CFLAGS=
 237 LIRC_LIBS=
 238 AC_CHECK_HEADER(lirc/lirc_client.h,[AC_CHECK_LIB(lirc_client,lirc_init,[HAVE_LIRC=1
 239 LIRC_LIBS=-llirc_client],HAVE_LIRC=0)],HAVE_LIRC=0)
 240 ])