configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.63)
  24
  25 AC_INIT([pulseaudio],[m4_esyscmd(./git-version-gen .tarball-version)],[pulseaudio-discuss (at) lists (dot) freedesktop (dot) org],[pulseaudio],[http://pulseaudio.org/])
  26 AC_CONFIG_SRCDIR([src/daemon/main.c])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_HEADERS([config.h])
  29 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules color-tests dist-xz tar-ustar])
  30
  31 m4_define(pa_major, `echo $VERSION | cut -d. -f1 | cut -d- -f1`)
  32 m4_define(pa_minor, `echo $VERSION | cut -d. -f2 | cut -d- -f1`)
  33
  34 AC_SUBST(PA_MAJOR, pa_major)
  35 AC_SUBST(PA_MINOR, pa_minor)
  36 AC_SUBST(PA_MAJORMINOR, pa_major.pa_minor)
  37
  38 AC_SUBST(PA_API_VERSION, 12)
  39 AC_SUBST(PA_PROTOCOL_VERSION, 25)
  40
  41 # The stable ABI for client applications, for the version info x:y:z
  42 # always will hold y=z
  43 AC_SUBST(LIBPULSE_VERSION_INFO, [13:4:13])
  44
  45 # A simplified, synchronous, ABI-stable interface for client
  46 # applications, for the version info x:y:z always will hold y=z
  47 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:3:0])
  48
  49 # The ABI-stable network browsing interface for client applications,
  50 # for the version info x:y:z always will hold y=z
  51 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  52
  53 # The ABI-stable GLib adapter for client applications, for the version
  54 # info x:y:z always will hold y=z
  55 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
  56
  57 AC_CANONICAL_HOST
  58 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  59
  60 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  61
  62 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  63     AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  64     ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  65 ])
  66
  67 AM_SILENT_RULES([yes])
  68
  69
  70 #### Checks for programs. ####
  71
  72 # mkdir -p
  73
  74 AC_PROG_MKDIR_P
  75
  76 # CC
  77
  78 AC_PROG_CC
  79 AC_PROG_CC_C99
  80 AM_PROG_CC_C_O
  81 # Only required if you want the WebRTC canceller -- no runtime dep on
  82 # libstdc++ otherwise
  83 AC_PROG_CXX
  84 AC_PROG_GCC_TRADITIONAL
  85 AC_USE_SYSTEM_EXTENSIONS
  86
  87 # M4
  88
  89 AC_CHECK_PROGS([M4], gm4 m4, no)
  90 AS_IF([test "x$M4" = "xno"], AC_MSG_ERROR([m4 missing]))
  91
  92 # pkg-config
  93
  94 PKG_PROG_PKG_CONFIG
  95
  96 # gettext
  97
  98 if test "x$enable_nls" != "xno"; then
  99 IT_PROG_INTLTOOL([0.35.0])
 100 GETTEXT_PACKAGE=pulseaudio
 101 AC_SUBST([GETTEXT_PACKAGE])
 102 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 103 AM_GLIB_GNU_GETTEXT
 104
 105 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 106 AX_DEFINE_DIR(PULSE_LOCALEDIR, pulselocaledir, [Gettext locale dir])
 107 else
 108 # workaround till an intltool m4 bug is fixed upstream
 109 # (https://bugs.launchpad.net/intltool/+bug/904647)
 110 USE_NLS=no
 111 AC_SUBST(USE_NLS)
 112 fi
 113
 114
 115 #### Determine host OS ####
 116
 117 os_is_linux=0
 118 os_is_win32=0
 119 os_is_darwin=0
 120
 121 AC_MSG_CHECKING([host operating system])
 122 case "$host_os" in
 123     linux*)
 124         AC_MSG_RESULT([linux])
 125         os_is_linux=1
 126     ;;
 127     darwin*)
 128         AC_MSG_RESULT([darwin])
 129         os_is_darwin=1
 130         AC_DEFINE([OS_IS_DARWIN], 1, [Build target is Darwin.])
 131     ;;
 132     mingw*)
 133         AC_MSG_RESULT([win32])
 134         os_is_win32=1
 135         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 136     ;;
 137     *)
 138         AC_MSG_RESULT([unknown])
 139     ;;
 140 esac
 141
 142 AM_CONDITIONAL(OS_IS_DARWIN, test "x$os_is_darwin" = "x1")
 143 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 144 AC_SUBST([OS_IS_WIN32], [$os_is_win32])
 145
 146 # Platform specific hacks
 147 case "$host_os" in
 148     darwin* )
 149         AC_DEFINE([_DARWIN_C_SOURCE], [200112L], [Needed to get NSIG on Mac OS X])
 150     ;;
 151     mingw* )
 152         AC_DEFINE([WIN32_LEAN_AND_MEAN], 1, [Needed to avoid including unnecessary headers on Windows])
 153     ;;
 154     solaris* )
 155         AC_DEFINE(_XOPEN_SOURCE,       600, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 156         AC_DEFINE(__EXTENSIONS__,        1, [Needed to get declarations for msg_control and msg_controllen on Solaris])
 157     ;;
 158 esac
 159
 160
 161 #### Compiler flags ####
 162
 163 AX_APPEND_COMPILE_FLAGS(
 164     [-Wall -W -Wextra -pipe -Wno-long-long -Wvla -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing -Wwrite-strings -Wno-unused-parameter -ffast-math -Wp,-D_FORTIFY_SOURCE=2 -fno-common -fdiagnostics-show-option],
 165     [], [-pedantic -Werror])
 166
 167 # Only enable fastpath asserts when doing a debug build, e.g. from bootstrap.sh.
 168 AS_CASE([" $CFLAGS "], [*" -O0 "*], [], [AX_APPEND_FLAG(["-DFASTPATH"], [CPPFLAGS])])
 169
 170
 171 #### Linker flags ####
 172
 173 # Check whether the linker supports the -version-script option.
 174 # The Make variable $(srcdir) needs to be in the LDFLAGS in that form,
 175 # so that it is expanded the right way in every subdir.
 176 AX_CHECK_LINK_FLAG(["-Wl,-version-script=${srcdir}/src/map-file"],
 177     [VERSIONING_LDFLAGS='-Wl,-version-script=$(abs_top_srcdir)/src/map-file'])
 178 AC_SUBST([VERSIONING_LDFLAGS])
 179
 180 # Use immediate (now) bindings; avoids the funky re-call in itself.
 181 # The -z now syntax is lifted from Sun's linker and works with GNU's too, other linkers might be added later.
 182 AX_APPEND_LINK_FLAGS([-Wl,-z,now], [IMMEDIATE_LDFLAGS])
 183 AC_SUBST([IMMEDIATE_LDFLAGS])
 184
 185 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 186 # so we request the nodelete flag to be enabled.
 187 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 188 AX_APPEND_LINK_FLAGS([-Wl,-z,nodelete], [NODELETE_LDFLAGS])
 189 AC_SUBST([NODELETE_LDFLAGS])
 190
 191 # Check for the proper way to build libraries that have no undefined symbols
 192 case $host in
 193     # FreeBSD (et al.) does not complete linking for shared objects when pthreads
 194     # are requested, as different implementations are present.
 195     *-freebsd* | *-openbsd*) ;;
 196     *)
 197         for possible_flag in "-Wl,--no-undefined" "-Wl,-z,defs"; do
 198             AX_CHECK_LINK_FLAG([$possible_flag], [NOUNDEFINED_LDFLAGS="$possible_flag"; break])
 199         done
 200     ;;
 201 esac
 202 AC_SUBST([NOUNDEFINED_LDFLAGS])
 203
 204
 205 #### Atomic operations ####
 206
 207 # Native atomic operation support
 208 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 209     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]))
 210
 211 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 212     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]))
 213
 214 if test "x$enable_atomic_arm_memory_barrier" = "xyes"; then
 215     AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers])
 216 fi
 217
 218 # If everything else fails use libatomic_ops
 219 need_libatomic_ops=yes
 220
 221 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 222     pulseaudio_cv_sync_bool_compare_and_swap, [
 223     AC_LINK_IFELSE(
 224         AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
 225         [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 226         [pulseaudio_cv_sync_bool_compare_and_swap=no])
 227     ])
 228
 229 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 230     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 231     need_libatomic_ops=no
 232 else
 233     # HW specific atomic ops stuff
 234     AC_MSG_CHECKING([architecture for native atomic operations])
 235     case $host in
 236         arm*)
 237             AC_MSG_RESULT([arm])
 238             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 239             # The Linux kernel helper functions have been there since 2.6.16. However
 240             # compile time checking for kernel version in cross compile environment
 241             # (which is usually the case for arm cpu) is tricky (or impossible).
 242             if test "x$os_is_linux" = "x1" && test "x$enable_atomic_arm_linux_helpers" != "xno"; then
 243                 AC_MSG_RESULT([yes])
 244                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 245                 need_libatomic_ops=no
 246             else
 247                 AC_MSG_RESULT([no])
 248                 AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 249                     pulseaudio_cv_support_arm_atomic_ops, [
 250                     AC_COMPILE_IFELSE(
 251                         AC_LANG_PROGRAM([], [[
 252                             volatile int a=0;
 253                             int o=0, n=1, r;
 254                             asm volatile ("ldrex    %0, [%1]\n"
 255                                           "subs  %0, %0, %2\n"
 256                                           "strexeq %0, %3, [%1]\n"
 257                                           : "=&r" (r)
 258                                           : "r" (&a), "Ir" (o), "r" (n)
 259                                           : "cc");
 260                             return (a==1 ? 0 : -1);
 261                         ]]),
 262                         [pulseaudio_cv_support_arm_atomic_ops=yes],
 263                         [pulseaudio_cv_support_arm_atomic_ops=no])
 264                 ])
 265                 AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 266                     AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARM atomic instructions.])
 267                     need_libatomic_ops=no
 268                 ])
 269             fi
 270         ;;
 271         *-netbsdelf5*)
 272             AC_MSG_RESULT([yes])
 273             need_libatomic_ops=no
 274         ;;
 275         *-freebsd*)
 276             AC_MSG_RESULT([yes])
 277             need_libatomic_ops=no
 278         ;;
 279         *)
 280             AC_MSG_RESULT([unknown])
 281         ;;
 282     esac
 283 fi
 284
 285 # If we're on ARM, check for the ARMV6 instructions we need */
 286 case $host in
 287   arm*)
 288     AC_CACHE_CHECK([support for required armv6 instructions],
 289       pulseaudio_cv_support_armv6,
 290       [AC_COMPILE_IFELSE(
 291          AC_LANG_PROGRAM([],
 292            [[volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 293              asm volatile ("ldr r0, %2 \n"
 294                            "ldr r2, %3 \n"
 295                            "ldr r3, %4 \n"
 296                            "ssat r1, #8, r0 \n"
 297                            "str r1, %0 \n"
 298                            "pkhbt r1, r3, r2, LSL #8 \n"
 299                            "str r1, %1 \n"
 300                            : "=m" (a), "=m" (b)
 301                            : "m" (a), "m" (b), "m" (c)
 302                            : "r0", "r1", "r2", "r3", "cc");
 303              return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 304            ]]),
 305          [pulseaudio_cv_support_armv6=yes],
 306          [pulseaudio_cv_support_armv6=no])
 307       ])
 308     AS_IF([test "$pulseaudio_cv_support_armv6" = "yes"], [
 309         AC_DEFINE([HAVE_ARMV6], 1, [Have ARMv6 instructions.])
 310       ])
 311   ;;
 312   *)
 313   ;;
 314 esac
 315
 316
 317 #### libtool stuff ####
 318
 319 LT_PREREQ(2.2)
 320 LT_INIT([dlopen win32-dll disable-static])
 321
 322 dnl Unfortunately, even up to libtool 2.2.6a there is no way to know
 323 dnl exactly which version of libltdl is present in the system, so we
 324 dnl just assume that it's a working version as long as we have the
 325 dnl library and the header files.
 326 dnl
 327 dnl As an extra safety device, check for lt_dladvise_init() which is
 328 dnl only implemented in libtool 2.x, and refine as we go if we have
 329 dnl refined requirements.
 330 dnl
 331 dnl Check the header files first since the system may have a
 332 dnl libltdl.so for runtime, but no headers, and we want to bail out as
 333 dnl soon as possible.
 334 dnl
 335 dnl We don't need any special variable for this though, since the user
 336 dnl can give the proper place to find libltdl through the standard
 337 dnl variables like LDFLAGS and CPPFLAGS.
 338
 339 AC_CHECK_HEADER([ltdl.h],
 340     [AC_CHECK_LIB([ltdl], [lt_dladvise_init], [LIBLTDL=-lltdl], [LIBLTDL=])],
 341     [LIBLTDL=])
 342
 343 AS_IF([test "x$LIBLTDL" = "x"],
 344     [AC_MSG_ERROR([Unable to find libltdl version 2. Makes sure you have libtool 2.2 or later installed.])])
 345 AC_SUBST([LIBLTDL])
 346
 347
 348 ###################################
 349 #   Basic environment checks      #
 350 ###################################
 351
 352 #### Checks for header files. ####
 353
 354 # ISO
 355 AC_HEADER_STDC
 356
 357 # POSIX
 358 AC_CHECK_HEADERS_ONCE([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 359     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 360     sys/mman.h sys/select.h sys/socket.h sys/wait.h \
 361     sys/uio.h syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 362 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 363                  [#include <sys/types.h>
 364                   #if HAVE_NETINET_IN_H
 365                   # include <netinet/in.h>
 366                   #endif
 367                   #if HAVE_NETINET_IN_SYSTM_H
 368                   # include <netinet/in_systm.h>
 369                   #endif
 370                  ])
 371 AC_CHECK_HEADERS([sys/resource.h], [HAVE_SYS_RESOURCE_H=1], [HAVE_SYS_RESOURCE_H=0])
 372 AC_SUBST(HAVE_SYS_RESOURCE_H)
 373 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 374 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 375 AC_SUBST(HAVE_AF_UNIX)
 376
 377 # Linux
 378 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 379 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 380
 381 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 382
 383 # Solaris
 384 AC_CHECK_HEADERS_ONCE([sys/filio.h])
 385
 386 # Windows
 387 AC_CHECK_HEADERS_ONCE([windows.h winsock2.h ws2tcpip.h])
 388
 389 # NetBSD
 390 AC_CHECK_HEADERS_ONCE([sys/atomic.h])
 391
 392 # Other
 393 AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
 394 AC_CHECK_HEADERS_ONCE([byteswap.h])
 395 AC_CHECK_HEADERS_ONCE([sys/syscall.h])
 396 AC_CHECK_HEADERS_ONCE([sys/eventfd.h])
 397 AC_CHECK_HEADERS_ONCE([execinfo.h])
 398 AC_CHECK_HEADERS_ONCE([langinfo.h])
 399 AC_CHECK_HEADERS_ONCE([regex.h pcreposix.h])
 400
 401
 402 #### Typdefs, structures, etc. ####
 403
 404 AC_C_CONST
 405 AC_C_BIGENDIAN
 406 AC_TYPE_PID_T
 407 AC_TYPE_SIZE_T
 408 AC_CHECK_TYPES(ssize_t, , AC_DEFINE([ssize_t], [signed long], [Define ssize_t if it is not done by the standard libs.]))
 409 AC_TYPE_OFF_T
 410
 411 AC_TYPE_UID_T
 412 AC_CHECK_DECLS(environ)
 413
 414 # SIGXCPU
 415 AX_CHECK_DEFINE([signal.h], [SIGXCPU], [HAVE_SIGXCPU=1], [HAVE_SIGXCPU=0])
 416 AS_IF([test "x$HAVE_SIGXCPU" = "x1"], AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?]))
 417 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 418
 419 # INADDR_NONE, Solaris lacks this
 420 AX_CHECK_DEFINE([netinet/in.h], [INADDR_NONE], [],
 421     [AX_CHECK_DEFINE([winsock2.h], [INADDR_NONE], [],
 422         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 423
 424
 425 # _Bool
 426 AC_CACHE_CHECK([whether $CC knows _Bool],
 427     pulseaudio_cv__Bool,
 428     [AC_COMPILE_IFELSE(
 429         AC_LANG_PROGRAM([], [[_Bool b;]]),
 430         [pulseaudio_cv__Bool=yes],
 431         [pulseaudio_cv__Bool=no])
 432     ])
 433
 434 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.]))
 435
 436
 437 #### Thread support ####
 438
 439 AX_TLS
 440 AS_IF([test "$ac_cv_tls" == "__thread"],
 441     AC_DEFINE([SUPPORT_TLS___THREAD], 1, [Define this if the compiler supports __thread for Thread-Local Storage]))
 442
 443 # Win32 build breaks with win32 pthread installed
 444 AS_IF([test "x$os_is_win32" != "x1"],
 445   [AX_PTHREAD])
 446
 447 AS_IF([test "x$ax_pthread_ok" == "xyes"],
 448     AC_DEFINE([_POSIX_PTHREAD_SEMANTICS], 1, [Needed on Solaris]))
 449
 450
 451 #### Check for libs ####
 452
 453 # ISO
 454 AC_SEARCH_LIBS([pow], [m])
 455
 456 # POSIX
 457 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 458 AC_SEARCH_LIBS([dlopen], [dl])
 459 AC_SEARCH_LIBS([shm_open], [rt])
 460 AC_SEARCH_LIBS([inet_ntop], [nsl])
 461 AC_SEARCH_LIBS([timer_create], [rt])
 462 AC_SEARCH_LIBS([pthread_setaffinity_np], [pthread])
 463 AC_SEARCH_LIBS([pthread_getname_np], [pthread])
 464 AC_SEARCH_LIBS([pthread_setname_np], [pthread])
 465
 466 # BSD
 467 AC_SEARCH_LIBS([connect], [socket])
 468 AC_SEARCH_LIBS([backtrace], [execinfo ubacktrace])
 469
 470 # Darwin/OS X
 471 if test "x$os_is_darwin" = "x1" ; then
 472     AC_MSG_CHECKING([looking for Apple CoreService Framework])
 473     # How do I check a framework "library" - AC_CHECK_LIB prob. won't work??, just assign LIBS & hope
 474     AC_CHECK_HEADER([/Developer/Headers/FlatCarbon/CoreServices.h],
 475         [LIBS="$LIBS -framework CoreServices"],
 476         [AC_MSG_ERROR([CoreServices.h header file not found])]
 477     )
 478
 479     AC_MSG_RESULT([ok])
 480     AC_DEFINE([HAVE_CLOCK_GETTIME], 1, [Using clock_gettime() replacement])
 481     HAVE_BONJOUR=1
 482 fi
 483
 484 AM_CONDITIONAL([HAVE_BONJOUR], [test "x$HAVE_BONJOUR" = x1])
 485
 486 # Windows
 487 AC_SEARCH_LIBS([regexec], [pcreposix])
 488 # This magic is needed so we do not needlessly add static libs to the win32  build, disabling its ability to make dlls.
 489 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 490
 491
 492 #### Check for functions ####
 493
 494 # ISO
 495 AC_CHECK_FUNCS_ONCE([lrintf strtof])
 496
 497 # POSIX
 498 AC_FUNC_FORK
 499 AC_FUNC_GETGROUPS
 500 AC_CHECK_FUNCS_ONCE([chmod chown fstat fchown fchmod clock_gettime getaddrinfo getgrgid_r getgrnam_r \
 501     getpwnam_r getpwuid_r gettimeofday getuid mlock nanosleep \
 502     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 503     sigaction sleep symlink sysconf uname pthread_setaffinity_np pthread_getname_np pthread_setname_np])
 504 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 505 AC_SUBST(HAVE_MKFIFO)
 506 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 507
 508 # X/OPEN
 509 AC_CHECK_FUNCS_ONCE([readlink])
 510
 511 # SUSv2
 512 AC_CHECK_FUNCS_ONCE([ctime_r usleep])
 513
 514 # SUSv3
 515 AC_CHECK_FUNCS_ONCE([strerror_r])
 516
 517 # BSD
 518 AC_CHECK_FUNCS_ONCE([lstat])
 519
 520 # Non-standard
 521 AC_CHECK_FUNCS_ONCE([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l pipe2 accept4])
 522
 523 AC_FUNC_ALLOCA
 524
 525 AC_CHECK_FUNCS([regexec], [HAVE_REGEX=1], [HAVE_REGEX=0])
 526 AM_CONDITIONAL(HAVE_REGEX, [test "x$HAVE_REGEX" = "x1"])
 527
 528 # Large File-Support (LFS)
 529 AC_SYS_LARGEFILE
 530 # Check for open64 to know if the current system does have open64() and similar functions
 531 AC_CHECK_FUNCS_ONCE([open64])
 532
 533
 534 ###################################
 535 #      External libraries         #
 536 ###################################
 537
 538 #### [lib]iconv ####
 539
 540 AM_ICONV
 541
 542 #### X11 (optional) ####
 543
 544 AC_ARG_ENABLE([x11],
 545     AS_HELP_STRING([--disable-x11],[Disable optional X11 support]))
 546
 547 AS_IF([test "x$enable_x11" != "xno"],
 548     [PKG_CHECK_MODULES(X11, [ x11-xcb xcb >= 1.6 ice sm xtst ], HAVE_X11=1, HAVE_X11=0)],
 549     HAVE_X11=0)
 550
 551 AS_IF([test "x$enable_x11" = "xyes" && test "x$HAVE_X11" = "x0"],
 552     [AC_MSG_ERROR([*** X11 not found])])
 553
 554 AC_SUBST(X11_CFLAGS)
 555 AC_SUBST(X11_LIBS)
 556 AC_SUBST(HAVE_X11)
 557 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
 558 AS_IF([test "x$HAVE_X11" = "x1"], AC_DEFINE([HAVE_X11], 1, [Have X11?]))
 559
 560 #### Capabilities (optional) ####
 561
 562 CAP_LIBS=''
 563
 564 AC_ARG_WITH([caps],
 565     AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 566
 567 if test "x${with_caps}" != "xno"; then
 568     AC_SEARCH_LIBS([cap_init], [cap], [], [
 569                     if test "x${with_caps}" = "xyes" ; then
 570                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 571                     fi])
 572     AC_CHECK_HEADERS([sys/capability.h], [], [
 573                     if test "x${with_caps}" = "xyes" ; then
 574                         AC_MSG_ERROR([*** POSIX caps headers not found])
 575                     fi])
 576 fi
 577
 578 #### Valgrind (optional) ####
 579
 580 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 581
 582 #### json parsing ####
 583
 584 PKG_CHECK_MODULES(LIBJSON, [ json >= 0.9 ])
 585 AC_SUBST(LIBJSON_CFLAGS)
 586 AC_SUBST(LIBJSON_LIBS)
 587
 588 #### Sound file ####
 589
 590 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.20 ])
 591 AC_SUBST(LIBSNDFILE_CFLAGS)
 592 AC_SUBST(LIBSNDFILE_LIBS)
 593
 594 #### atomic-ops ####
 595
 596 AC_MSG_CHECKING([whether we need libatomic_ops])
 597 if test "x$need_libatomic_ops" = "xyes"; then
 598     AC_MSG_RESULT([yes])
 599     AC_CHECK_HEADERS([atomic_ops.h],
 600         [CFLAGS="$CFLAGS -DAO_REQUIRE_CAS"],
 601         [AC_MSG_ERROR([*** libatomic-ops headers not found])])
 602
 603     # Win32 does not need the lib and breaks horribly if we try to include it
 604     AS_IF([test "x$os_is_win32" != "x1"], [LIBS="$LIBS -latomic_ops"])
 605 else
 606     AC_MSG_RESULT([no])
 607 fi
 608
 609 #### Libsamplerate support (optional) ####
 610
 611 AC_ARG_ENABLE([samplerate],
 612     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]))
 613
 614 AS_IF([test "x$enable_samplerate" != "xno"],
 615     [PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ], HAVE_LIBSAMPLERATE=1, HAVE_LIBSAMPLERATE=0)],
 616     HAVE_LIBSAMPLERATE=0)
 617
 618 AS_IF([test "x$enable_samplerate" = "xyes" && test "x$HAVE_LIBSAMPLERATE" = "x0"],
 619     [AC_MSG_ERROR([*** Libsamplerate not found])])
 620
 621 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 622 AC_SUBST(LIBSAMPLERATE_LIBS)
 623 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 624 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?]))
 625
 626 #### Database support ####
 627
 628 AC_ARG_WITH([database],
 629     AS_HELP_STRING([--with-database=auto|tdb|gdbm|simple],[Choose database backend.]),[],[with_database=auto])
 630
 631
 632 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xtdb"],
 633     [PKG_CHECK_MODULES(TDB, [ tdb ], HAVE_TDB=1, HAVE_TDB=0)],
 634     HAVE_TDB=0)
 635 AS_IF([test "x$HAVE_TDB" = "x1"], with_database=tdb)
 636
 637 AS_IF([test "x$with_database" = "xtdb" && test "x$HAVE_TDB" = "x0"],
 638     [AC_MSG_ERROR([*** tdb not found])])
 639
 640
 641 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xgdbm"],
 642     [
 643         HAVE_GDBM=1
 644         AC_CHECK_LIB(gdbm, gdbm_open, [], HAVE_GDBM=0)
 645         AC_CHECK_HEADERS(gdbm.h, [], HAVE_GDBM=0)
 646     ],
 647     HAVE_GDBM=0)
 648 AS_IF([test "x$HAVE_GDBM" = "x1"],
 649     [
 650         with_database=gdbm
 651         GDBM_CFLAGS=
 652         GDBM_LIBS=-lgdbm
 653     ])
 654
 655 AS_IF([test "x$with_database" = "xgdbm" && test "x$HAVE_GDBM" = "x0"],
 656     [AC_MSG_ERROR([*** gdbm not found])])
 657
 658
 659 AS_IF([test "x$with_database" = "xauto" -o "x$with_database" = "xsimple"],
 660     HAVE_SIMPLEDB=1,
 661     HAVE_SIMPLEDB=0)
 662 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], with_database=simple)
 663
 664 AS_IF([test "x$HAVE_TDB" != x1 -a "x$HAVE_GDBM" != x1 -a "x$HAVE_SIMPLEDB" != x1],
 665     AC_MSG_ERROR([*** missing database backend]))
 666
 667
 668 AC_SUBST(TDB_CFLAGS)
 669 AC_SUBST(TDB_LIBS)
 670 AM_CONDITIONAL([HAVE_TDB], [test "x$HAVE_TDB" = x1])
 671 AS_IF([test "x$HAVE_TDB" = "x1"], AC_DEFINE([HAVE_TDB], 1, [Have tdb?]))
 672
 673 AC_SUBST(GDBM_CFLAGS)
 674 AC_SUBST(GDBM_LIBS)
 675 AM_CONDITIONAL([HAVE_GDBM], [test "x$HAVE_GDBM" = x1])
 676 AS_IF([test "x$HAVE_GDBM" = "x1"], AC_DEFINE([HAVE_GDBM], 1, [Have gdbm?]))
 677
 678 AM_CONDITIONAL([HAVE_SIMPLEDB], [test "x$HAVE_SIMPLEDB" = x1])
 679 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], AC_DEFINE([HAVE_SIMPLEDB], 1, [Have simple?]))
 680
 681 #### OSS support (optional) ####
 682
 683 AC_ARG_ENABLE([oss-output],
 684     AS_HELP_STRING([--disable-oss-output],[Disable optional OSS output support]))
 685
 686 AC_ARG_ENABLE([oss-wrapper],
 687     AS_HELP_STRING([--disable-oss-wrapper],[Disable optional OSS wrapper support]))
 688
 689 AS_IF([test "x$enable_oss_output" != "xno" -o "x$enable_oss_wrapper" != "xno"],
 690     [AC_CHECK_HEADERS([sys/soundcard.h], HAVE_OSS=1, HAVE_OSS=0)],
 691     HAVE_OSS=0)
 692
 693 AS_IF([test "x$enable_oss_output" = "xyes" -o "x$enable_oss_wrapper" = "xyes" && test "x$HAVE_OSS" = "x0"],
 694     [AC_MSG_ERROR([*** OSS support not found])])
 695
 696 AS_IF([test "x$enable_oss_output" != "xno"],
 697     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_OUTPUT=1, HAVE_OSS_OUTPUT=0)],
 698     HAVE_OSS_OUTPUT=0)
 699
 700 AS_IF([test "x$enable_oss_wrapper" != "xno"],
 701     [AS_IF([test "x$HAVE_OSS" = "x1"], HAVE_OSS_WRAPPER=1, HAVE_OSS_WRAPPER=0)],
 702     HAVE_OSS_WRAPPER=0)
 703
 704 AC_SUBST(HAVE_OSS_OUTPUT)
 705 AM_CONDITIONAL([HAVE_OSS_OUTPUT], [test "x$HAVE_OSS_OUTPUT" = "x1"])
 706 AM_CONDITIONAL([HAVE_OSS_WRAPPER], [test "x$HAVE_OSS_WRAPPER" = "x1"])
 707 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], AC_DEFINE([HAVE_OSS_OUTPUT], 1, [Have OSS output?]))
 708 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], AC_DEFINE([HAVE_OSS_WRAPPER], 1, [Have OSS wrapper (padsp)?]))
 709
 710 #### CoreAudio support (optional) ####
 711
 712 AC_ARG_ENABLE([coreaudio-output],
 713     AS_HELP_STRING([--disable-coreaudio-output],[Disable optional CoreAudio output support]))
 714
 715 AS_IF([test "x$enable_coreaudio_output" != "xno"],
 716     [AC_CHECK_HEADERS([CoreAudio/CoreAudio.h], HAVE_COREAUDIO=1, HAVE_COREAUDIO=0)],
 717     HAVE_COREAUDIO=0)
 718
 719 AS_IF([test "x$enable_coreaudio_output" = "xyes" && test "x$HAVE_COREAUDIO" = "x0"],
 720     [AC_MSG_ERROR([*** CoreAudio output support not found])])
 721
 722 AM_CONDITIONAL([HAVE_COREAUDIO], [test "x$HAVE_COREAUDIO" = "x1" && test "x$enable_coreaudio_output" != "xno"])
 723
 724 #### ALSA support (optional) ####
 725
 726 AC_ARG_ENABLE([alsa],
 727     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]))
 728
 729 AS_IF([test "x$enable_alsa" != "xno"],
 730     [PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.19 ], HAVE_ALSA=1, HAVE_ALSA=0)],
 731     HAVE_ALSA=0)
 732
 733 AS_IF([test "x$enable_alsa" = "xyes" && test "x$HAVE_ALSA" = "x0"],
 734     [AC_MSG_ERROR([*** Needed alsa >= 1.0.19 support not found])])
 735
 736 AC_SUBST(ASOUNDLIB_CFLAGS)
 737 AC_SUBST(ASOUNDLIB_LIBS)
 738 AC_SUBST(HAVE_ALSA)
 739 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 740 AS_IF([test "x$HAVE_ALSA" = "x1"], AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?]))
 741
 742 #### EsounD support (optional) ####
 743
 744 AC_ARG_ENABLE([esound],
 745     AS_HELP_STRING([--disable-esound],[Disable optional EsounD support]))
 746 AM_CONDITIONAL([HAVE_ESOUND], [test "x$enable_esound" != "xno"])
 747 AS_IF([test "x$enable_esound" != "xno"], [HAVE_ESOUND=1])
 748
 749 #### Solaris audio support (optional) ####
 750
 751 AC_ARG_ENABLE([solaris],
 752     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]))
 753
 754 AS_IF([test "x$enable_solaris" != "xno"],
 755     [AC_CHECK_HEADERS([sys/audio.h], HAVE_SOLARIS=1, HAVE_SOLARIS=0)],
 756     HAVE_SOLARIS=0)
 757
 758 AS_IF([test "x$enable_solaris" = "xyes" && test "x$HAVE_SOLARIS" = "x0"],
 759     [AC_MSG_ERROR([*** Solaris audio support not found])])
 760
 761 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 762 AS_IF([test "x$HAVE_SOLARIS" = "x1"], AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?]))
 763
 764 #### WaveOut audio support (optional) ####
 765
 766 AC_ARG_ENABLE([waveout],
 767     AS_HELP_STRING([--disable-waveout],[Disable optional WaveOut audio support]))
 768
 769 AS_IF([test "x$enable_waveout" != "xno"],
 770     [AC_CHECK_HEADERS([mmsystem.h], HAVE_WAVEOUT=1, HAVE_WAVEOUT=0, [#include <windows.h>])],
 771     HAVE_WAVEOUT=0)
 772
 773 AS_IF([test "x$enable_waveout" = "xyes" && test "x$HAVE_WAVEOUT" = "x0"],
 774     [AC_MSG_ERROR([*** WaveOut audio support not found])])
 775
 776 AC_SUBST(HAVE_WAVEOUT)
 777 AM_CONDITIONAL([HAVE_WAVEOUT], [test "x$HAVE_WAVEOUT" = x1])
 778 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], AC_DEFINE([HAVE_WAVEOUT], 1, [Have WaveOut audio?]))
 779
 780 #### GLib 2 support (optional) ####
 781
 782 AC_ARG_ENABLE([glib2],
 783     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]))
 784
 785 AS_IF([test "x$enable_glib2" != "xno"],
 786     [PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ], HAVE_GLIB20=1, HAVE_GLIB20=0)],
 787     HAVE_GLIB20=0)
 788
 789 AS_IF([test "x$enable_glib2" = "xyes" && test "x$HAVE_GLIB20" = "x0"],
 790     [AC_MSG_ERROR([*** GLib 2 support not found])])
 791
 792 AC_SUBST(GLIB20_CFLAGS)
 793 AC_SUBST(GLIB20_LIBS)
 794 AC_SUBST(HAVE_GLIB20)
 795 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 796 AS_IF([test "x$HAVE_GLIB20" = "x1"], AC_DEFINE([HAVE_GLIB], 1, [Have GLIB?]))
 797
 798 #### GTK2 support (optional) ####
 799
 800 AC_ARG_ENABLE([gtk2],
 801     AS_HELP_STRING([--disable-gtk2],[Disable optional Gtk+ 2 support]))
 802
 803 AS_IF([test "x$enable_gtk2" != "xno"],
 804     [PKG_CHECK_MODULES(GTK20, [ gtk+-2.0 >= 2.4.0 ], HAVE_GTK20=1, HAVE_GTK20=0)],
 805     HAVE_GTK20=0)
 806
 807 AS_IF([test "x$enable_gtk2" = "xyes" && test "x$HAVE_GTK20" = "x0"],
 808     [AC_MSG_ERROR([*** Gtk+ 2 support not found])])
 809
 810 AC_SUBST(GTK20_CFLAGS)
 811 AC_SUBST(GTK20_LIBS)
 812 AM_CONDITIONAL([HAVE_GTK20], [test "x$HAVE_GTK20" = x1])
 813 AS_IF([test "x$HAVE_GTK20" = "x1"], AC_DEFINE([HAVE_GTK], 1, [Have GTK?]))
 814
 815 #### GConf support (optional) ####
 816
 817 AC_ARG_ENABLE([gconf],
 818     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]))
 819
 820 AS_IF([test "x$enable_gconf" != "xno"],
 821     [PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 gobject-2.0 ], HAVE_GCONF=1, HAVE_GCONF=0)],
 822     HAVE_GCONF=0)
 823
 824 AS_IF([test "x$enable_gconf" = "xyes" && test "x$HAVE_GCONF" = "x0"],
 825     [AC_MSG_ERROR([*** GConf support not found])])
 826
 827 AC_SUBST(GCONF_CFLAGS)
 828 AC_SUBST(GCONF_LIBS)
 829 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 830
 831 #### Avahi support (optional) ####
 832
 833 AC_ARG_ENABLE([avahi],
 834     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]))
 835
 836 AS_IF([test "x$enable_avahi" != "xno"],
 837     [PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ], HAVE_AVAHI=1, HAVE_AVAHI=0)],
 838     HAVE_AVAHI=0)
 839
 840 AS_IF([test "x$enable_avahi" = "xyes" && test "x$HAVE_AVAHI" = "x0"],
 841     [AC_MSG_ERROR([*** Avahi support not found])])
 842
 843 AC_SUBST(AVAHI_CFLAGS)
 844 AC_SUBST(AVAHI_LIBS)
 845 AC_SUBST(HAVE_AVAHI)
 846 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 847
 848 #### JACK (optional) ####
 849
 850 AC_ARG_ENABLE([jack],
 851     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]))
 852
 853 AS_IF([test "x$enable_jack" != "xno"],
 854     [PKG_CHECK_MODULES(JACK, [ jack >= 0.117.0 ], HAVE_JACK=1, HAVE_JACK=0)],
 855     HAVE_JACK=0)
 856
 857 AS_IF([test "x$enable_jack" = "xyes" && test "x$HAVE_JACK" = "x0"],
 858     [AC_MSG_ERROR([*** JACK support not found])])
 859
 860 AC_SUBST(JACK_CFLAGS)
 861 AC_SUBST(JACK_LIBS)
 862 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 863
 864 #### Async DNS support (optional) ####
 865
 866 AC_ARG_ENABLE([asyncns],
 867     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]))
 868
 869 AS_IF([test "x$enable_asyncns" != "xno"],
 870     [PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ], HAVE_LIBASYNCNS=1, HAVE_LIBASYNCNS=0)],
 871     HAVE_LIBASYNCNS=0)
 872
 873 AS_IF([test "x$enable_asyncns" = "xyes" && test "x$HAVE_LIBASYNCNS" = "x0"],
 874     [AC_MSG_ERROR([*** Async DNS support not found])])
 875
 876 AC_SUBST(LIBASYNCNS_CFLAGS)
 877 AC_SUBST(LIBASYNCNS_LIBS)
 878 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 879 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?]))
 880
 881 #### TCP wrappers (optional) ####
 882
 883 AC_ARG_ENABLE([tcpwrap],
 884     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]))
 885
 886 AS_IF([test "x$enable_tcpwrap" != "xno"],
 887     [
 888         ACX_LIBWRAP
 889         AS_IF([test "x$LIBWRAP_LIBS" != "x"], HAVE_TCPWRAP=1, HAVE_TCPWRAP=0)
 890     ],
 891     HAVE_TCPWRAP=0)
 892
 893 AS_IF([test "x$enable_tcpwrap" = "xyes" && test "x$HAVE_TCPWRAP" = "x0"],
 894     [AC_MSG_ERROR([*** TCP wrappers support not found])])
 895
 896 AC_SUBST(LIBWRAP_LIBS)
 897
 898 #### LIRC support (optional) ####
 899
 900 AC_ARG_ENABLE([lirc],
 901     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]))
 902
 903 LIRC_CFLAGS=
 904 LIRC_LIBS=
 905
 906 AS_IF([test "x$enable_lirc" != "xno"],
 907     [
 908         HAVE_LIRC=1
 909         AC_CHECK_HEADER(lirc/lirc_client.h, [], [HAVE_LIRC=0])
 910         AC_CHECK_LIB(lirc_client, lirc_init, [LIRC_LIBS=-llirc_client], [HAVE_LIRC=0])
 911     ],
 912     HAVE_LIRC=0)
 913
 914 AS_IF([test "x$enable_lirc" = "xyes" && test "x$HAVE_LIRC" = "x0"],
 915     [AC_MSG_ERROR([*** LIRC support not found])])
 916
 917 AC_SUBST(LIRC_CFLAGS)
 918 AC_SUBST(LIRC_LIBS)
 919 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 920
 921 #### D-Bus support (optional) ####
 922
 923 AC_ARG_ENABLE([dbus],
 924     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]))
 925
 926 AS_IF([test "x$enable_dbus" != "xno"],
 927     [PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.0 ], HAVE_DBUS=1, HAVE_DBUS=0)],
 928     HAVE_DBUS=0)
 929
 930 AS_IF([test "x$enable_dbus" = "xyes" && test "x$HAVE_DBUS" = "x0"],
 931     [AC_MSG_ERROR([*** D-Bus (1.3.0+) support not found])])
 932
 933 AS_IF([test "x$HAVE_DBUS" = "x1"],
 934     [
 935         save_CFLAGS="$CFLAGS"; CFLAGS="$CFLAGS $DBUS_CFLAGS"
 936         save_LIBS="$LIBS"; LIBS="$LIBS $DBUS_LIBS"
 937         AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 938         CFLAGS="$save_CFLAGS"
 939         LIBS="$save_LIBS"
 940     ])
 941
 942 AC_SUBST(DBUS_CFLAGS)
 943 AC_SUBST(DBUS_LIBS)
 944 AC_SUBST(HAVE_DBUS)
 945 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 946 AS_IF([test "x$HAVE_DBUS" = "x1"], AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.]))
 947
 948 PA_MACHINE_ID="${localstatedir}/lib/dbus/machine-id"
 949 AX_DEFINE_DIR(PA_MACHINE_ID, PA_MACHINE_ID, [D-Bus machine-id file])
 950 PA_MACHINE_ID_FALLBACK="${sysconfdir}/machine-id"
 951 AX_DEFINE_DIR(PA_MACHINE_ID_FALLBACK, PA_MACHINE_ID_FALLBACK,
 952               [Fallback machine-id file])
 953
 954 #### HAL support (optional), dependant on D-Bus ####
 955
 956 AC_ARG_ENABLE([hal],
 957     AS_HELP_STRING([--disable-hal],[Disable optional HAL support]))
 958
 959 AS_IF([test "x$enable_hal" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
 960     [PKG_CHECK_MODULES(HAL, [ hal >= 0.5.11 ], HAVE_HAL=1, HAVE_HAL=0)],
 961     HAVE_HAL=0)
 962 AS_IF([test "x$HAVE_DBUS" != "x1"], HAVE_HAL=0)
 963
 964 AS_IF([test "x$enable_hal" = "xyes" && test "x$HAVE_HAL" = "x0"],
 965     [AC_MSG_ERROR([*** HAL support not found (requires D-Bus)])])
 966
 967 AC_SUBST(HAL_CFLAGS)
 968 AC_SUBST(HAL_LIBS)
 969 AC_SUBST(HAVE_HAL)
 970 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 971 AS_IF([test "x$HAVE_HAL" = "x1"], AC_DEFINE([HAVE_HAL], 1, [Have HAL.]))
 972
 973 #### BlueZ support (optional, dependant on D-Bus) ####
 974
 975 AC_ARG_ENABLE([bluez],
 976     AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]))
 977
 978 AS_IF([test "x$enable_bluez" != "xno"],
 979     [PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ], HAVE_BLUEZ=1, HAVE_BLUEZ=0)],
 980     HAVE_BLUEZ=0)
 981 AS_IF([test "x$HAVE_DBUS" != "x1"], HAVE_BLUEZ=0)
 982
 983 AS_IF([test "x$enable_bluez" = "xyes" && test "x$HAVE_BLUEZ" = "x0"],
 984     [AC_MSG_ERROR([*** BLUEZ support not found (requires D-Bus)])])
 985
 986 AC_SUBST(BLUEZ_CFLAGS)
 987 AC_SUBST(BLUEZ_LIBS)
 988 AC_SUBST(HAVE_BLUEZ)
 989 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 990
 991 #### UDEV support (optional) ####
 992
 993 AC_ARG_ENABLE([udev],
 994     AS_HELP_STRING([--disable-udev],[Disable optional UDEV support]))
 995
 996 AS_IF([test "x$enable_udev" != "xno" -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \)],
 997     [PKG_CHECK_MODULES(UDEV, [ libudev >= 143 ], HAVE_UDEV=1, HAVE_UDEV=0)],
 998     HAVE_UDEV=0)
 999
