CMakeLists.txt

   1 # Check if this is a in tree build.
   2 if (NOT DEFINED LLVM_MAIN_SRC_DIR)
   3   project(Polly)
   4   cmake_minimum_required(VERSION 2.8)
   5
   6   # Where is LLVM installed?
   7   set(LLVM_INSTALL_ROOT "" CACHE PATH "Root of LLVM install.")
   8   # Check if the LLVM_INSTALL_ROOT valid.
   9   if( NOT EXISTS ${LLVM_INSTALL_ROOT}/include/llvm )
  10     message(FATAL_ERROR "LLVM_INSTALL_ROOT (${LLVM_INSTALL_ROOT}) is not a valid LLVM installation.")
  11   endif(NOT EXISTS ${LLVM_INSTALL_ROOT}/include/llvm)
  12   #FileCheck is not install by default, warn the user to Copy FileCheck
  13   if( NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/FileCheck
  14       OR NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/not)
  15     message(WARNING "FileCheck or not are requred by running regress tests, "
  16                     "but they are not installed! Please copy it to "
  17                     "${LLVM_INSTALL_ROOT}/bin.")
  18   endif(NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/FileCheck
  19         OR NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/not)
  20   # Add the llvm header path.
  21   include_directories(${LLVM_INSTALL_ROOT}/include/)
  22
  23   # Get the system librarys that will link into LLVM.
  24   function(get_system_libs return_var)
  25     # Returns in `return_var' a list of system libraries used by LLVM.
  26     if( NOT MSVC )
  27       if( MINGW )
  28         set(system_libs ${system_libs} imagehlp psapi)
  29       elseif( CMAKE_HOST_UNIX )
  30         if( HAVE_LIBDL )
  31           set(system_libs ${system_libs} ${CMAKE_DL_LIBS})
  32         endif()
  33         if( LLVM_ENABLE_THREADS AND HAVE_LIBPTHREAD )
  34           set(system_libs ${system_libs} pthread)
  35         endif()
  36       endif( MINGW )
  37     endif( NOT MSVC )
  38     set(${return_var} ${system_libs} PARENT_SCOPE)
  39   endfunction(get_system_libs)
  40
  41   # Now set the header paths.
  42   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --includedir
  43                   OUTPUT_VARIABLE LLVM_INCLUDE_DIR
  44                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  45   include_directories( ${LLVM_INCLUDE_DIR} )
  46
  47   # Get the TARGET_TRIPLE
  48   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --host-target
  49                   OUTPUT_VARIABLE TARGET_TRIPLE
  50                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  51
  52   # And then set the cxx flags.
  53   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --cxxflags
  54                   OUTPUT_VARIABLE LLVM_CXX_FLAGS
  55                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  56   set(CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS} ${LLVM_CXX_FLAGS})
  57 endif(NOT DEFINED LLVM_MAIN_SRC_DIR)
  58
  59 set(POLLY_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  60 set(POLLY_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  61
  62 # Add path for custom modules
  63 set(CMAKE_MODULE_PATH
  64   ${CMAKE_MODULE_PATH}
  65   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  66   )
  67
  68 include("polly_macros")
  69
  70 # Add appropriate flags for GCC
  71 if (CMAKE_COMPILER_IS_GNUCXX)
  72   # FIXME: Turn off exceptions, RTTI:
  73   # -fno-exceptions -fno-rtti
  74   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual -Wno-long-long -Wall -W -Wno-unused-parameter -Wwrite-strings -fno-exceptions -fno-rtti")
  75 endif ()
  76
  77 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
  78
  79 # Add path for custom modules
  80 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${POLLY_SOURCE_DIR}/cmake")
  81
  82 SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  83
  84 FIND_PACKAGE(Isl REQUIRED)
  85 FIND_PACKAGE(Pluto)
  86
  87 option(POLLY_USE_CLOOG "Build Polly with Cloog support" ON)
  88 if (POLLY_USE_CLOOG)
  89   # Build Cloog support in Polly (default is for cloog-isl).
  90   FIND_PACKAGE(Cloog)
  91   FIND_PACKAGE(Gmp REQUIRED)
  92 endif(POLLY_USE_CLOOG)
  93
  94 option(POLLY_ENABLE_GPGPU_CODEGEN "Enable GPGPU code generation feature" OFF)
  95 if (POLLY_ENABLE_GPGPU_CODEGEN)
  96   # Do not require CUDA, as GPU code generation test cases can be run without
  97   # a cuda library.
  98   FIND_PACKAGE(CUDA)
  99   set(GPU_CODEGEN TRUE)
 100 endif(POLLY_ENABLE_GPGPU_CODEGEN)
 101
 102 option(POLLY_ENABLE_OPENSCOP "Enable Openscop library for scop import/export" ON)
 103 if (POLLY_ENABLE_OPENSCOP)
 104   FIND_PACKAGE(OpenScop)
 105 endif(POLLY_ENABLE_OPENSCOP)
 106
 107 option(POLLY_ENABLE_SCOPLIB "Enable SCoPLib library for scop import/export" ON)
 108 if (POLLY_ENABLE_SCOPLIB)
 109   FIND_PACKAGE(SCoPLib)
 110 endif(POLLY_ENABLE_SCOPLIB)
 111
 112 if (CLOOG_FOUND)
 113   INCLUDE_DIRECTORIES( ${CLOOG_INCLUDE_DIR} )
 114 endif(CLOOG_FOUND)
 115 if (PLUTO_FOUND)
 116   INCLUDE_DIRECTORIES( ${PLUTO_INCLUDE_DIR} )
 117 endif(PLUTO_FOUND)
 118 INCLUDE_DIRECTORIES( ${ISL_INCLUDE_DIR} )
 119 if (GMP_FOUND)
 120   INCLUDE_DIRECTORIES( ${GMP_INCLUDE_DIR} )
 121 endif(GMP_FOUND)
 122
 123 # Support GPGPU code generation if the library is available.
 124 if (CUDALIB_FOUND)
 125   INCLUDE_DIRECTORIES( ${CUDALIB_INCLUDE_DIR} )
 126 endif(CUDALIB_FOUND)
 127
 128 # Support OpenScop export/import if the library is available.
 129 if (OPENSCOP_FOUND)
 130   INCLUDE_DIRECTORIES( ${OPENSCOP_INCLUDE_DIR} )
 131 endif(OPENSCOP_FOUND)
 132 if (SCOPLIB_FOUND)
 133   INCLUDE_DIRECTORIES( ${SCOPLIB_INCLUDE_DIR} )
 134 endif(SCOPLIB_FOUND)
 135
 136
 137 include_directories(
 138   ${CMAKE_CURRENT_SOURCE_DIR}/include
 139   ${CMAKE_CURRENT_SOURCE_DIR}/lib/JSON/include
 140   ${CMAKE_CURRENT_BINARY_DIR}/include
 141   )
 142
 143 install(DIRECTORY include/
 144   DESTINATION include
 145   FILES_MATCHING
 146   PATTERN "*.h"
 147   PATTERN ".svn" EXCLUDE
 148   )
 149
 150 install(DIRECTORY ${POLLY_BINARY_DIR}/include/
 151   DESTINATION include
 152   FILES_MATCHING
 153   PATTERN "*.h"
 154   PATTERN "CMakeFiles" EXCLUDE
 155   PATTERN ".svn" EXCLUDE
 156   )
 157
 158 add_definitions( -D_GNU_SOURCE )
 159
 160 add_subdirectory(include)
 161 add_subdirectory(lib)
 162 add_subdirectory(test)
 163 add_subdirectory(tools)
 164 # TODO: docs.
 165
 166
 167 configure_file( ${CMAKE_CURRENT_SOURCE_DIR}/include/polly/Config/config.h.cmake
 168                 ${POLLY_BINARY_DIR}/include/polly/Config/config.h )
 169
 170 # Add target to check formatting of polly files
 171 file( GLOB_RECURSE files *.h *.cpp)
 172 file( GLOB_RECURSE jsonfiles lib/JSON/*.h lib/JSON/*.cpp)
 173 list( REMOVE_ITEM files ${jsonfiles} )
 174 add_custom_command( OUTPUT formatting COMMAND
 175   CLANG_FORMAT=${LLVM_BINARY_DIR}/bin/clang-format
 176   ${CMAKE_CURRENT_SOURCE_DIR}/utils/check_format.sh ${files})
 177 add_custom_target(polly-check-format DEPENDS formatting)
 178 add_custom_command( OUTPUT formatting-update COMMAND
 179   CLANG_FORMAT=${LLVM_BINARY_DIR}/bin/clang-format
 180   ${CMAKE_CURRENT_SOURCE_DIR}/utils/update_format.sh ${files})
 181 add_custom_target(polly-update-format DEPENDS formatting-update)