CMakeLists.txt

   1 # Check if this is a in tree build.
   2 if (NOT DEFINED LLVM_MAIN_SRC_DIR)
   3   project(Polly)
   4   cmake_minimum_required(VERSION 2.8)
   5
   6   # Where is LLVM installed?
   7   set(LLVM_INSTALL_ROOT "" CACHE PATH "Root of LLVM install.")
   8   # Check if the LLVM_INSTALL_ROOT valid.
   9   if( NOT EXISTS ${LLVM_INSTALL_ROOT}/include/llvm )
  10     message(FATAL_ERROR "LLVM_INSTALL_ROOT (${LLVM_INSTALL_ROOT}) is not a valid LLVM installation.")
  11   endif(NOT EXISTS ${LLVM_INSTALL_ROOT}/include/llvm)
  12   # FileCheck, not and llvm-lit are not install by default, warn the user to copy them.
  13   if( NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/FileCheck
  14       OR NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/not
  15       OR NOT EXISTS ${LLVM_INSTALL_ROOT}/bin/llvm-lit )
  16     message(WARNING "'FileCheck', 'not' and 'llvm-lit' are required by running regress tests, "
  17                     "but they are not installed! Please copy them to "
  18                     "${LLVM_INSTALL_ROOT}/bin.")
  19   endif()
  20   # Add the llvm header path.
  21   include_directories(${LLVM_INSTALL_ROOT}/include/)
  22
  23   # Get the system librarys that will link into LLVM.
  24   function(get_system_libs return_var)
  25     # Returns in `return_var' a list of system libraries used by LLVM.
  26     if( NOT MSVC )
  27       if( MINGW )
  28         set(system_libs ${system_libs} imagehlp psapi)
  29       elseif( CMAKE_HOST_UNIX )
  30         if( HAVE_LIBDL )
  31           set(system_libs ${system_libs} ${CMAKE_DL_LIBS})
  32         endif()
  33         if( LLVM_ENABLE_THREADS AND HAVE_LIBPTHREAD )
  34           set(system_libs ${system_libs} pthread)
  35         endif()
  36       endif( MINGW )
  37     endif( NOT MSVC )
  38     set(${return_var} ${system_libs} PARENT_SCOPE)
  39   endfunction(get_system_libs)
  40
  41   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --libdir
  42                   OUTPUT_VARIABLE LLVM_LIBRARY_DIR
  43                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  44   link_directories("${LLVM_LIBRARY_DIR}")
  45
  46   # Now set the header paths.
  47   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --includedir
  48                   OUTPUT_VARIABLE LLVM_INCLUDE_DIR
  49                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  50   include_directories( ${LLVM_INCLUDE_DIR} )
  51
  52   # Get the TARGET_TRIPLE
  53   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --host-target
  54                   OUTPUT_VARIABLE TARGET_TRIPLE
  55                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  56
  57   # And then set the cxx flags.
  58   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --cxxflags
  59                   OUTPUT_VARIABLE LLVM_CXX_FLAGS
  60                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  61   set(CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS} ${LLVM_CXX_FLAGS})
  62
  63   # Check LLVM_ENABLE_ASSERTIONS
  64   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --assertion-mode
  65                   OUTPUT_VARIABLE LLVM_ENABLE_ASSERTIONS
  66                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  67   # Copied from LLVM's HandleLLVMOptions.cmake
  68   if( LLVM_ENABLE_ASSERTIONS )
  69     # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  70     if( NOT MSVC )
  71       add_definitions( -D_DEBUG )
  72     endif()
  73     # On non-Debug builds cmake automatically defines NDEBUG, so we
  74     # explicitly undefine it:
  75     if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  76       add_definitions( -UNDEBUG )
  77       # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  78       foreach (flags_var_to_scrub
  79           CMAKE_CXX_FLAGS_RELEASE
  80           CMAKE_CXX_FLAGS_RELWITHDEBINFO
  81           CMAKE_CXX_FLAGS_MINSIZEREL
  82           CMAKE_C_FLAGS_RELEASE
  83           CMAKE_C_FLAGS_RELWITHDEBINFO
  84           CMAKE_C_FLAGS_MINSIZEREL)
  85         string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  86           "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  87       endforeach()
  88     endif()
  89   endif()
  90
  91   # Sources available, too?
  92   execute_process(COMMAND "${LLVM_INSTALL_ROOT}/bin/llvm-config" --src-root
  93                   OUTPUT_VARIABLE MAIN_SRC_DIR
  94                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  95   set(LLVM_SOURCE_ROOT ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  96
  97   # Enable unit tests if available.
  98   set(UNITTEST_DIR ${LLVM_SOURCE_ROOT}/utils/unittest)
  99   if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h)
 100     add_library(gtest ${UNITTEST_DIR}/googletest/src/gtest-all.cc)
 101     target_include_directories(gtest PUBLIC "${UNITTEST_DIR}/googletest/include" PRIVATE "${UNITTEST_DIR}/googletest")
 102     if( NOT MSVC )
 103       target_link_libraries(gtest pthread tinfo dl)
 104     endif ()
 105
 106     add_library(gtest_main ${UNITTEST_DIR}/UnitTestMain/TestMain.cpp)
 107     target_link_libraries(gtest_main gtest)
 108
 109     set(POLLY_GTEST_AVAIL 1)
 110   endif()
 111
 112   # Make sure the isl c files are built as fPIC
 113   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
 114 else ()
 115   set(LLVM_SOURCE_ROOT "${LLVM_MAIN_SRC_DIR}")
 116   set(POLLY_GTEST_AVAIL 1)
 117 endif ()
 118
 119 set(POLLY_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 120 set(POLLY_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 121
 122 # Add path for custom modules
 123 set(CMAKE_MODULE_PATH
 124   ${CMAKE_MODULE_PATH}
 125   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 126   )
 127
 128 include("polly_macros")
 129
 130 # Add appropriate flags for GCC
 131 if (CMAKE_COMPILER_IS_GNUCXX)
 132   # FIXME: Turn off exceptions, RTTI:
 133   # -fno-exceptions -fno-rtti
 134   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual -Wno-long-long -Wall -W -Wno-unused-parameter -Wwrite-strings -fno-exceptions -fno-rtti")
 135 elseif (MSVC)
 136   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHs-c-")
 137   add_definitions("-D_HAS_EXCEPTIONS=0")
 138 else ()
 139   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
 140 endif ()
 141
 142 # Add path for custom modules
 143 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${POLLY_SOURCE_DIR}/cmake")
 144
 145 SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 146
 147 option(POLLY_ENABLE_GPGPU_CODEGEN "Enable GPGPU code generation feature" OFF)
 148 if (POLLY_ENABLE_GPGPU_CODEGEN)
 149   # Do not require CUDA, as GPU code generation test cases can be run without
 150   # a cuda library.
 151   FIND_PACKAGE(CUDA)
 152   set(GPU_CODEGEN TRUE)
 153 else(POLLY_ENABLE_GPGPU_CODEGEN)
 154   set(GPU_CODEGEN FALSE)
 155 endif(POLLY_ENABLE_GPGPU_CODEGEN)
 156
 157
 158 # Support GPGPU code generation if the library is available.
 159 if (CUDALIB_FOUND)
 160   INCLUDE_DIRECTORIES( ${CUDALIB_INCLUDE_DIR} )
 161 endif(CUDALIB_FOUND)
 162
 163 include_directories(
 164   BEFORE
 165   ${CMAKE_CURRENT_SOURCE_DIR}/include
 166   ${CMAKE_CURRENT_SOURCE_DIR}/lib/JSON/include
 167   ${CMAKE_CURRENT_BINARY_DIR}/lib/External/isl/include
 168   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External/isl/include
 169   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External/pet/include
 170   ${CMAKE_CURRENT_SOURCE_DIR}/lib/External
 171   ${CMAKE_CURRENT_BINARY_DIR}/include
 172   )
 173
 174 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 175   install(DIRECTORY include/
 176     DESTINATION include
 177     FILES_MATCHING
 178     PATTERN "*.h"
 179     PATTERN ".svn" EXCLUDE
 180     )
 181
 182   install(DIRECTORY ${POLLY_BINARY_DIR}/include/
 183     DESTINATION include
 184     FILES_MATCHING
 185     PATTERN "*.h"
 186     PATTERN "CMakeFiles" EXCLUDE
 187     PATTERN ".svn" EXCLUDE
 188     )
 189 endif()
 190
 191 add_definitions( -D_GNU_SOURCE )
 192
 193 add_subdirectory(docs)
 194 add_subdirectory(lib)
 195 add_subdirectory(test)
 196 if (POLLY_GTEST_AVAIL)
 197   add_subdirectory(unittests)
 198 endif ()
 199 add_subdirectory(tools)
 200 # TODO: docs.
 201
 202
 203 configure_file( ${CMAKE_CURRENT_SOURCE_DIR}/include/polly/Config/config.h.cmake
 204                 ${POLLY_BINARY_DIR}/include/polly/Config/config.h )
 205
 206 # Add target to check formatting of polly files
 207 file( GLOB_RECURSE files *.h lib/*.cpp lib/*.c tools/*.cpp tools/*.c tools/*.h unittests/*.cpp)
 208 file( GLOB_RECURSE jsonfiles lib/JSON/*.h lib/JSON/*.cpp)
 209 file( GLOB_RECURSE external lib/External/*.h lib/External/*.c)
 210 list( REMOVE_ITEM files ${jsonfiles} ${external})
 211
 212 set(check_format_depends)
 213 set(update_format_depends)
 214 set(i 0)
 215 foreach (file IN LISTS files)
 216   add_custom_command(OUTPUT polly-check-format${i}
 217     COMMAND clang-format -sort-includes -style=llvm ${file} | diff -u ${file} -
 218     VERBATIM
 219     COMMENT "Checking format of ${file}..."
 220   )
 221   list(APPEND check_format_depends "polly-check-format${i}")
 222
 223   add_custom_command(OUTPUT polly-update-format${i}
 224     COMMAND clang-format -sort-includes -i -style=llvm ${file}
 225     VERBATIM
 226     COMMENT "Updating format of ${file}..."
 227   )
 228   list(APPEND update_format_depends "polly-update-format${i}")
 229
 230   math(EXPR i ${i}+1)
 231 endforeach ()
 232
 233 add_custom_target(polly-check-format DEPENDS ${check_format_depends})
 234 set_target_properties(polly-check-format PROPERTIES FOLDER "Polly")
 235
 236 add_custom_target(polly-update-format DEPENDS ${update_format_depends})
 237 set_target_properties(polly-update-format PROPERTIES FOLDER "Polly")
 238
 239 # Set the variable POLLY_LINK_LIBS in the llvm/tools/ dir.
 240 set(POLLY_LINK_LIBS ${POLLY_LINK_LIBS} PARENT_SCOPE)