1000 AS_IF([test "x$enable_udev" = "xyes" && test "x$HAVE_UDEV" = "x0"],
1001     [AC_MSG_ERROR([*** UDEV support not found])])
1002
1003 AC_SUBST(UDEV_CFLAGS)
1004 AC_SUBST(UDEV_LIBS)
1005 AC_SUBST(HAVE_UDEV)
1006 AM_CONDITIONAL([HAVE_UDEV], [test "x$HAVE_UDEV" = x1])
1007 AS_IF([test "x$HAVE_UDEV" = "x1"], AC_DEFINE([HAVE_UDEV], 1, [Have UDEV.]))
1008
1009 #### HAL compat support (optional, dependant on UDEV) ####
1010
1011 AC_ARG_ENABLE([hal-compat],
1012     AS_HELP_STRING([--disable-hal-compat],[Disable optional HAL->udev transition compatibility support]))
1013
1014 AS_IF([test "x$enable_hal_compat" != "xno"],
1015     [AS_IF([test "x$HAVE_HAL" = "x0" -a "x$HAVE_UDEV" = "x1"], HAVE_HAL_COMPAT=1, HAVE_HAL_COMPAT=0)],
1016     HAVE_HAL_COMPAT=0)
1017
1018 AS_IF([test "x$enable_hal_compat" = "xyes" && test "x$HAVE_HAL_COMPAT" = "x0"],
1019     [AC_MSG_ERROR([*** HAL-compat support requires UDEV and no HAL])])
1020
1021 AM_CONDITIONAL([HAVE_HAL_COMPAT], [test "x$HAVE_HAL_COMPAT" = x1])
1022 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], AC_DEFINE([HAVE_HAL_COMPAT], 1, [Have HAL compatibility.]))
1023
1024 #### IPv6 connection support (optional) ####
1025
1026 AC_ARG_ENABLE([ipv6],
1027     AS_HELP_STRING([--disable-ipv6],[Disable optional IPv6 support]))
1028
1029 AS_IF([test "x$enable_ipv6" != "xno"], [HAVE_IPV6=1], [HAVE_IPV6=0])
1030
1031 AS_IF([test "x$HAVE_IPV6" = "x1"], AC_DEFINE([HAVE_IPV6], 1, [Define this to enable IPv6 connection support]))
1032
1033 #### OpenSSL support (optional) ####
1034
1035 AC_ARG_ENABLE([openssl],
1036     AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]))
1037
1038 AS_IF([test "x$enable_openssl" != "xno"],
1039     [PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ], HAVE_OPENSSL=1, HAVE_OPENSSL=0)],
1040     HAVE_OPENSSL=0)
1041
1042 AS_IF([test "x$enable_openssl" = "xyes" && test "x$HAVE_OPENSSL" = "x0"],
1043     [AC_MSG_ERROR([*** OpenSSL support not found])])
1044
1045 AC_SUBST(OPENSSL_CFLAGS)
1046 AC_SUBST(OPENSSL_LIBS)
1047 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1048 AS_IF([test "x$HAVE_OPENSSL" = "x1"], AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL]))
1049
1050 #### FFTW (optional) ####
1051
1052 AC_ARG_WITH([fftw],
1053     AS_HELP_STRING([--without-fftw],[Omit FFTW-using modules (equalizer)]))
1054
1055 AS_IF([test "x$with_fftw" != "xno"],
1056     [PKG_CHECK_MODULES(FFTW, [ fftw3f ], HAVE_FFTW=1, HAVE_FFTW=0)],
1057     HAVE_FFTW=0)
1058
1059 AS_IF([test "x$with_fftw" = "xyes" && test "x$HAVE_FFTW" = "x0"],
1060     [AC_MSG_ERROR([*** FFTW support not found])])
1061
1062 AM_CONDITIONAL([HAVE_FFTW], [test "x$HAVE_FFTW" = "x1"])
1063
1064 #### speex (optional) ####
1065
1066 AC_ARG_WITH([speex],
1067     AS_HELP_STRING([--without-speex],[Omit speex (resampling, AEC)]))
1068
1069 AS_IF([test "x$with_speex" != "xno"],
1070     [PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ], HAVE_SPEEX=1, HAVE_SPEEX=0)],
1071     HAVE_SPEEX=0)
1072
1073 AS_IF([test "x$with_speex" = "xyes" && test "x$HAVE_SPEEX" = "x0"],
1074     [AC_MSG_ERROR([*** speex support not found])])
1075
1076 AM_CONDITIONAL([HAVE_SPEEX], [test "x$HAVE_SPEEX" = "x1"])
1077 AS_IF([test "x$HAVE_SPEEX" = "x1"], AC_DEFINE([HAVE_SPEEX], 1, [Have speex]))
1078
1079 AC_SUBST(LIBSPEEX_CFLAGS)
1080 AC_SUBST(LIBSPEEX_LIBS)
1081
1082 #### ORC (optional) ####
1083
1084 ORC_CHECK([0.4.11])
1085
1086 #### Build and Install man pages ####
1087
1088 AC_ARG_ENABLE([manpages],
1089     AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]))
1090
1091 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$enable_manpages" != "xno"])
1092
1093 #### PulseAudio system group & user  #####
1094
1095 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1096 if test -z "$with_system_user" ; then
1097     PA_SYSTEM_USER=pulse
1098 else
1099     PA_SYSTEM_USER=$with_system_user
1100 fi
1101 AC_SUBST(PA_SYSTEM_USER)
1102 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1103
1104 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1105 if test -z "$with_system_group" ; then
1106     PA_SYSTEM_GROUP=pulse
1107 else
1108     PA_SYSTEM_GROUP=$with_system_group
1109 fi
1110 AC_SUBST(PA_SYSTEM_GROUP)
1111 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1112
1113 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1114 if test -z "$with_access_group" ; then
1115     PA_ACCESS_GROUP=pulse-access
1116 else
1117     PA_ACCESS_GROUP=$with_access_group
1118 fi
1119 AC_SUBST(PA_ACCESS_GROUP)
1120 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1121
1122 AC_ARG_ENABLE([per-user-esound-socket],
1123     AS_HELP_STRING([--disable-per-user-esound-socket],[Use global esound socket directory /tmp/.esd/socket.]))
1124
1125 if test "x$enable_per_user_esound_socket" != "xno"; then
1126     USE_PER_USER_ESOUND_SOCKET=1
1127     AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1128 else
1129     USE_PER_USER_ESOUND_SOCKET=0
1130 fi
1131
1132 #### PulseAudio system runtime dir ####
1133
1134 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1135 AX_DEFINE_DIR(PA_SYSTEM_RUNTIME_PATH, PA_SYSTEM_RUNTIME_PATH, [System runtime dir])
1136 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1137 AX_DEFINE_DIR(PA_SYSTEM_CONFIG_PATH, PA_SYSTEM_CONFIG_PATH, [System config dir])
1138 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1139 AX_DEFINE_DIR(PA_SYSTEM_STATE_PATH, PA_SYSTEM_STATE_PATH, [System state dir])
1140
1141 PA_BINARY=${bindir}/pulseaudio${EXEEXT}
1142 AX_DEFINE_DIR(PA_BINARY, PA_BINARY, [Location of pulseaudio binary])
1143
1144 PACTL_BINARY=${bindir}/pactl${EXEEXT}
1145 AX_DEFINE_DIR(PACTL_BINARY, PACTL_BINARY, [Location of pactl binary])
1146
1147 AC_SUBST(PA_SOEXT, [.so])
1148
1149 AC_SUBST(pulseconfdir, ["${sysconfdir}/pulse"])
1150 AX_DEFINE_DIR(PA_DEFAULT_CONFIG_DIR, pulseconfdir, [Location of configuration files])
1151
1152 AC_DEFINE_UNQUOTED(PA_BUILDDIR, "${ac_pwd}/src", [Location of uninstalled binaries])
1153
1154 #### Mac OSX specific stuff #####
1155
1156 AC_ARG_ENABLE(mac-universal,
1157     AS_HELP_STRING([--enable-mac-universal], [Build Mac universal binaries]),
1158     enable_mac_universal=$enableval, enable_mac_universal="no")
1159
1160 AC_ARG_WITH(mac-version-min,
1161     AS_HELP_STRING([--with-mac-version-min=<version>], [Defines the earliest version of MacOS X that the executables will run on.]),
1162     mac_version_min=$withval, mac_version_min="10.5")
1163
1164 AC_ARG_WITH(mac-sysroot,
1165     AS_HELP_STRING([--with-mac-sysroot=<path>], [SDK basedir to use as the logical root directory for headers and libraries.]),
1166     mac_sysroot=$withval, mac_sysroot="/Developer/SDKs/MacOSX10.5.sdk")
1167
1168 if test "x$os_is_darwin" = "x1" ; then
1169     LDFLAGS="$LDFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1170     CFLAGS="$CFLAGS -isysroot $mac_sysroot -mmacosx-version-min=$mac_version_min"
1171
1172     if test "x$enable_mac_universal" = "xyes" ; then
1173         mac_arches="-arch i386 -arch x86_64"
1174         LDFLAGS="$LDFLAGS $mac_arches"
1175         CFLAGS="$CFLAGS $mac_arches"
1176     fi
1177 fi
1178
1179 AC_ARG_ENABLE([webrtc-aec],
1180     AS_HELP_STRING([--enable-webrtc-aec], [Enable the optional WebRTC-based echo canceller]))
1181
1182 AS_IF([test "x$enable_webrtc_aec" != "xno"],
1183     [PKG_CHECK_MODULES(WEBRTC, [ webrtc-audio-processing ], [HAVE_WEBRTC=1], [HAVE_WEBRTC=0])],
1184     [HAVE_WEBRTC=0])
1185
1186 AS_IF([test "x$enable_webrtc_aec" = "xyes" && test "x$HAVE_WEBRTC" = "x0"],
1187     [AC_MSG_ERROR([*** webrtc-audio-processing library not found])])
1188
1189 AC_SUBST(WEBRTC_CFLAGS)
1190 AC_SUBST(WEBRTC_LIBS)
1191 AM_CONDITIONAL([HAVE_WEBRTC], [test "x$HAVE_WEBRTC" = "x1"])
1192
1193 AC_ARG_ENABLE([adrian-aec],
1194     AS_HELP_STRING([--enable-adrian-aec], [Enable Adrian's optional echo canceller]))
1195 AS_IF([test "x$enable_adrian_aec" != "xno"],
1196     [HAVE_ADRIAN_EC=1])
1197 AM_CONDITIONAL([HAVE_ADRIAN_EC], [test "x$HAVE_ADRIAN_EC" = "x1"])
1198
1199
1200
1201 ###################################
1202 #            Output               #
1203 ###################################
1204
1205 AC_DEFINE_UNQUOTED(PA_CFLAGS, "$CFLAGS", [The CFLAGS used during compilation])
1206
1207 # Check whether to build tests by default (as compile-test) or not
1208 AC_ARG_ENABLE([default-build-tests],
1209     AS_HELP_STRING([--disable-default-build-tests], [Build test programs only during make check]))
1210 AM_CONDITIONAL([BUILD_TESTS_DEFAULT], [test "x$enable_default_build_tests" != "xno"])
1211
1212 AC_ARG_ENABLE([legacy-runtime-dir],
1213         AS_HELP_STRING([--disable-legacy-runtime-dir], [Try to connect on legacy (< 0.9.12) socket paths.]))
1214 if test "x$enable_legacy_runtime_dir" != "xno" ; then
1215         AC_DEFINE(ENABLE_LEGACY_RUNTIME_DIR, [1], [Legacy runtime dir])
1216 fi
1217
1218 AC_ARG_ENABLE([legacy-database-entry-format],
1219         AS_HELP_STRING([--disable-legacy-database-entry-format], [Try to load legacy (< 1.0) database files (card, device and volume restore).]))
1220 if test "x$enable_legacy_database_entry_format" != "xno" ; then
1221         AC_DEFINE(ENABLE_LEGACY_DATABASE_ENTRY_FORMAT, [1], [Legacy database entry format])
1222 fi
1223 AC_DEFINE([WIBBLE], 1, [Just a test.])
1224
1225 AC_ARG_ENABLE([static-bins],
1226     AS_HELP_STRING([--enable-static-bins],[Statically link executables.]))
1227 AM_CONDITIONAL([STATIC_BINS], [test "x$enable_static_bins" = "xyes"])
1228
1229 AC_ARG_WITH(
1230         [preopen-mods],
1231         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1232         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1233 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1234 if test "x$PREOPEN_MODS" != "xall" ; then
1235     tmpLIBS=""
1236     for mod in $PREOPEN_MODS; do
1237         tmpLIBS="$tmpLIBS module-$mod.la"
1238     done
1239     PREOPEN_MODS="$tmpLIBS"
1240     AC_SUBST(PREOPEN_MODS)
1241 fi
1242
1243 AC_ARG_WITH(
1244         [module-dir],
1245         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules]),
1246         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules"])
1247
1248 AC_SUBST(modlibexecdir)
1249 AX_DEFINE_DIR(PA_DLSEARCHPATH, modlibexecdir, [Modules dir])
1250
1251 AC_ARG_WITH(
1252         [udev-rules-dir],
1253         AS_HELP_STRING([--with-udev-rules-dir],[Directory where to install udev rules to (defaults to /lib/udev/rules.d)]),
1254         [udevrulesdir=$withval], [udevrulesdir="/lib/udev/rules.d"])
1255
1256 AC_SUBST(udevrulesdir)
1257
1258 AC_ARG_ENABLE([force-preopen],
1259     AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]))
1260
1261 if test "x$enable_force_preopen" = "xyes"; then
1262     FORCE_PREOPEN=yes
1263 else
1264     FORCE_PREOPEN=no
1265 fi
1266
1267 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1268
1269 AC_CONFIG_FILES([
1270 Makefile
1271 src/Makefile
1272 man/Makefile
1273 libpulse.pc
1274 libpulse-simple.pc
1275 libpulse-mainloop-glib.pc
1276 doxygen/Makefile
1277 doxygen/doxygen.conf
1278 src/pulse/version.h
1279 po/Makefile.in
1280 man/pulseaudio.1.xml
1281 man/esdcompat.1.xml
1282 man/pax11publish.1.xml
1283 man/paplay.1.xml
1284 man/pacat.1.xml
1285 man/pacmd.1.xml
1286 man/pactl.1.xml
1287 man/pasuspender.1.xml
1288 man/padsp.1.xml
1289 man/pulse-daemon.conf.5.xml
1290 man/pulse-client.conf.5.xml
1291 man/default.pa.5.xml
1292 man/start-pulseaudio-kde.1.xml
1293 man/start-pulseaudio-x11.1.xml
1294 ])
1295
1296 AC_CONFIG_FILES([src/esdcompat:src/daemon/esdcompat.in], [chmod +x src/esdcompat])
1297 AC_CONFIG_FILES([src/start-pulseaudio-x11:src/daemon/start-pulseaudio-x11.in], [chmod +x src/start-pulseaudio-x11])
1298 AC_CONFIG_FILES([src/start-pulseaudio-kde:src/daemon/start-pulseaudio-kde.in], [chmod +x src/start-pulseaudio-kde])
1299 AC_CONFIG_FILES([src/client.conf:src/pulse/client.conf.in])
1300 AC_CONFIG_FILES([src/daemon.conf:src/daemon/daemon.conf.in],
1301     [m4 src/daemon.conf > src/daemon.conf.gen && mv src/daemon.conf.gen src/daemon.conf])
1302 AC_CONFIG_FILES([src/default.pa:src/daemon/default.pa.in],
1303     [m4 src/default.pa > src/default.pa.gen && mv src/default.pa.gen src/default.pa])
1304 AC_CONFIG_FILES([src/system.pa:src/daemon/system.pa.in],
1305     [m4 src/system.pa > src/system.pa.gen && mv src/system.pa.gen src/system.pa])
1306
1307 # CMake related ProjectConfig files
1308 PA_LIBDIR="$libdir"
1309 AX_DEFINE_DIR(PA_LIBDIR, PA_LIBDIR, [PulseAudio library dir])
1310 PA_INCDIR="$includedir"
1311 AX_DEFINE_DIR(PA_INCDIR, PA_INCDIR, [PulseAudio include dir])
1312
1313 AC_CONFIG_FILES([PulseAudioConfig.cmake:PulseAudioConfig.cmake.in],
1314     [m4 PulseAudioConfig.cmake > PulseAudioConfig.cmake.gen && mv PulseAudioConfig.cmake.gen PulseAudioConfig.cmake])
1315 AC_CONFIG_FILES([PulseAudioConfigVersion.cmake])
1316
1317 AC_OUTPUT
1318
1319 # ==========================================================================
1320
1321 AS_IF([test "x$HAVE_X11" = "x1"], ENABLE_X11=yes, ENABLE_X11=no)
1322 AS_IF([test "x$HAVE_OSS_OUTPUT" = "x1"], ENABLE_OSS_OUTPUT=yes, ENABLE_OSS_OUTPUT=no)
1323 AS_IF([test "x$HAVE_OSS_WRAPPER" = "x1"], ENABLE_OSS_WRAPPER=yes, ENABLE_OSS_WRAPPER=no)
1324 AS_IF([test "x$HAVE_ALSA" = "x1"], ENABLE_ALSA=yes, ENABLE_ALSA=no)
1325 AS_IF([test "x$HAVE_COREAUDIO" = "x1"], ENABLE_COREAUDIO=yes, ENABLE_COREAUDIO=no)
1326 AS_IF([test "x$HAVE_SOLARIS" = "x1"], ENABLE_SOLARIS=yes, ENABLE_SOLARIS=no)
1327 AS_IF([test "x$HAVE_WAVEOUT" = "x1"], ENABLE_WAVEOUT=yes, ENABLE_WAVEOUT=no)
1328 AS_IF([test "x$HAVE_GLIB20" = "x1"], ENABLE_GLIB20=yes, ENABLE_GLIB20=no)
1329 AS_IF([test "x$HAVE_GTK20" = "x1"], ENABLE_GTK20=yes, ENABLE_GTK20=no)
1330 AS_IF([test "x$HAVE_GCONF" = "x1"], ENABLE_GCONF=yes, ENABLE_GCONF=no)
1331 AS_IF([test "x$HAVE_AVAHI" = "x1"], ENABLE_AVAHI=yes, ENABLE_AVAHI=no)
1332 AS_IF([test "x$HAVE_JACK" = "x1"], ENABLE_JACK=yes, ENABLE_JACK=no)
1333 AS_IF([test "x$HAVE_LIBASYNCNS" = "x1"], ENABLE_LIBASYNCNS=yes, ENABLE_LIBASYNCNS=no)
1334 AS_IF([test "x$HAVE_LIRC" = "x1"], ENABLE_LIRC=yes, ENABLE_LIRC=no)
1335 AS_IF([test "x$HAVE_DBUS" = "x1"], ENABLE_DBUS=yes, ENABLE_DBUS=no)
1336 AS_IF([test "x$HAVE_HAL" = "x1"], ENABLE_HAL=yes, ENABLE_HAL=no)
1337 AS_IF([test "x$HAVE_UDEV" = "x1"], ENABLE_UDEV=yes, ENABLE_UDEV=no)
1338 AS_IF([test "x$HAVE_BLUEZ" = "x1"], ENABLE_BLUEZ=yes, ENABLE_BLUEZ=no)
1339 AS_IF([test "x$HAVE_HAL_COMPAT" = "x1"], ENABLE_HAL_COMPAT=yes, ENABLE_HAL_COMPAT=no)
1340 AS_IF([test "x$HAVE_TCPWRAP" = "x1"], ENABLE_TCPWRAP=yes, ENABLE_TCPWRAP=no)
1341 AS_IF([test "x$HAVE_LIBSAMPLERATE" = "x1"], ENABLE_LIBSAMPLERATE=yes, ENABLE_LIBSAMPLERATE=no)
1342 AS_IF([test "x$HAVE_IPV6" = "x1"], ENABLE_IPV6=yes, ENABLE_IPV6=no)
1343 AS_IF([test "x$HAVE_OPENSSL" = "x1"], ENABLE_OPENSSL=yes, ENABLE_OPENSSL=no)
1344 AS_IF([test "x$HAVE_FFTW" = "x1"], ENABLE_FFTW=yes, ENABLE_FFTW=no)
1345 AS_IF([test "x$HAVE_ORC" = "xyes"], ENABLE_ORC=yes, ENABLE_ORC=no)
1346 AS_IF([test "x$HAVE_ADRIAN_EC" = "x1"], ENABLE_ADRIAN_EC=yes, ENABLE_ADRIAN_EC=no)
1347 AS_IF([test "x$HAVE_SPEEX" = "x1"], ENABLE_SPEEX=yes, ENABLE_SPEEX=no)
1348 AS_IF([test "x$HAVE_WEBRTC" = "x1"], ENABLE_WEBRTC=yes, ENABLE_WEBRTC=no)
1349 AS_IF([test "x$HAVE_TDB" = "x1"], ENABLE_TDB=yes, ENABLE_TDB=no)
1350 AS_IF([test "x$HAVE_GDBM" = "x1"], ENABLE_GDBM=yes, ENABLE_GDBM=no)
1351 AS_IF([test "x$HAVE_SIMPLEDB" = "x1"], ENABLE_SIMPLEDB=yes, ENABLE_SIMPLEDB=no)
1352 AS_IF([test "x$HAVE_ESOUND" = "x1"], ENABLE_ESOUND=yes, ENABLE_ESOUND=no)
1353 AS_IF([test "x$HAVE_ESOUND" = "x1" -a "x$USE_PER_USER_ESOUND_SOCKET" = "x1"], ENABLE_PER_USER_ESOUND_SOCKET=yes, ENABLE_PER_USER_ESOUND_SOCKET=no)
1354 AS_IF([test "x$enable_legacy_runtime_dir" != "xno"], ENABLE_LEGACY_RUNTIME_DIR=yes, ENABLE_LEGACY_RUNTIME_DIR=no)
1355 AS_IF([test "x$enable_legacy_database_entry_format" != "xno"], ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=yes, ENABLE_LEGACY_DATABASE_ENTRY_FORMAT=no)
1356
1357 echo "
1358  ---{ $PACKAGE_NAME $VERSION }---
1359
1360     prefix:                        ${prefix}
1361     sysconfdir:                    ${sysconfdir}
1362     localstatedir:                 ${localstatedir}
1363     modlibexecdir:                 ${modlibexecdir}
1364     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1365     System State Path:             ${PA_SYSTEM_STATE_PATH}
1366     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1367     Compiler:                      ${CC}
1368     CFLAGS:                        ${CFLAGS}
1369     LIBS:                          ${LIBS}
1370
1371     Enable X11:                    ${ENABLE_X11}
1372     Enable OSS Output:             ${ENABLE_OSS_OUTPUT}
1373     Enable OSS Wrapper:            ${ENABLE_OSS_WRAPPER}
1374     Enable EsounD:                 ${ENABLE_ESOUND}
1375     Enable Alsa:                   ${ENABLE_ALSA}
1376     Enable CoreAudio:              ${ENABLE_COREAUDIO}
1377     Enable Solaris:                ${ENABLE_SOLARIS}
1378     Enable WaveOut:                ${ENABLE_WAVEOUT}
1379     Enable GLib 2.0:               ${ENABLE_GLIB20}
1380     Enable Gtk+ 2.0:               ${ENABLE_GTK20}
1381     Enable GConf:                  ${ENABLE_GCONF}
1382     Enable Avahi:                  ${ENABLE_AVAHI}
1383     Enable Jack:                   ${ENABLE_JACK}
1384     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1385     Enable LIRC:                   ${ENABLE_LIRC}
1386     Enable D-Bus:                  ${ENABLE_DBUS}
1387       Enable HAL:                  ${ENABLE_HAL}
1388       Enable BlueZ:                ${ENABLE_BLUEZ}
1389     Enable udev:                   ${ENABLE_UDEV}
1390       Enable HAL->udev compat:     ${ENABLE_HAL_COMPAT}
1391     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1392     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1393     Enable IPv6:                   ${ENABLE_IPV6}
1394     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1395     Enable fftw:                   ${ENABLE_FFTW}
1396     Enable orc:                    ${ENABLE_ORC}
1397     Enable Adrian echo canceller:  ${ENABLE_ADRIAN_EC}
1398     Enable speex (resampler, AEC): ${ENABLE_SPEEX}
1399     Enable WebRTC echo canceller:  ${ENABLE_WEBRTC}
1400     Database
1401       tdb:                         ${ENABLE_TDB}
1402       gdbm:                        ${ENABLE_GDBM}
1403       simple database:             ${ENABLE_SIMPLEDB}
1404
1405     System User:                   ${PA_SYSTEM_USER}
1406     System Group:                  ${PA_SYSTEM_GROUP}
1407     Access Group:                  ${PA_ACCESS_GROUP}
1408     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1409     Force preopen:                 ${FORCE_PREOPEN}
1410     Preopened modules:             ${PREOPEN_MODS}
1411
1412     Legacy Runtime Dir Support:    ${ENABLE_LEGACY_RUNTIME_DIR}
1413     Legacy Database Entry Support: ${ENABLE_LEGACY_DATABASE_ENTRY_FORMAT}
1414 "
1415
1416 if test "${ENABLE_SPEEX}" = "no" && test "${ENABLE_WEBRTC}" = "no" && test "${ENABLE_ADRIAN_EC}" = "no" ; then
1417 AC_MSG_ERROR([At least one echo canceller implementation must be available.])
1418 fi
1419
1420 if test "${ENABLE_DBUS}" = "no" && test "x$os_is_win32" != "x1" ; then
1421    echo "
1422 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1423 You do not have D-Bus support enabled. It is strongly recommended
1424 that you enable D-Bus support if your platform supports it.
1425 Many parts of PulseAudio use D-Bus, from ConsoleKit interaction
1426 to the Device Reservation Protocol to speak to JACK, Bluetooth
1427 support and even a native control protocol for communicating and
1428 controling the PulseAudio daemon itself.
1429 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1430 "
1431 fi
1432
1433 if test "${ENABLE_UDEV}" = "no" && test "x$os_is_win32" != "x1" ; then
1434    echo "
1435 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1436 You do not have udev support enabled. It is strongly recommended
1437 that you enable udev support if your platform supports it as it is
1438 the primary method used to detect hardware audio devices (on Linux)
1439 and is thus a critical part of PulseAudio on that platform.
1440 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1441 "
1442 fi
1443
1444 if test "${ENABLE_SPEEX}" = "no" && test "x$os_is_win32" != "x1" ; then
1445    echo "
1446 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1447 You do not have speex support enabled. It is strongly recommended
1448 that you enable speex support if your platform supports it as it is
1449 the primary method used for audio resampling and is thus a critical
1450 part of PulseAudio on that platform.
1451 ===== WARNING WARNING WARNING WARNING WARNING WARNING WARNING =====
1452 "
1453 fi