configure.ac

   1 dnl PSPP - a program for statistical analysis.
   2 dnl Copyright (C) 2017, 2021 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software: you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation, either version 3 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 dnl
  17 dnl Process this file with autoconf to produce a configure script.
  18
  19 dnl Initialize.
  20 AC_PREREQ(2.64)
  21 AC_INIT([GNU PSPP], [1.6.2], [bug-gnu-pspp@gnu.org], [pspp])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_TESTDIR([tests])
  25 AM_INIT_AUTOMAKE([tar-ustar info-in-builddir])
  26
  27 dnl Checks for programs.
  28 AC_GNU_SOURCE
  29 AC_PROG_CC
  30 gl_EARLY
  31 if test x"$cross_compiling" = x"yes"; then
  32    if test x"$srcdir" = x"."; then
  33       AC_ERROR([Cross compiling must be done out of source.])
  34    fi
  35 fi
  36
  37 AM_PROG_CC_C_O
  38 AC_LIBTOOL_WIN32_DLL
  39 AC_LIBTOOL_DLOPEN
  40 AC_PROG_LIBTOOL
  41 AC_HEADER_TIOCGWINSZ
  42
  43 AC_CHECK_SIZEOF([ptrdiff_t])
  44 binary_width=`expr 8 '*' $ac_cv_sizeof_ptrdiff_t`
  45 AC_SUBST([binary_width])
  46
  47
  48 PKG_PROG_PKG_CONFIG
  49 m4_pattern_forbid([PKG_CHECK_MODULES])
  50 PSPP_CHECK_CLICKSEQUENCE
  51 PSPP_CHECK_MAKEINFO_DOCBOOK_XML
  52 PSPP_CHECK_DOT
  53
  54 PSPP_ENABLE_WERROR
  55 PSPP_ENABLE_OPTION([-Wall])
  56 PSPP_ENABLE_OPTION([-Wextra])
  57 PSPP_ENABLE_OPTION([-Wwrite-strings])
  58 PSPP_ENABLE_OPTION([-Wstrict-prototypes])
  59 PSPP_ENABLE_OPTION([-Wpointer-arith])
  60 PSPP_ENABLE_OPTION([-Wno-sign-compare])
  61 PSPP_ENABLE_OPTION([-Wmissing-prototypes])
  62
  63 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  64 AM_CONDITIONAL(host_is_w32, [case $host_os in mingw*) true;; *) false;; esac] )
  65
  66 PSPP_PERL
  67 PSPP_PYTHON3
  68 AC_CHECK_PROGS([TEX], [tex], [no])
  69 AC_SUBST([TEX])
  70
  71 # This suppresses an error in gl/careadlinkat.c that otherwise can't be
  72 # avoided in GCC 10.x:
  73 #   ../../gl/careadlinkat.c: In function ‘careadlinkat’:
  74 #   cc1: error: function may return address of local variable
  75 CFLAGS="$CFLAGS -DGCC_LINT"
  76
  77 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  78 AC_PROVIDE([AM_PO_SUBDIRS])
  79 AM_GNU_GETTEXT([external], [need-ngettext])
  80
  81 LIBS="$LIBINTL $LIBS"
  82 AC_CHECK_PROGS([MSGFMT], [msgfmt])
  83 if test "x$MSGFMT" = x; then
  84   PSPP_REQUIRED_PREREQ([msgfmt (is usually provided with gettext)])
  85 fi
  86
  87 AC_CHECK_PROGS([XGETTEXT], [xgettext])
  88 if test "x$XGETTEXT" = x; then
  89   PSPP_REQUIRED_PREREQ([xgettext (is usually provided with gettext)])
  90 fi
  91
  92 PSPP_CHECK_XGETTEXT
  93
  94 if test "$pspp_cv_progrecent_xgettext"  != "yes"; then
  95    PSPP_REQUIRED_PREREQ([xgettext version 0.20 or greater])
  96 fi
  97
  98 dnl Checks for libraries.
  99 AC_SYS_LARGEFILE
 100 AC_SEARCH_LIBS([sin], [m])
 101 PSPP_LC_PAPER
 102
 103
 104 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
 105 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
 106
 107 # Support for Cairo and Pango.
 108 PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
 109   [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"],
 110   [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later])])
 111
 112 dnl One of the tests uses xmllint.
 113 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
 114 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
 115   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
 116     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
 117     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
 118    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
 119
 120 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
 121
 122 # Support for GUI.
 123 AC_ARG_WITH([gui],
 124   [AS_HELP_STRING([--without-gui],
 125                   [Don't build the PSPPIRE GUI (using GTK+)])],
 126   [], [with_gui=yes])
 127 AM_CONDITIONAL([building_gui], [test "$with_gui" != "no"])
 128 if test "$with_gui" != "no"; then
 129   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
 130     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
 131
 132   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.22.0], [],
 133     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.22.0 or later (or use --without-gui)])])
 134
 135   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-4 >= 4.0], [],
 136     [PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
 137       [PSPP_REQUIRED_PREREQ([gtksourceview 4.x or gtksourceview 3.x version 3.4.2 or later (or use --without-gui)])])])
 138
 139   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.44], [],
 140     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.44 or later (or use --without-gui)])])
 141
 142   PKG_CHECK_MODULES([SPREAD_SHEET_WIDGET], [spread-sheet-widget >= 0.7], [],
 143     [PSPP_REQUIRED_PREREQ([spread-sheet-widget 0.7 (or use --without-gui)])])
 144   PKG_CHECK_VAR([SPREAD_SHEET_WIDGET_LIBDIR], [spread-sheet-widget], [libdir])
 145
 146   AC_ARG_VAR([GLIB_GENMARSHAL])
 147   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
 148   if test "x$GLIB_GENMARSHAL" = x; then
 149     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 150   fi
 151
 152   AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
 153   if test "x$GLIB_COMPILE_RESOURCES" = x; then
 154     PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
 155   fi
 156
 157 fi
 158
 159 gl_NEXT_HEADERS([gtk/gtk.h])
 160
 161 dnl Checks needed for psql reader
 162
 163 dnl The 8.x series postgres tarballs installs with a default prefix of
 164 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 165
 166 dnl If the libpq.so file is in a non standard path, (one which the linker
 167 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 168 dnl However, if the system happens to have more than one version of other
 169 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 170 dnl /usr and /usr/local) then the wrong one may get linked.
 171
 172 dnl To overcome this, we first check for libpq in the standard places, and
 173 dnl only set PG_LDFLAGS if it's not found.
 174
 175
 176 AC_ARG_WITH(
 177   libpq,
 178   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 179 AC_ARG_VAR([PG_CONFIG],
 180            [Full pathname of the pg_config program shipped with Postgresql])
 181 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 182              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 183
 184 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 185   AC_SUBST(PG_CONFIG)
 186   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 187   AC_SUBST(PG_CFLAGS)
 188
 189   AC_CHECK_LIB([pq], [PQexec],
 190      [:],
 191      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 192   AC_SUBST(PG_LDFLAGS)
 193
 194   PG_LIBS=-lpq
 195   AC_SUBST(PG_LIBS)
 196
 197   PKG_CHECK_EXISTS(libssl,
 198         AC_DEFINE([USE_SSL],1,
 199                    [Define to 1 if the openssl library is present.])
 200            ,)
 201
 202   # Now verify that we can actually link against libpq.  If we are
 203   # cross-compiling and picked up a host libpq, or if libpq is just
 204   # badly installed, this will fail.
 205   AC_CACHE_CHECK(
 206     [whether -lpq links successfully],
 207     [pspp_cv_have_libpq],
 208     [save_CPPFLAGS=$CPPFLAGS
 209      save_LIBS=$LIBS
 210      save_LDFLAGS=$LDFLAGS
 211      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 212      LIBS="$PG_LIBS $LIBS"
 213      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 214      AC_LINK_IFELSE(
 215        [AC_LANG_PROGRAM(
 216          [#include <libpq-fe.h>
 217          ], [PQfinish (0);])],
 218        [pspp_cv_have_libpq=yes],
 219        [pspp_cv_have_libpq=no])
 220      CPPFLAGS=$save_CPPFLAGS
 221      LIBS=$save_LIBS
 222      LDFLAGS=$save_LDFLAGS])
 223
 224   if test $pspp_cv_have_libpq = yes; then
 225     PSQL_SUPPORT=yes
 226     AC_DEFINE([PSQL_SUPPORT], [1],
 227       [Define to 1 if building in support for reading from postgres
 228        databases.])
 229   else
 230     PSQL_SUPPORT=no
 231     PG_CONFIG=
 232     PG_CFLAGS=
 233     PG_LDFLAGS=
 234     PG_LIBS=
 235   fi
 236 else
 237   PSQL_SUPPORT=no
 238   pspp_cv_have_libpq=no
 239 fi
 240 AC_SUBST([PSQL_SUPPORT])
 241
 242 dnl Check for libxml2
 243 PKG_CHECK_MODULES(
 244   [LIBXML2], [libxml-2.0], [], [PSPP_REQUIRED_PREREQ([libxml2])])
 245
 246 dnl Check for zlib.
 247 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 248 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 249
 250 dnl Avoid interference between zlib's crc32() function and gnulib's
 251 dnl crc32() function, which have different signatures.  PSPP calls
 252 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 253 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 254 dnl crc32(), then zlib will call gnulib's version instead of its own,
 255 dnl causing failures.  (This can happen even if zlib isn't detected
 256 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 257 dnl sometimes use zlib themselves.)
 258 AC_DEFINE(
 259   [crc32], [gl_crc32],
 260   [Avoid making zlib call gnulib's crc32() instead of its own.])
 261
 262 PSPP_PERL_MODULE
 263
 264 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 265 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 266                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 267
 268
 269 PSPP_GSL_NEEDS_FGNU89_INLINE
 270
 271 PSPP_READLINE
 272
 273 dnl Checks for header files.
 274 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 275
 276 dnl Some systems don't have SIGWINCH
 277 AC_CHECK_DECLS([SIGWINCH], [], [],
 278           [#include <signal.h>
 279           /* NetBSD declares sys_siglist in unistd.h.  */
 280           #ifdef HAVE_UNISTD_H
 281           # include <unistd.h>
 282           #endif
 283           ])
 284
 285
 286 # For gnulib.
 287 gl_INIT
 288
 289 AC_C_INLINE
 290
 291 AC_C_BIGENDIAN
 292
 293 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 294
 295 AC_PROG_LN_S
 296
 297 # iconv is required
 298 AM_ICONV
 299 if test "$am_cv_func_iconv" != "yes"; then
 300    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 301 fi
 302 LIBS="$LIBICONV $LIBS"
 303
 304 dnl Required by the gnulib 'relocatable-prog' module.
 305 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 306 RELOCATABLE_LIBRARY_PATH='$(pkglibdir):$(SPREAD_SHEET_WIDGET_LIBDIR)'
 307 RELOCATABLE_STRIP=:
 308
 309 PSPP_CHECK_PREREQS
 310
 311 dnl The makefile needs to know if we're cross compiling, so that
 312 dnl it can make arrangements to build the documentation examples.
 313 AM_CONDITIONAL(cross_compiling, test x"$cross_compiling" = x"yes" )
 314
 315 AC_CONFIG_FILES(
 316   [Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 317
 318 AC_CONFIG_COMMANDS([doc/pspp-figures/dummy], [:])
 319
 320 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 321
 322 AC_OUTPUT
 323 echo "PSPP configured successfully."
 324
 325 dnl configure.ac ends here