configure.ac

   1 AC_INIT([ppcg], [0.00])
   2 AC_CONFIG_AUX_DIR([.])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6
   7 AC_PROG_CC
   8 AC_PROG_LIBTOOL
   9
  10 AX_SUBMODULE(isl,build|bundled|system,bundled)
  11 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
  12
  13 AC_SUBST(ISL_CFLAGS)
  14 AC_SUBST(ISL_LIBS)
  15 case "$with_isl" in
  16 bundled)
  17         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
  18         ppcg_configure_args="$ppcg_configure_args --with-isl-builddir=../isl"
  19         ;;
  20 build)
  21         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
  22         ppcg_configure_args="$ppcg_configure_args --with-isl-builddir=$ISL_BUILDDIR"
  23         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
  24         ;;
  25 system)
  26         PKG_CHECK_MODULES([ISL], [isl])
  27 esac
  28
  29 AX_SUBMODULE(cloog,build|bundled|system,bundled)
  30 AM_CONDITIONAL(BUNDLED_CLOOG, test $with_cloog = bundled)
  31
  32 AC_SUBST(CLOOG_LDFLAGS)
  33 AC_SUBST(CLOOG_CFLAGS)
  34 AC_SUBST(CLOOG_LIBS)
  35 CLOOG_CFLAGS="-DCLOOG_INT_GMP=1"
  36 case "$with_cloog" in
  37 bundled)
  38         CLOOG_CFLAGS="$CLOOG_CFLAGS -I\$(top_srcdir)/cloog/include -I\$(top_builddir)/cloog/include"
  39         ;;
  40 build)
  41         with_cloog_builddir=`echo @abs_builddir@ | $with_cloog_builddir/config.status --file=-`
  42         CLOOG_CFLAGS="$CLOOG_CFLAGS -I$cloog_srcdir/include -I$with_cloog_builddir/include"
  43         CLOOG_LIBS="$with_cloog_builddir/libcloog-isl.la"
  44         ;;
  45 system)
  46         if test "x$with_cloog_prefix" != "x"; then
  47                 CLOOG_CFLAGS="$CLOOG_CFLAGS -I$with_cloog_prefix/include"
  48         fi
  49         if test "x$with_cloog_exec_prefix" != "x"; then
  50                 CLOOG_LDFLAGS="-L$with_cloog_exec_prefix/lib"
  51         fi
  52         CLOOG_LIBS="-lcloog-isl"
  53 esac
  54
  55 AX_SUBMODULE(clan,build|bundled|system,bundled)
  56 AM_CONDITIONAL(BUNDLED_CLAN, test $with_clan = bundled)
  57
  58 AC_SUBST(CLAN_LDFLAGS)
  59 AC_SUBST(CLAN_CFLAGS)
  60 AC_SUBST(CLAN_LIBS)
  61 CLAN_CFLAGS="-DSCOPLIB_INT_T_IS_LONGLONG"
  62 case "$with_cloog" in
  63 bundled)
  64         CLAN_CFLAGS="$CLAN_CFLAGS -I\$(top_srcdir)/clan/scoplib/scoplib-0.2.0/include -I\$(top_srcdir)/clan/include -I\$(top_builddir)/clan/scoplib/scoplib-0.2.0/include -I\$(top_builddir)/clan/include"
  65         ;;
  66 build)
  67         with_clan_builddir=`echo @abs_builddir@ | $with_clan_builddir/config.status --file=-`
  68         CLAN_CFLAGS="$CLAN_CFLAGS -I$clan_srcdir/scoplib/scoplib-0.2.0/include -I$clan_srcdir/include -I$with_clan_builddir/scoplib/scoplib-0.2.0/include -I$with_clan_builddir/include"
  69         CLAN_LIBS="$with_clan_builddir/source/libclan.la"
  70         ;;
  71 system)
  72         if test "x$with_clan_prefix" != "x"; then
  73                 CLAN_CFLAGS="$CLAN_CFLAGS -I$with_clan_prefix/include"
  74         fi
  75         if test "x$with_clan_exec_prefix" != "x"; then
  76                 CLAN_LDFLAGS="-L$with_clan_exec_prefix/lib"
  77         fi
  78         CLAN_LIBS="-lclan"
  79 esac
  80
  81 AC_CONFIG_FILES(Makefile)
  82 if test $with_isl = bundled; then
  83         AC_CONFIG_SUBDIRS(isl)
  84 fi
  85 if test $with_cloog = bundled; then
  86         AC_CONFIG_SUBDIRS(cloog)
  87 fi
  88 if test $with_clan = bundled; then
  89         AC_CONFIG_SUBDIRS(clan)
  90 fi
  91 AC_CONFIG_COMMANDS_POST([
  92         dnl pass on arguments to subdir configures, but don't
  93         dnl add them to config.status
  94         ac_configure_args="$ac_configure_args $ppcg_configure_args"
  95 ])
  96 AC_OUTPUT