configure.ac

   1 dnl PSPP - a program for statistical analysis.
   2 dnl Copyright (C) 2017, 2021 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software: you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation, either version 3 of the License, or
   7 dnl (at your option) any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 dnl
  17 dnl Process this file with autoconf to produce a configure script.
  18
  19 dnl Initialize.
  20 AC_PREREQ(2.64)
  21 AC_INIT([GNU PSPP], [1.6.2], [bug-gnu-pspp@gnu.org], [pspp])
  22 AC_CONFIG_AUX_DIR([build-aux])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_CONFIG_TESTDIR([tests])
  25 AM_INIT_AUTOMAKE([tar-ustar info-in-builddir])
  26
  27 dnl Checks for programs.
  28 AC_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 gl_EARLY
  31 if test x"$cross_compiling" = x"yes"; then
  32    if test x"$srcdir" = x"."; then
  33       AC_MSG_ERROR([Cross compiling must be done out of source.])
  34    fi
  35 fi
  36
  37 AM_PROG_CC_C_O
  38 LT_INIT([dlopen win32-dll])
  39 AC_HEADER_TIOCGWINSZ
  40
  41 AC_CHECK_SIZEOF([ptrdiff_t])
  42 binary_width=`expr 8 '*' $ac_cv_sizeof_ptrdiff_t`
  43 AC_SUBST([binary_width])
  44
  45
  46 PKG_PROG_PKG_CONFIG
  47 m4_pattern_forbid([PKG_CHECK_MODULES])
  48 PSPP_CHECK_CLICKSEQUENCE
  49 PSPP_CHECK_MAKEINFO_DOCBOOK_XML
  50 PSPP_CHECK_DOT
  51
  52 PSPP_ENABLE_WERROR
  53 PSPP_ENABLE_OPTION([-Wall])
  54 PSPP_ENABLE_OPTION([-Wextra])
  55 PSPP_ENABLE_OPTION([-Wwrite-strings])
  56 PSPP_ENABLE_OPTION([-Wstrict-prototypes])
  57 PSPP_ENABLE_OPTION([-Wpointer-arith])
  58 PSPP_ENABLE_OPTION([-Wno-sign-compare])
  59 PSPP_ENABLE_OPTION([-Wmissing-prototypes])
  60
  61 AM_CONDITIONAL(cc_is_gcc, test x"$GCC" = x"yes" )
  62 AM_CONDITIONAL(host_is_w32, [case $host_os in mingw*) true;; *) false;; esac] )
  63
  64 PSPP_PERL
  65 PSPP_PYTHON3
  66 AC_CHECK_PROGS([TEX], [tex], [no])
  67 AC_SUBST([TEX])
  68
  69 # This suppresses an error in gl/careadlinkat.c that otherwise can't be
  70 # avoided in GCC 10.x:
  71 #   ../../gl/careadlinkat.c: In function ‘careadlinkat’:
  72 #   cc1: error: function may return address of local variable
  73 CFLAGS="$CFLAGS -DGCC_LINT"
  74
  75 dnl Disable automatic po/ support, because PSPP provides its own po/ support.
  76 AC_PROVIDE([AM_PO_SUBDIRS])
  77 AM_GNU_GETTEXT([external], [need-ngettext])
  78
  79 LIBS="$LIBINTL $LIBS"
  80 AC_CHECK_PROGS([MSGFMT], [msgfmt])
  81 if test "x$MSGFMT" = x; then
  82   PSPP_REQUIRED_PREREQ([msgfmt (is usually provided with gettext)])
  83 fi
  84
  85 AC_CHECK_PROGS([XGETTEXT], [xgettext])
  86 if test "x$XGETTEXT" = x; then
  87   PSPP_REQUIRED_PREREQ([xgettext (is usually provided with gettext)])
  88 fi
  89
  90 PSPP_CHECK_XGETTEXT
  91
  92 if test "$pspp_cv_progrecent_xgettext"  != "yes"; then
  93    PSPP_REQUIRED_PREREQ([xgettext version 0.20 or greater])
  94 fi
  95
  96 dnl Checks for libraries.
  97 AC_SYS_LARGEFILE
  98 AC_SEARCH_LIBS([sin], [m])
  99 PSPP_LC_PAPER
 100
 101
 102 AC_ARG_VAR([PSPP_LDFLAGS], [linker flags to be used for linking the pspp binary only])
 103 AC_ARG_VAR([PSPPIRE_LDFLAGS], [linker flags to be used for linking the psppire binary only])
 104
 105 # Support for Cairo and Pango.
 106 PKG_CHECK_MODULES([CAIRO], [cairo >= 1.5 pango >= 1.22 pangocairo],
 107   [CPPFLAGS="$CPPFLAGS $CAIRO_CFLAGS"],
 108   [PSPP_REQUIRED_PREREQ([cairo 1.5 or later and pango 1.22 or later])])
 109
 110 dnl One of the tests uses xmllint.
 111 AC_CACHE_CHECK([for an xmllint program which fits our needs],[ac_cv_path_XMLLINT],
 112 [AC_PATH_PROGS_FEATURE_CHECK([XMLLINT], [xmllint],
 113   [[$ac_path_XMLLINT --version 2>&1 | $GREP XPath > /dev/null &&
 114     test `$ac_path_XMLLINT --version 2>&1 | $SED 's/^.* \([0-9]*\).*/\1/'` -gt 20900 &&
 115     ac_cv_path_XMLLINT=$ac_path_XMLLINT]],
 116    [AC_MSG_WARN([no appropriate xmllint program found. Using a dummy (echo)]); ac_cv_path_XMLLINT=$ECHO])])
 117
 118 AC_SUBST([XMLLINT],[$ac_cv_path_XMLLINT])
 119
 120 # Support for GUI.
 121 AC_ARG_WITH([gui],
 122   [AS_HELP_STRING([--without-gui],
 123                   [Don't build the PSPPIRE GUI (using GTK+)])],
 124   [], [with_gui=yes])
 125 AM_CONDITIONAL([building_gui], [test "$with_gui" != "no"])
 126 if test "$with_gui" != "no"; then
 127   PKG_CHECK_MODULES([GTHREAD], [gthread-2.0], [],
 128     [PSPP_REQUIRED_PREREQ([gthread 2.0 (or use --without-gui)])])
 129
 130   PKG_CHECK_MODULES([GTK], [gtk+-3.0 >= 3.22.0], [],
 131     [PSPP_REQUIRED_PREREQ([gtk+ 3.0 version 3.22.0 or later (or use --without-gui)])])
 132
 133   PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-4 >= 4.0], [],
 134     [PKG_CHECK_MODULES([GTKSOURCEVIEW], [gtksourceview-3.0 >= 3.4.2], [],
 135       [PSPP_REQUIRED_PREREQ([gtksourceview 4.x or gtksourceview 3.x version 3.4.2 or later (or use --without-gui)])])])
 136
 137   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.44], [],
 138     [PSPP_REQUIRED_PREREQ([glib 2.0 version 2.44 or later (or use --without-gui)])])
 139
 140   PKG_CHECK_MODULES([SPREAD_SHEET_WIDGET], [spread-sheet-widget >= 0.7], [],
 141     [PSPP_REQUIRED_PREREQ([spread-sheet-widget 0.7 (or use --without-gui)])])
 142   PKG_CHECK_VAR([SPREAD_SHEET_WIDGET_LIBDIR], [spread-sheet-widget], [libdir])
 143
 144   AC_ARG_VAR([GLIB_GENMARSHAL])
 145   AC_CHECK_PROGS([GLIB_GENMARSHAL], [glib-genmarshal])
 146   if test "x$GLIB_GENMARSHAL" = x; then
 147     PSPP_REQUIRED_PREREQ([glib-genmarshal (or use --without-gui)])
 148   fi
 149
 150   AC_CHECK_PROGS([GLIB_COMPILE_RESOURCES], [glib-compile-resources])
 151   if test "x$GLIB_COMPILE_RESOURCES" = x; then
 152     PSPP_REQUIRED_PREREQ([glib-compile-resources (or use --without-gui)])
 153   fi
 154
 155   dnl g_memdup2 has been introduced in glib 2.67.3. Older versions need
 156   dnl a workaround
 157   AC_CHECK_LIB(glib-2.0, g_memdup2, [AC_DEFINE([HAVE_G_MEMDUP2], [1], [g_memdup2 check])])
 158
 159 fi
 160
 161 gl_NEXT_HEADERS([gtk/gtk.h])
 162
 163 dnl Checks needed for psql reader
 164
 165 dnl The 8.x series postgres tarballs installs with a default prefix of
 166 dnl /usr/local/pgsql whereas, OSes (such as debian)  install into /usr .
 167
 168 dnl If the libpq.so file is in a non standard path, (one which the linker
 169 dnl doesn't search) then we must set the PG_LDFLAGS to -R/usr/wherever/
 170 dnl However, if the system happens to have more than one version of other
 171 dnl dependent libraries (eg. libgtk) in different standard paths. (eg:
 172 dnl /usr and /usr/local) then the wrong one may get linked.
 173
 174 dnl To overcome this, we first check for libpq in the standard places, and
 175 dnl only set PG_LDFLAGS if it's not found.
 176
 177
 178 AC_ARG_WITH(
 179   libpq,
 180   [AS_HELP_STRING([--without-libpq], [don't compile in Postgres capability])])
 181 AC_ARG_VAR([PG_CONFIG],
 182            [Full pathname of the pg_config program shipped with Postgresql])
 183 AC_PATH_PROG([PG_CONFIG], [pg_config], [],
 184              [$PATH:/usr/local/pgsql/bin:/usr/pgsql/bin])
 185
 186 if test x"$with_libpq" != x"no" && test -n "$PG_CONFIG" ; then
 187   AC_SUBST(PG_CONFIG)
 188   PG_CFLAGS=-I`$PG_CONFIG --includedir`
 189   AC_SUBST(PG_CFLAGS)
 190
 191   AC_CHECK_LIB([pq], [PQexec],
 192      [:],
 193      [PG_LDFLAGS="-L`$PG_CONFIG --libdir` -R`$PG_CONFIG --libdir`"])
 194   AC_SUBST(PG_LDFLAGS)
 195
 196   PG_LIBS=-lpq
 197   AC_SUBST(PG_LIBS)
 198
 199   PKG_CHECK_EXISTS(libssl,
 200         AC_DEFINE([USE_SSL],1,
 201                    [Define to 1 if the openssl library is present.])
 202            ,)
 203
 204   # Now verify that we can actually link against libpq.  If we are
 205   # cross-compiling and picked up a host libpq, or if libpq is just
 206   # badly installed, this will fail.
 207   AC_CACHE_CHECK(
 208     [whether -lpq links successfully],
 209     [pspp_cv_have_libpq],
 210     [save_CPPFLAGS=$CPPFLAGS
 211      save_LIBS=$LIBS
 212      save_LDFLAGS=$LDFLAGS
 213      CPPFLAGS="$PG_CFLAGS $CPPFLAGS"
 214      LIBS="$PG_LIBS $LIBS"
 215      LDFLAGS="$PG_LDFLAGS $LDFLAGS"
 216      AC_LINK_IFELSE(
 217        [AC_LANG_PROGRAM(
 218          [#include <libpq-fe.h>
 219          ], [PQfinish (0);])],
 220        [pspp_cv_have_libpq=yes],
 221        [pspp_cv_have_libpq=no])
 222      CPPFLAGS=$save_CPPFLAGS
 223      LIBS=$save_LIBS
 224      LDFLAGS=$save_LDFLAGS])
 225
 226   if test $pspp_cv_have_libpq = yes; then
 227     PSQL_SUPPORT=yes
 228     AC_DEFINE([PSQL_SUPPORT], [1],
 229       [Define to 1 if building in support for reading from postgres
 230        databases.])
 231   else
 232     PSQL_SUPPORT=no
 233     PG_CONFIG=
 234     PG_CFLAGS=
 235     PG_LDFLAGS=
 236     PG_LIBS=
 237   fi
 238 else
 239   PSQL_SUPPORT=no
 240   pspp_cv_have_libpq=no
 241 fi
 242 AC_SUBST([PSQL_SUPPORT])
 243
 244 dnl Check for libxml2
 245 PKG_CHECK_MODULES(
 246   [LIBXML2], [libxml-2.0], [], [PSPP_REQUIRED_PREREQ([libxml2])])
 247
 248 dnl Check for zlib.
 249 AC_SEARCH_LIBS([gzopen], [z], [], [PSPP_REQUIRED_PREREQ([zlib])])
 250 AC_CHECK_HEADERS([zlib.h], [], [PSPP_REQUIRED_PREREQ([zlib])])
 251
 252 dnl Avoid interference between zlib's crc32() function and gnulib's
 253 dnl crc32() function, which have different signatures.  PSPP calls
 254 dnl only gnulib's crc32() directly, but it calls zlib's crc32()
 255 dnl indirectly through other zlib calls.  If we don't rename gnulib's
 256 dnl crc32(), then zlib will call gnulib's version instead of its own,
 257 dnl causing failures.  (This can happen even if zlib isn't detected
 258 dnl directly, because other libraries that PSPP uses, e.g. libpng,
 259 dnl sometimes use zlib themselves.)
 260 AC_DEFINE(
 261   [crc32], [gl_crc32],
 262   [Avoid making zlib call gnulib's crc32() instead of its own.])
 263
 264 PSPP_PERL_MODULE
 265
 266 AC_SEARCH_LIBS([cblas_dsdot], [gslcblas],,[PSPP_REQUIRED_PREREQ([libgslcblas])])
 267 PKG_CHECK_MODULES([GSL], [gsl >= 1.13], [],
 268                          AC_SEARCH_LIBS([gsl_poly_eval_derivs], [gsl],,[PSPP_REQUIRED_PREREQ([gsl version 1.13 or later])]))
 269
 270
 271 PSPP_GSL_NEEDS_FGNU89_INLINE
 272
 273 PSPP_READLINE
 274
 275 dnl Checks for header files.
 276 AC_CHECK_HEADERS([sys/wait.h fpu_control.h ieeefp.h fenv.h pwd.h])
 277
 278 dnl Some systems don't have SIGWINCH
 279 AC_CHECK_DECLS([SIGWINCH], [], [],
 280           [#include <signal.h>
 281           /* NetBSD declares sys_siglist in unistd.h.  */
 282           #ifdef HAVE_UNISTD_H
 283           # include <unistd.h>
 284           #endif
 285           ])
 286
 287
 288 # For gnulib.
 289 gl_INIT
 290
 291 AC_C_INLINE
 292
 293 AC_C_BIGENDIAN
 294
 295 AC_CHECK_FUNCS([__setfpucw fork execl isinf isnan finite getpid feholdexcept fpsetmask popen round])
 296
 297 AC_PROG_LN_S
 298
 299 # iconv is required
 300 AM_ICONV
 301 if test "$am_cv_func_iconv" != "yes"; then
 302    PSPP_REQUIRED_PREREQ([iconv (see http://www.gnu.org/software/libiconv/)])
 303 fi
 304 LIBS="$LIBICONV $LIBS"
 305
 306 dnl Required by the gnulib 'relocatable-prog' module.
 307 dnl See doc/relocatable-maint.texi in the gnulib tree for details.
 308 RELOCATABLE_LIBRARY_PATH='$(pkglibdir):$(SPREAD_SHEET_WIDGET_LIBDIR)'
 309 RELOCATABLE_STRIP=:
 310
 311 PSPP_CHECK_PREREQS
 312
 313 dnl The makefile needs to know if we're cross compiling, so that
 314 dnl it can make arrangements to build the documentation examples.
 315 AM_CONDITIONAL(cross_compiling, test x"$cross_compiling" = x"yes" )
 316
 317 AC_CONFIG_FILES(
 318   [Makefile po/Makefile tests/atlocal perl-module/lib/PSPP.pm])
 319
 320 AC_CONFIG_COMMANDS([doc/pspp-figures/dummy], [:])
 321
 322 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
 323
 324 AC_OUTPUT
 325 echo "PSPP configured successfully."
 326
 327 dnl configure.ac ends here