configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # $Id$
   5
   6 # This file is part of PulseAudio.
   7 #
   8 # PulseAudio is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU Lesser General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # PulseAudio is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public License
  19 # along with PulseAudio; if not, write to the Free Software Foundation,
  20 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  21
  22 AC_PREREQ(2.57)
  23
  24 m4_define(PA_MAJOR, [0])
  25 m4_define(PA_MINOR, [9])
  26 m4_define(PA_MICRO, [5])
  27
  28 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzcbylcnhqvb (at) 0pointer (dot) de])
  29 AC_CONFIG_SRCDIR([src/daemon/main.c])
  30 AC_CONFIG_HEADERS([config.h])
  31 AM_INIT_AUTOMAKE([foreign -Wall])
  32
  33 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  34 AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/pulseaudio/])
  35
  36 AC_SUBST(PA_API_VERSION, 10)
  37 AC_SUBST(PA_PROTOCOL_VERSION, 10)
  38
  39 AC_SUBST(LIBPULSE_VERSION_INFO, [1:0:1])
  40 AC_SUBST(LIBPULSECORE_VERSION_INFO, [2:0:0])
  41 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:0:0])
  42 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:0:1])
  43 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:2:0])
  44
  45 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  46    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  47    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  48 fi
  49
  50 #### Platform hacks ####
  51
  52 case $host in
  53    *-*-solaris* )
  54       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  55       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  56       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  57       ;;
  58 esac
  59
  60 #### Checks for programs. ####
  61
  62 # CC
  63
  64 AC_PROG_CC
  65 AC_PROG_GCC_TRADITIONAL
  66 AC_GNU_SOURCE
  67
  68 # M4
  69
  70 AC_PATH_PROG([M4], [m4 gm4], [no])
  71 if test "x$M4" = xno ; then
  72    AC_MSG_ERROR([m4 missing])
  73 fi
  74
  75 # GCC flags
  76
  77 test_gcc_flag() {
  78     AC_LANG_CONFTEST([int main() {}])
  79     $CC -c conftest.c $CFLAGS $@ > /dev/null 2> /dev/null
  80     ret=$?
  81     rm -f conftest.o
  82     return $ret
  83 }
  84
  85 # If using GCC specify some additional parameters
  86 if test "x$GCC" = "xyes" ; then
  87
  88     # We use gnu99 instead of c99 because many have interpreted the standard
  89     # in a way that int64_t isn't defined on non-64 bit platforms.
  90     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter"
  91
  92     for flag in $DESIRED_FLAGS ; do
  93         AC_MSG_CHECKING([whether $CC accepts $flag])
  94         if test_gcc_flag $flag ; then
  95            CFLAGS="$CFLAGS $flag"
  96            AC_MSG_RESULT([yes])
  97         else
  98            AC_MSG_RESULT([no])
  99         fi
 100     done
 101 fi
 102
 103 #### libtool stuff ####
 104
 105 AC_LTDL_ENABLE_INSTALL
 106 AC_LIBLTDL_INSTALLABLE
 107 AC_SUBST(LTDLINCL)
 108 AC_SUBST(LIBLTDL)
 109 AC_LIBTOOL_DLOPEN
 110 AC_LIBTOOL_WIN32_DLL
 111 AC_PROG_LIBTOOL
 112 AC_CONFIG_SUBDIRS(libltdl)
 113
 114 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 115     AC_MSG_ERROR([[
 116
 117         *** Cannot find the libltdl development files.
 118         *** Maybe you need to install the libltdl-dev package.
 119         ]])
 120 fi
 121
 122 #### Determine build environment ####
 123
 124 os_is_win32=0
 125
 126 case "$host_os" in
 127         mingw*)
 128         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 129         os_is_win32=1
 130                 ;;
 131         esac
 132
 133 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 134
 135 ###################################
 136 #   Basic environment checks      #
 137 ###################################
 138
 139 #### Checks for header files. ####
 140
 141 # ISO
 142 AC_HEADER_STDC
 143
 144 # POSIX
 145 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 146     netinet/in_systm.h netinet/ip.h netinet/tcp.h pwd.h sched.h \
 147     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 148     syslog.h])
 149 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 150 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 151
 152 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 153 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 154
 155 # XPG4-UNIX
 156 AC_CHECK_HEADERS([sys/poll.h])
 157
 158 # Linux
 159 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 160
 161 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 162
 163 AC_CHECK_HEADERS([sys/prctl.h])
 164
 165 # Solaris
 166 AC_CHECK_HEADERS([sys/filio.h])
 167
 168 # Windows
 169 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 170
 171 # Other
 172 AC_CHECK_HEADERS([sys/ioctl.h])
 173
 174 #### Typdefs, structures, etc. ####
 175
 176 AC_C_CONST
 177 AC_C_BIGENDIAN
 178 AC_TYPE_PID_T
 179 AC_TYPE_SIZE_T
 180 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 181     [Define ssize_t if it is not done by the standard libs.])])
 182 AC_TYPE_OFF_T
 183 AC_TYPE_SIGNAL
 184 AC_TYPE_UID_T
 185
 186 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 187 HAVE_SIGXCPU=1
 188 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 189 ], [HAVE_SIGXCPU=0])
 190 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 191
 192 # Solaris lacks this
 193 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 194     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 195         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 196
 197 #### Check for libs ####
 198
 199 # ISO
 200 AC_SEARCH_LIBS([pow], [m])
 201
 202 # POSIX
 203 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 204 AC_SEARCH_LIBS([dlopen], [dl])
 205 AC_SEARCH_LIBS([shm_open], [rt])
 206
 207 # BSD
 208 AC_SEARCH_LIBS([connect], [socket])
 209
 210 # Non-standard
 211
 212 # This magic is needed so we do not needlessly add static libs to the win32
 213 # build, disabling its ability to make dlls.
 214 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 215
 216 #### Check for functions ####
 217
 218 # POSIX
 219 AC_FUNC_FORK
 220 AC_FUNC_GETGROUPS
 221 AC_FUNC_SELECT_ARGTYPES
 222 AC_CHECK_FUNCS([chmod chown getaddrinfo getgrgid_r getpwuid_r gettimeofday \
 223     getuid inet_ntop inet_pton nanosleep pipe posix_memalign setpgid setsid \
 224     shm_open sigaction sleep sysconf])
 225 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 226
 227 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 228
 229 # X/OPEN
 230 AC_CHECK_FUNCS([readlink])
 231
 232 # SUSv2
 233 AC_CHECK_FUNCS([ctime_r usleep])
 234
 235 # SUSv3
 236 AC_CHECK_FUNCS([strerror_r])
 237
 238 # BSD
 239 AC_CHECK_FUNCS([lstat])
 240
 241 # Non-standard
 242
 243 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid])
 244
 245 #### POSIX threads ####
 246
 247 ACX_PTHREAD
 248
 249 #### Large File-Support (LFS) ####
 250
 251 AC_SYS_LARGEFILE
 252
 253 # Check for open64 to know if the current system does have open64() and similar functions
 254 AC_CHECK_FUNCS([open64])
 255
 256 #### [lib]iconv ####
 257
 258 AM_ICONV
 259
 260 ###################################
 261 #      External libraries         #
 262 ###################################
 263
 264 #### X11 (optional) ####
 265
 266 HAVE_X11=0
 267
 268 # The macro tests the host, not the build target
 269 if test "x$os_is_win32" != "x1" ; then
 270     AC_PATH_XTRA
 271     test "x$no_x" != "xyes" && HAVE_X11=1
 272 fi
 273
 274 AC_SUBST(HAVE_X11)
 275 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 276 if test "x$HAVE_X11" = "x1" ; then
 277     AC_DEFINE([HAVE_X11], 1, [Have X11])
 278 fi
 279
 280 #### Capabilities (optional) ####
 281
 282 CAP_LIBS=''
 283
 284 AC_ARG_WITH(
 285         [caps],
 286         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 287
 288 if test "x${with_caps}" != "xno"; then
 289     AC_SEARCH_LIBS([cap_init], [cap], [], [
 290                     if test "x${with_caps}" = "xyes" ; then
 291                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 292                     fi])
 293     AC_CHECK_HEADERS([sys/capability.h], [], [
 294                     if test "x${with_caps}" = "xyes" ; then
 295                         AC_MSG_ERROR([*** POSIX caps headers not found])
 296                     fi])
 297 fi
 298
 299 #### pkg-config ####
 300
 301 # Check for pkg-config manually first, as if its not installed the
 302 # PKG_PROG_PKG_CONFIG macro won't be defined.
 303 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 304
 305 if test x"$have_pkg_config" = "xno"; then
 306     AC_MSG_ERROR(pkg-config is required to install this program)
 307 fi
 308
 309 PKG_PROG_PKG_CONFIG
 310
 311 #### Sample rate conversion ####
 312
 313 PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ])
 314 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 315 AC_SUBST(LIBSAMPLERATE_LIBS)
 316
 317 #### Sound file ####
 318
 319 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 320 AC_SUBST(LIBSNDFILE_CFLAGS)
 321 AC_SUBST(LIBSNDFILE_LIBS)
 322
 323 #### atomic-ops ###
 324
 325 AC_CHECK_HEADERS([atomic_ops.h], [], [
 326 AC_MSG_ERROR([*** libatomic-ops headers not found])
 327 ])
 328
 329 # Win32 does not need the lib and breaks horribly if we try to include it
 330 if test "x$os_is_win32" != "x1" ; then
 331     LIBS="$LIBS -latomic_ops"
 332 fi
 333
 334 #### OSS support (optional) ####
 335
 336 AC_ARG_ENABLE([oss],
 337     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 338         [
 339             case "${enableval}" in
 340                 yes) oss=yes ;;
 341                 no) oss=no ;;
 342                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 343             esac
 344         ],
 345         [oss=auto])
 346
 347 if test "x${oss}" != xno ; then
 348     AC_CHECK_HEADERS([sys/soundcard.h],
 349         [
 350             HAVE_OSS=1
 351             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 352         ],
 353         [
 354             HAVE_OSS=0
 355             if test "x$oss" = xyes ; then
 356                 AC_MSG_ERROR([*** OSS support not found])
 357             fi
 358         ])
 359 else
 360     HAVE_OSS=0
 361 fi
 362
 363 AC_SUBST(HAVE_OSS)
 364 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 365
 366
 367 #### ALSA support (optional) ####
 368
 369 AC_ARG_ENABLE([alsa],
 370     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 371         [
 372             case "${enableval}" in
 373                 yes) alsa=yes ;;
 374                 no) alsa=no ;;
 375                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 376             esac
 377         ],
 378         [alsa=auto])
 379
 380 if test "x${alsa}" != xno ; then
 381     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.0 ],
 382         [
 383             HAVE_ALSA=1
 384             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 385         ],
 386         [
 387             HAVE_ALSA=0
 388             if test "x$alsa" = xyes ; then
 389                 AC_MSG_ERROR([*** ALSA support not found])
 390             fi
 391         ])
 392 else
 393     HAVE_ALSA=0
 394 fi
 395
 396 AC_SUBST(ASOUNDLIB_CFLAGS)
 397 AC_SUBST(ASOUNDLIB_LIBS)
 398 AC_SUBST(HAVE_ALSA)
 399 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 400
 401 #### Solaris audio support (optional) ####
 402
 403 AC_ARG_ENABLE([solaris],
 404     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 405         [
 406             case "${enableval}" in
 407                 yes) solaris=yes ;;
 408                 no) solaris=no ;;
 409                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 410             esac
 411         ],
 412         [solaris=auto])
 413
 414 if test "x${solaris}" != xno ; then
 415     AC_CHECK_HEADERS([sys/audio.h],
 416         [
 417             HAVE_SOLARIS=1
 418             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 419         ],
 420         [
 421             HAVE_SOLARIS=0
 422             if test "x$solaris" = xyes ; then
 423                 AC_MSG_ERROR([*** Solaris audio support not found])
 424             fi
 425         ])
 426 else
 427     HAVE_SOLARIS=0
 428 fi
 429
 430 AC_SUBST(HAVE_SOLARIS)
 431 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 432
 433 #### GLib 2 support (optional) ####
 434
 435 AC_ARG_ENABLE([glib2],
 436     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 437         [
 438             case "${enableval}" in
 439                 yes) glib2=yes ;;
 440                 no) glib2=no ;;
 441                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 442             esac
 443         ],
 444         [glib2=auto])
 445
 446 if test "x${glib2}" != xno ; then
 447     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 448         HAVE_GLIB20=1,
 449         [
 450             HAVE_GLIB20=0
 451             if test "x$glib2" = xyes ; then
 452                 AC_MSG_ERROR([*** GLib 2 support not found])
 453             fi
 454         ])
 455 else
 456     HAVE_GLIB20=0
 457 fi
 458
 459 AC_SUBST(GLIB20_CFLAGS)
 460 AC_SUBST(GLIB20_LIBS)
 461 AC_SUBST(HAVE_GLIB20)
 462 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 463
 464 #### GConf support (optional) ####
 465
 466 AC_ARG_ENABLE([gconf],
 467     AC_HELP_STRING([--disable-gconf], [Disable optional GConf support]),
 468         [
 469             case "${enableval}" in
 470                 yes) gconf=yes ;;
 471                 no) gconf=no ;;
 472                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 473             esac
 474         ],
 475         [glib=auto])
 476
 477 if test "x${gconf}" != xno ; then
 478     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 479         HAVE_GCONF=1,
 480         [
 481             HAVE_GCONF=0
 482             if test "x$gconf" = xyes ; then
 483                 AC_MSG_ERROR([*** GConf support not found])
 484             fi
 485         ])
 486 else
 487     HAVE_GCONF=0
 488 fi
 489
 490 AC_SUBST(GCONF_CFLAGS)
 491 AC_SUBST(GCONF_LIBS)
 492 AC_SUBST(HAVE_GCONF)
 493 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 494
 495 #### Avahi support (optional) ####
 496
 497 AC_ARG_ENABLE([avahi],
 498     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 499         [
 500             case "${enableval}" in
 501                 yes) avahi=yes ;;
 502                 no) avahi=no ;;
 503                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 504             esac
 505         ],
 506         [avahi=auto])
 507
 508 if test "x${avahi}" != xno ; then
 509     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 510         HAVE_AVAHI=1,
 511         [
 512                 HAVE_AVAHI=0
 513                 if test "x$avahi" = xyes ; then
 514                         AC_MSG_ERROR([*** Avahi support not found])
 515                 fi
 516         ])
 517 else
 518     HAVE_AVAHI=0
 519 fi
 520
 521 AC_SUBST(AVAHI_CFLAGS)
 522 AC_SUBST(AVAHI_LIBS)
 523 AC_SUBST(HAVE_AVAHI)
 524 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 525
 526 ### LIBOIL ####
 527
 528 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 529 AC_SUBST(LIBOIL_CFLAGS)
 530 AC_SUBST(LIBOIL_LIBS)
 531
 532 ### JACK (optional) ####
 533
 534 AC_ARG_ENABLE([jack],
 535     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 536         [
 537             case "${enableval}" in
 538                 yes) jack=yes ;;
 539                 no) jack=no ;;
 540                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 541             esac
 542         ],
 543         [jack=auto])
 544
 545 if test "x${jack}" != xno ; then
 546     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 547         HAVE_JACK=1,
 548         [
 549             HAVE_JACK=0
 550             if test "x$jack" = xyes ; then
 551                 AC_MSG_ERROR([*** JACK support not found])
 552             fi
 553         ])
 554 else
 555     HAVE_JACK=0
 556 fi
 557
 558 AC_SUBST(JACK_CFLAGS)
 559 AC_SUBST(JACK_LIBS)
 560 AC_SUBST(HAVE_JACK)
 561 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 562
 563 #### Async DNS support (optional) ####
 564
 565 AC_ARG_ENABLE([asyncns],
 566     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 567         [
 568             case "${enableval}" in
 569                 yes) asyncns=yes ;;
 570                 no) asyncns=no ;;
 571                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 572             esac
 573         ],
 574         [asyncns=auto])
 575
 576 if test "x${asyncns}" != xno ; then
 577     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 578         HAVE_LIBASYNCNS=1,
 579         [
 580             HAVE_LIBASYNCNS=0
 581             if test "x$asyncns" = xyes ; then
 582                 AC_MSG_ERROR([*** Async DNS support not found])
 583             fi
 584         ])
 585 else
 586     HAVE_LIBASYNCNS=0
 587 fi
 588
 589 AC_SUBST(LIBASYNCNS_CFLAGS)
 590 AC_SUBST(LIBASYNCNS_LIBS)
 591 AC_SUBST(HAVE_LIBASYNCNS)
 592 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 593
 594 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 595    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 596 fi
 597
 598 #### TCP wrappers (optional) ####
 599
 600 AC_ARG_ENABLE([tcpwrap],
 601     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 602         [
 603             case "${enableval}" in
 604                 yes) tcpwrap=yes ;;
 605                 no) tcpwrap=no ;;
 606                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 607             esac
 608         ],
 609         [tcpwrap=auto])
 610
 611 if test "x${tcpwrap}" != xno ; then
 612     ACX_LIBWRAP
 613     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 614         AC_MSG_ERROR([*** TCP wrappers support not found])
 615     fi
 616 else
 617     LIBWRAP_LIBS=
 618 fi
 619
 620 AC_SUBST(LIBWRAP_LIBS)
 621
 622 #### LIRC support (optional) ####
 623
 624 AC_ARG_ENABLE([lirc],
 625     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 626         [
 627             case "${enableval}" in
 628                 yes) lirc=yes ;;
 629                 no) lirc=no ;;
 630                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 631             esac
 632         ],
 633         [lirc=auto])
 634
 635 if test "x${lirc}" != xno ; then
 636     ACX_LIRC
 637     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 638         AC_MSG_ERROR([*** LIRC support not found])
 639     fi
 640 else
 641     HAVE_LIRC=0
 642 fi
 643
 644 AC_SUBST(LIRC_CFLAGS)
 645 AC_SUBST(LIRC_LIBS)
 646 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 647
 648 #### HAL support (optional) ####
 649
 650 AC_ARG_ENABLE([hal],
 651     AC_HELP_STRING([--disable-hal], [Disable optional HAL support]),
 652         [
 653             case "${enableval}" in
 654                 yes) hal=yes ;;
 655                 no) hal=no ;;
 656                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 657             esac
 658         ],
 659         [hal=auto])
 660
 661 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 662     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 663         HAVE_HAL=1,
 664         [
 665             HAVE_HAL=0
 666             if test "x$hal" = xyes ; then
 667                 AC_MSG_ERROR([*** HAL support not found])
 668             fi
 669         ])
 670 else
 671     HAVE_HAL=0
 672 fi
 673
 674 AC_SUBST(HAL_CFLAGS)
 675 AC_SUBST(HAL_LIBS)
 676 AC_SUBST(HAVE_HAL)
 677 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 678
 679 #### PulseAudio system group & user  #####
 680
 681 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
 682 if test -z "$with_system_user" ; then
 683     PA_SYSTEM_USER=pulse
 684 else
 685     PA_SYSTEM_USER=$with_system_user
 686 fi
 687 AC_SUBST(PA_SYSTEM_USER)
 688 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
 689
 690 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
 691 if test -z "$with_system_group" ; then
 692     PA_SYSTEM_GROUP=pulse
 693 else
 694     PA_SYSTEM_GROUP=$with_system_group
 695 fi
 696 AC_SUBST(PA_SYSTEM_GROUP)
 697 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
 698
 699 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
 700 if test -z "$with_realtime_group" ; then
 701     PA_REALTIME_GROUP=realtime
 702 else
 703     PA_REALTIME_GROUP=$with_realtime_group
 704 fi
 705 AC_SUBST(PA_REALTIME_GROUP)
 706 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
 707
 708 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
 709 if test -z "$with_access_group" ; then
 710     PA_ACCESS_GROUP=pulse-access
 711 else
 712     PA_ACCESS_GROUP=$with_access_group
 713 fi
 714 AC_SUBST(PA_ACCESS_GROUP)
 715 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
 716
 717 #### PulseAudio system runtime dir ####
 718 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
 719 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
 720
 721 ###################################
 722 #            Output               #
 723 ###################################
 724
 725 AC_ARG_ENABLE(
 726         [static-bins],
 727         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
 728         [STATIC_BINS=1], [STATIC_BINS=0])
 729 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
 730
 731 AC_ARG_WITH(
 732         [preopen-mods],
 733         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
 734         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
 735 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
 736 if test "x$PREOPEN_MODS" != "xall" ; then
 737     tmpLIBS=""
 738     for mod in $PREOPEN_MODS; do
 739         tmpLIBS="$tmpLIBS module-$mod.la"
 740     done
 741     PREOPEN_MODS="$tmpLIBS"
 742     AC_SUBST(PREOPEN_MODS)
 743 fi
 744
 745 AC_ARG_WITH(
 746         [module-dir],
 747         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
 748         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
 749
 750 AC_SUBST(modlibexecdir)
 751
 752 AC_ARG_ENABLE(
 753         [force-preopen],
 754         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
 755         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
 756 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
 757
 758 AC_CONFIG_FILES([
 759 Makefile
 760 src/Makefile
 761 libpulse.pc
 762 libpulse-simple.pc
 763 libpulse-browse.pc
 764 libpulse-mainloop-glib.pc
 765 doxygen/Makefile
 766 doxygen/doxygen.conf
 767 src/pulse/version.h
 768 ])
 769 AC_OUTPUT
 770
 771 # ==========================================================================
 772 ENABLE_X11=no
 773 if test "x$HAVE_X11" = "x1" ; then
 774    ENABLE_X11=yes
 775 fi
 776
 777 ENABLE_OSS=no
 778 if test "x$HAVE_OSS" = "x1" ; then
 779    ENABLE_OSS=yes
 780 fi
 781
 782 ENABLE_ALSA=no
 783 if test "x$HAVE_ALSA" = "x1" ; then
 784    ENABLE_ALSA=yes
 785 fi
 786
 787 ENABLE_SOLARIS=no
 788 if test "x$HAVE_SOLARIS" = "x1" ; then
 789    ENABLE_SOLARIS=yes
 790 fi
 791
 792 ENABLE_GLIB20=no
 793 if test "x$HAVE_GLIB20" = "x1" ; then
 794    ENABLE_GLIB20=yes
 795 fi
 796
 797 ENABLE_GCONF=no
 798 if test "x$HAVE_GCONF" = "x1" ; then
 799    ENABLE_GCONF=yes
 800 fi
 801
 802 ENABLE_AVAHI=no
 803 if test "x$HAVE_AVAHI" = "x1" ; then
 804    ENABLE_AVAHI=yes
 805 fi
 806
 807 ENABLE_JACK=no
 808 if test "x$HAVE_JACK" = "x1" ; then
 809    ENABLE_JACK=yes
 810 fi
 811
 812 ENABLE_LIBASYNCNS=no
 813 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
 814    ENABLE_LIBASYNCNS=yes
 815 fi
 816
 817 ENABLE_LIRC=no
 818 if test "x$HAVE_LIRC" = "x1" ; then
 819    ENABLE_LIRC=yes
 820 fi
 821
 822 ENABLE_HAL=no
 823 if test "x$HAVE_HAL" = "x1" ; then
 824    ENABLE_HAL=yes
 825 fi
 826
 827 ENABLE_TCPWRAP=no
 828 if test "x${LIBWRAP_LIBS}" != x ; then
 829    ENABLE_TCPWRAP=yes
 830 fi
 831
 832 echo "
 833  ---{ $PACKAGE_NAME $VERSION }---
 834
 835     prefix:                 ${prefix}
 836     sysconfdir:             ${sysconfdir}
 837     localstatedir:          ${localstatedir}
 838     System Runtime Path:    ${PA_SYSTEM_RUNTIME_PATH}
 839     Compiler:               ${CC}
 840     CFLAGS:                 ${CFLAGS}
 841     Have X11:               ${ENABLE_X11}
 842     Enable OSS:             ${ENABLE_OSS}
 843     Enable Alsa:            ${ENABLE_ALSA}
 844     Enable Solaris:         ${ENABLE_SOLARIS}
 845     Enable GLib 2.0:        ${ENABLE_GLIB20}
 846     Enable GConf:           ${ENABLE_GCONF}
 847     Enable Avahi:           ${ENABLE_AVAHI}
 848     Enable Jack:            ${ENABLE_JACK}
 849     Enable Async DNS:       ${ENABLE_LIBASYNCNS}
 850     Enable LIRC:            ${ENABLE_LIRC}
 851     Enable HAL:             ${ENABLE_HAL}
 852     Enable TCP Wrappers:    ${ENABLE_TCPWRAP}
 853     System User:            ${PA_SYSTEM_USER}
 854     System Group:           ${PA_SYSTEM_GROUP}
 855     Realtime Group:         ${PA_REALTIME_GROUP}
 856     Access Group:           ${PA_ACCESS_GROUP}
 857 "