cmake/CMakeLists.txt

   1 # Keep this in sync with llvm/cmake/CMakeLists.txt!
   2 if (LLVM_INSTALL_ROOT)
   3   # this simplifies things down the road, by not requiring to distinguish
   4   # between in-tree and out of tree builds
   5   set(LLVM_BINARY_DIR ${LLVM_INSTALL_ROOT})
   6 endif()
   7
   8 set(LLVM_INSTALL_PACKAGE_DIR "lib${LLVM_LIBDIR_SUFFIX}/cmake/llvm")
   9 set(POLLY_INSTALL_PACKAGE_DIR "lib${LLVM_LIBDIR_SUFFIX}/cmake/polly")
  10 if (CMAKE_CONFIGURATION_TYPES)
  11   set(POLLY_EXPORTS_FILE_NAME "PollyExports-$<LOWER_CASE:$<CONFIG>>.cmake")
  12 else()
  13   # avoid conflicts in the build-tree when changing configuration
  14   set(POLLY_EXPORTS_FILE_NAME "PollyExports-all.cmake")
  15 endif()
  16
  17 set(POLLY_CONFIG_EXPORTED_TARGETS Polly ${ISL_TARGET})
  18 if (NOT MSVC)
  19   # LLVMPolly is a dummy target on Win
  20   list(APPEND POLLY_CONFIG_EXPORTED_TARGETS LLVMPolly)
  21 endif()
  22 if (POLLY_ENABLE_GPGPU_CODEGEN)
  23   list(APPEND POLLY_CONFIG_EXPORTED_TARGETS PollyPPCG)
  24 endif()
  25
  26 # Get the target type for every exported target
  27 foreach(tgt IN LISTS POLLY_CONFIG_EXPORTED_TARGETS)
  28   get_target_property(tgt_type ${tgt} TYPE)
  29   string(REPLACE "_LIBRARY" "" tgt_type ${tgt_type})
  30   set(POLLY_CONFIG_TARGET_${tgt}_TYPE ${tgt_type})
  31 endforeach()
  32
  33 set(llvm_cmake_builddir "${LLVM_BINARY_DIR}/${LLVM_INSTALL_PACKAGE_DIR}")
  34 set(POLLY_CONFIG_LLVM_CMAKE_DIR "${llvm_cmake_builddir}")
  35
  36 # generate the import code for bundled/undbundled libisl versions
  37 if (NOT POLLY_BUNDLED_ISL)
  38   get_property(incl TARGET ISL PROPERTY INTERFACE_INCLUDE_DIRECTORIES)
  39   get_property(lib TARGET ISL PROPERTY INTERFACE_LINK_LIBRARIES)
  40   get_property(opt TARGET ISL PROPERTY INTERFACE_COMPILE_OPTIONS)
  41   set(ISL_CONFIG_CODE "
  42 add_library(ISL INTERFACE IMPORTED)
  43 set_property(TARGET ISL APPEND PROPERTY INTERFACE_INCLUDE_DIRECTORIES ${incl})
  44 set_property(TARGET ISL APPEND PROPERTY INTERFACE_LINK_LIBRARIES ${lib})
  45 set_property(TARGET ISL APPEND PROPERTY INTERFACE_COMPILE_OPTIONS ${opt})")
  46 else()
  47   set(ISL_CONFIG_CODE "
  48 if (NOT TARGET PollyISL)
  49   add_library(PollyISL ${POLLY_CONFIG_TARGET_PollyISL_TYPE} IMPORTED)
  50 endif()")
  51 endif()
  52
  53 # Generate PollyConfig.cmake for the build tree.
  54 set(POLLY_CONFIG_CMAKE_DIR "${CMAKE_BINARY_DIR}/${POLLY_INSTALL_PACKAGE_DIR}")
  55 set(POLLY_CONFIG_INCLUDE_DIRS ${ISL_INCLUDE_DIRS})
  56 set(POLLY_CONFIG_LIBRARY_DIRS "${POLLY_BINARY_DIR}/lib")
  57
  58 # set locations for imported targets
  59 foreach(tgt IN LISTS POLLY_CONFIG_EXPORTED_TARGETS)
  60   get_target_property(tgt_type ${tgt} TYPE)
  61   if (NOT tgt_type STREQUAL "INTERFACE_LIBRARY")
  62     set(POLLY_EXPORTS
  63       "set_target_properties(${tgt} PROPERTIES
  64               IMPORTED_LOCATION_$<UPPER_CASE:$<CONFIG>> $<TARGET_FILE:${tgt}>)
  65 ${POLLY_EXPORTS}")
  66   endif()
  67 endforeach(tgt)
  68
  69 # PollyConfig holds the target definitions and general settings, PollyExports
  70 # the imported locations
  71 configure_file(
  72   ${CMAKE_CURRENT_SOURCE_DIR}/PollyConfig.cmake.in
  73   ${POLLY_CONFIG_CMAKE_DIR}/PollyConfig.cmake
  74   @ONLY)
  75
  76 file(GENERATE
  77   OUTPUT ${POLLY_CONFIG_CMAKE_DIR}/${POLLY_EXPORTS_FILE_NAME}
  78   CONTENT "${POLLY_EXPORTS}")
  79
  80
  81 # Generate PollyConfig.cmake for the install tree.
  82 unset(POLLY_EXPORTS)
  83 set(POLLY_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")
  84 set(POLLY_CONFIG_LLVM_CMAKE_DIR "${LLVM_BINARY_DIR}/${LLVM_INSTALL_PACKAGE_DIR}")
  85 set(POLLY_CONFIG_CMAKE_DIR "${POLLY_INSTALL_PREFIX}/${POLLY_INSTALL_PACKAGE_DIR}")
  86 set(POLLY_CONFIG_LIBRARY_DIRS "${POLLY_INSTALL_PREFIX}/lib${LLVM_LIBDIR_SUFFIX}")
  87 if (POLLY_BUNDLED_ISL)
  88   set(POLLY_CONFIG_INCLUDE_DIRS "${POLLY_INSTALL_PREFIX}/include/polly")
  89 else()
  90   set(POLLY_CONFIG_INCLUDE_DIRS ${ISL_INCLUDE_DIRS})
  91 endif()
  92
  93 # set locations for imported targets. The path is constructed to be relative to
  94 # the config file
  95 foreach(tgt IN LISTS POLLY_CONFIG_EXPORTED_TARGETS)
  96   get_target_property(tgt_type ${tgt} TYPE)
  97   if (tgt_type STREQUAL "EXECUTABLE")
  98     set(tgt_prefix "bin/")
  99   else()
 100     set(tgt_prefix "lib/")
 101   endif()
 102
 103   set(tgt_path "${CMAKE_INSTALL_PREFIX}/${tgt_prefix}$<TARGET_FILE_NAME:${tgt}>")
 104   file(RELATIVE_PATH tgt_path ${POLLY_CONFIG_CMAKE_DIR} ${tgt_path})
 105
 106   if (NOT tgt_type STREQUAL "INTERFACE_LIBRARY")
 107     set(POLLY_EXPORTS
 108 "set_target_properties(${tgt} PROPERTIES
 109         IMPORTED_LOCATION_$<UPPER_CASE:$<CONFIG>> \${CMAKE_CURRENT_LIST_DIR}/${tgt_path})
 110 ${POLLY_EXPORTS}")
 111   endif()
 112 endforeach(tgt)
 113
 114 configure_file(
 115   ${CMAKE_CURRENT_SOURCE_DIR}/PollyConfig.cmake.in
 116   ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/PollyConfig.cmake
 117   @ONLY)
 118 file(GENERATE OUTPUT
 119   ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${POLLY_EXPORTS_FILE_NAME}
 120   CONTENT "${POLLY_EXPORTS}")
 121
 122 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 123   install(
 124     FILES
 125     "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/PollyConfig.cmake"
 126     "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${POLLY_EXPORTS_FILE_NAME}"
 127     DESTINATION "${POLLY_INSTALL_PACKAGE_DIR}")
 128 endif ()