test/ScopInfo/multidim_nested_start_share_parameter.ll

   1 ; RUN: opt %loadPolly -polly-detect-unprofitable -polly-scops -analyze -polly-delinearize < %s | FileCheck %s
   2 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
   3 target triple = "x86_64-unknown-linux-gnu"
   4
   5 ; void foo(long n, long m, long o, double A[n][m][o]) {
   6 ;
   7 ;   for (long i = 0; i < n-13; i++)
   8 ;     for (long j = 14; j < m; j++)
   9 ;       for (long k = 0; k < o-17; k++) {
  10 ;         A[i+3][j-4][k+7] = 1.0;
  11 ;         A[i+13][j-14][k+17] = 11.0;
  12 ;       }
  13 ; }
  14 ;
  15 ; CHECK: Assumed Context:
  16 ; CHECK:   {  :  }
  17 ; CHECK: p0: %n
  18 ; CHECK: p1: %m
  19 ; CHECK: p2: %o
  20 ; CHECK-NOT: p3
  21 ;
  22 ; CHECK:   [n, m, o] -> { Stmt_for_k[i0, i1, i2] -> MemRef_A[3 + i0, 10 + i1, 7 + i2] };
  23 ; CHECK:   [n, m, o] -> { Stmt_for_k[i0, i1, i2] -> MemRef_A[13 + i0, i1, 17 + i2] };
  24
  25 define void @foo(i64 %n, i64 %m, i64 %o, double* %A) {
  26 entry:
  27   br label %for.i
  28
  29 for.i:
  30   %i = phi i64 [ 0, %entry ], [ %i.inc, %for.i.inc ]
  31   br label %for.j
  32
  33 for.j:
  34   %j = phi i64 [ 14, %for.i ], [ %j.inc, %for.j.inc ]
  35   br label %for.k
  36
  37 for.k:
  38   %k = phi i64 [ 0, %for.j ], [ %k.inc, %for.k.inc ]
  39
  40   %offset0 = add nsw i64 %i, 3
  41   %subscript0 = mul i64 %offset0, %m
  42   %offset1 = add nsw i64 %j, -4
  43   %subscript1 = add i64 %offset1, %subscript0
  44   %subscript2 = mul i64 %subscript1, %o
  45   %offset2 = add nsw i64 %k, 7
  46   %subscript3 = add i64 %subscript2, %offset2
  47   %idx = getelementptr inbounds double, double* %A, i64 %subscript3
  48   store double 1.0, double* %idx
  49
  50   %offset3 = add nsw i64 %i, 13
  51   %subscript4 = mul i64 %offset3, %m
  52   %offset4 = add nsw i64 %j, -14
  53   %subscript5 = add i64 %offset4, %subscript4
  54   %subscript6 = mul i64 %subscript5, %o
  55   %offset5 = add nsw i64 %k, 17
  56   %subscript7 = add i64 %subscript6, %offset5
  57   %idx1 = getelementptr inbounds double, double* %A, i64 %subscript7
  58   store double 11.0, double* %idx1
  59
  60   br label %for.k.inc
  61
  62 for.k.inc:
  63   %k.inc = add nsw i64 %k, 1
  64   %osub = sub nsw i64 %o, 17
  65   %k.exitcond = icmp eq i64 %k.inc, %osub
  66   br i1 %k.exitcond, label %for.j.inc, label %for.k
  67
  68 for.j.inc:
  69   %j.inc = add nsw i64 %j, 1
  70   %j.exitcond = icmp eq i64 %j.inc, %m
  71   br i1 %j.exitcond, label %for.i.inc, label %for.j
  72
  73 for.i.inc:
  74   %i.inc = add nsw i64 %i, 1
  75   %nsub = sub nsw i64 %n, 13
  76   %i.exitcond = icmp eq i64 %i.inc, %nsub
  77   br i1 %i.exitcond, label %end, label %for.i
  78
  79 end:
  80   ret void
  81 }