test/ScopInfo/multidim_nested_start_integer.ll

   1 ; RUN: opt %loadPolly -polly-detect-unprofitable -polly-scops -analyze -polly-delinearize < %s | FileCheck %s
   2 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
   3 target triple = "x86_64-unknown-linux-gnu"
   4
   5 ; void foo(long n, long m, long o, double A[n][m][o]) {
   6 ;   for (long i = 0; i < n - 3; i++)
   7 ;     for (long j = 4; j < m; j++)
   8 ;       for (long k = 0; k < o - 7; k++)
   9 ;         A[i+3][j-4][k+7] = 1.0;
  10 ; }
  11 ;
  12 ; CHECK: Assumed Context:
  13 ; CHECK:   {  :  }
  14 ; CHECK: p0: %n
  15 ; CHECK: p1: %m
  16 ; CHECK: p2: %o
  17 ; CHECK-NOT: p3
  18 ; CHECK: Domain
  19 ; CHECK:   [n, m, o] -> { Stmt_for_k[i0, i1, i2] : i0 >= 0 and i0 <= -4 + n and i1 >= 0 and i1 <= -5 + m and i2 >= 0 and i2 <= -8 + o };
  20 ; CHECK: Scattering
  21 ; CHECK:   [n, m, o] -> { Stmt_for_k[i0, i1, i2] -> [i0, i1, i2] };
  22 ; CHECK: MustWriteAccess
  23 ; CHECK:   [n, m, o] -> { Stmt_for_k[i0, i1, i2] -> MemRef_A[3 + i0, i1, 7 + i2] };
  24
  25 define void @foo(i64 %n, i64 %m, i64 %o, double* %A) {
  26 entry:
  27   br label %for.i
  28
  29 for.i:
  30   %i = phi i64 [ 0, %entry ], [ %i.inc, %for.i.inc ]
  31   br label %for.j
  32
  33 for.j:
  34   %j = phi i64 [ 4, %for.i ], [ %j.inc, %for.j.inc ]
  35   br label %for.k
  36
  37 for.k:
  38   %k = phi i64 [ 0, %for.j ], [ %k.inc, %for.k.inc ]
  39   %offset0 = add nsw i64 %i, 3
  40   %subscript0 = mul i64 %offset0, %m
  41   %offset1 = add nsw i64 %j, -4
  42   %subscript1 = add i64 %offset1, %subscript0
  43   %subscript2 = mul i64 %subscript1, %o
  44   %offset2 = add nsw i64 %k, 7
  45   %subscript = add i64 %subscript2, %offset2
  46   %idx = getelementptr inbounds double, double* %A, i64 %subscript
  47   store double 1.0, double* %idx
  48   br label %for.k.inc
  49
  50 for.k.inc:
  51   %k.inc = add nsw i64 %k, 1
  52   %osub = sub nsw i64 %o, 7
  53   %k.exitcond = icmp eq i64 %k.inc, %osub
  54   br i1 %k.exitcond, label %for.j.inc, label %for.k
  55
  56 for.j.inc:
  57   %j.inc = add nsw i64 %j, 1
  58   %j.exitcond = icmp eq i64 %j.inc, %m
  59   br i1 %j.exitcond, label %for.i.inc, label %for.j
  60
  61 for.i.inc:
  62   %i.inc = add nsw i64 %i, 1
  63   %nsub = sub nsw i64 %n, 3
  64   %i.exitcond = icmp eq i64 %i.inc, %nsub
  65   br i1 %i.exitcond, label %end, label %for.i
  66
  67 end:
  68   ret void
  69 }