test/ScopInfo/multidim_ivs_and_parameteric_offsets_3d.ll

   1 ; RUN: opt %loadPolly -polly-detect-unprofitable -polly-scops -analyze -polly-delinearize < %s | FileCheck %s
   2 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
   3 target triple = "x86_64-unknown-linux-gnu"
   4
   5 ; void foo(long n, long m, long o, double A[n][m][o], long p, long q, long r) {
   6 ;
   7 ;   for (long i = 0; i < n; i++)
   8 ;     for (long j = 0; j < m; j++)
   9 ;       for (long k = 0; k < o; k++)
  10 ;         A[i+p][j+q][k+r] = 1.0;
  11 ; }
  12 ;
  13 ; Access function:
  14 ;    {{{((8 * ((((%m * %p) + %q) * %o) + %r)) + %A),+,(8 * %m * %o)}<%for.i>,+,
  15 ;        (8 * %o)}<%for.j>,+,8}<%for.k>
  16
  17 ; CHECK: Assumed Context:
  18 ; CHECK: [n, m, o, p, q, r] -> { : q = 0 and r = 0 }
  19 ;
  20 ; CHECK: p0: %n
  21 ; CHECK: p1: %m
  22 ; CHECK: p2: %o
  23 ; CHECK: p3: %p
  24 ; CHECK: p4: %q
  25 ; CHECK: p5: %r
  26 ; CHECK-NOT: p6
  27 ;
  28 ; CHECK: Domain
  29 ; CHECK:   [n, m, o, p, q, r] -> { Stmt_for_k[i0, i1, i2] : i0 >= 0 and i0 <= -1 + n and i1 >= 0 and i1 <= -1 + m and i2 >= 0 and i2 <= -1 + o };
  30 ; CHECK: Scattering
  31 ; CHECK:   [n, m, o, p, q, r] -> { Stmt_for_k[i0, i1, i2] -> [i0, i1, i2] };
  32 ; CHECK: MustWriteAccess
  33 ; CHECK:   [n, m, o, p, q, r] -> { Stmt_for_k[i0, i1, i2] -> MemRef_A[p + i0, q + i1, r + i2] };
  34
  35 define void @foo(i64 %n, i64 %m, i64 %o, double* %A, i64 %p, i64 %q, i64 %r) {
  36 entry:
  37   br label %for.i
  38
  39 for.i:
  40   %i = phi i64 [ 0, %entry ], [ %i.inc, %for.i.inc ]
  41   br label %for.j
  42
  43 for.j:
  44   %j = phi i64 [ 0, %for.i ], [ %j.inc, %for.j.inc ]
  45   br label %for.k
  46
  47 for.k:
  48   %k = phi i64 [ 0, %for.j ], [ %k.inc, %for.k.inc ]
  49   %offset0 = add nsw i64 %i, %p
  50   %subscript0 = mul i64 %offset0, %m
  51   %offset1 = add nsw i64 %j, %q
  52   %subscript1 = add i64 %offset1, %subscript0
  53   %subscript2 = mul i64 %subscript1, %o
  54   %offset2 = add nsw i64 %k, %r
  55   %subscript = add i64 %subscript2, %offset2
  56   %idx = getelementptr inbounds double, double* %A, i64 %subscript
  57   store double 1.0, double* %idx
  58   br label %for.k.inc
  59
  60 for.k.inc:
  61   %k.inc = add nsw i64 %k, 1
  62   %k.exitcond = icmp eq i64 %k.inc, %o
  63   br i1 %k.exitcond, label %for.j.inc, label %for.k
  64
  65 for.j.inc:
  66   %j.inc = add nsw i64 %j, 1
  67   %j.exitcond = icmp eq i64 %j.inc, %m
  68   br i1 %j.exitcond, label %for.i.inc, label %for.j
  69
  70 for.i.inc:
  71   %i.inc = add nsw i64 %i, 1
  72   %i.exitcond = icmp eq i64 %i.inc, %n
  73   br i1 %i.exitcond, label %end, label %for.i
  74
  75 end:
  76   ret void
  77 }