planner-timeclock.el

   1 ;;; planner-timeclock.el --- Timeclock integration for the Emacs Planner
   2
   3 ;; Copyright (C) 2001, 2004, 2005 Free Software Foundation, Inc.
   4 ;; Parts copyright (C) 2005 Peter K. Lee
   5
   6 ;; Author: John Wiegley <johnw@gnu.org>
   7 ;; Keywords: planner, timeclock
   8 ;; URL: http://www.plannerlove.com/
   9
  10 ;; This file is part of Planner.  It is not part of GNU Emacs.
  11
  12 ;; Planner is free software; you can redistribute it and/or modify it
  13 ;; under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; Planner is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with Planner; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This module allows you to clock in and clock out of your projects.
  30 ;; You can also generate reports with the <timeclock-report> tag.
  31 ;;
  32 ;; timeclock.el is part of GNU Emacs.  If you are using XEmacs, please
  33 ;; use the version in the contrib directory -- otherwise, just use the
  34 ;; version that comes with Emacs.
  35
  36 ;;; Contributors:
  37
  38 ;; Yann Hodique helped port this to Muse.
  39
  40 ;; Peter K. Lee helped fix an issue involving planner-multi.el with
  41 ;; the Muse port.
  42
  43 ;;; Code:
  44
  45 (require 'planner)
  46 (require 'timeclock)
  47 (require 'planner-schedule)
  48 (require 'easymenu)
  49 (require 'advice)
  50
  51 (defvar planner-timeclock-current-task nil
  52   "Description of current task.")
  53
  54 (defalias 'planner-timeclock-in 'planner-task-in-progress)
  55
  56 (defadvice timeclock-out (after planner-timeclock activate)
  57   "Clear `planner-timeclock-current-task.'"
  58   (setq planner-timeclock-current-task nil))
  59
  60 (defun planner-timeclock-plan-string (task-info &optional plans)
  61   "Return the string for the plan part of the timeclock entry for TASK-INFO."
  62   (let ((plan-link (if (featurep 'planner-multi)
  63                        ;; Remove the date links
  64                        (planner-multi-make-link
  65                         (or (planner-multi-filter-links
  66                              planner-date-regexp
  67                              (if plans
  68                                  (planner-multi-split plans)
  69                                (planner-multi-task-link-as-list task-info))
  70                              t)
  71                             (list (planner-task-plan task-info))))
  72                      (planner-make-link
  73                       (or plans (planner-task-plan task-info))))))
  74     (if plan-link
  75         (concat plan-link ": ")
  76       "")))
  77
  78 (defun planner-timeclock-task-marked (old-status new-status)
  79   "Clock out if the task description matches the one clocked in."
  80   (cond
  81    ((string= new-status "X")
  82     (when (and planner-timeclock-current-task
  83                (string= (planner-task-description (planner-current-task-info))
  84                         planner-timeclock-current-task)
  85                (timeclock-currently-in-p))
  86       (timeclock-out 1)))
  87    ((string= new-status "P")
  88     (when (and planner-timeclock-current-task
  89              (string= (planner-task-description (planner-current-task-info))
  90                       planner-timeclock-current-task)
  91              (timeclock-currently-in-p))
  92     (timeclock-out)))
  93    ((string= new-status "o")
  94     (let* ((task-info (planner-current-task-info))
  95            (project (concat
  96                      (planner-timeclock-plan-string task-info)
  97                      (planner-task-description task-info))))
  98       (if (timeclock-currently-in-p)
  99           (timeclock-change nil project)
 100         (timeclock-in nil project))
 101       (setq planner-timeclock-current-task (planner-task-description task-info)))))
 102   t)
 103 (add-hook 'planner-mark-task-hook 'planner-timeclock-task-marked)
 104
 105 (defadvice planner-replan-task (around planner-timeclock activate)
 106   "Edit the clocked in task as well."
 107   (let ((info (planner-current-task-info)))
 108     ad-do-it
 109     (with-current-buffer (find-file-noselect timeclock-file)
 110       (goto-char (point-min))
 111       (while (re-search-forward
 112               (concat
 113                "^. [^ \n]+ [^ \n]+ "
 114                "\\(" (regexp-quote (planner-timeclock-plan-string info)) "\\)"
 115                (regexp-quote (planner-task-description info)) "$") nil t)
 116         (replace-match
 117          (save-match-data (planner-timeclock-plan-string nil (ad-get-arg 0)))
 118          t t nil 1))
 119       (save-buffer)
 120       (kill-buffer (current-buffer)))))
 121
 122 (defadvice planner-edit-task-description (around planner-timeclock activate)
 123   "Update the timelog as well. Warning! Do not have duplicate tasks!"
 124   (let ((info (planner-current-task-info)))
 125     (when (string= (planner-task-description info) planner-timeclock-current-task)
 126       (setq planner-timeclock-current-task (ad-get-arg 0)))
 127     ad-do-it
 128     (with-current-buffer (find-file-noselect timeclock-file)
 129       (goto-char (point-min))
 130       (while (re-search-forward
 131               (concat
 132                "^. [^ \n]+ [^ \n]+ "
 133                (regexp-quote (planner-timeclock-plan-string info))
 134                "\\("
 135                (regexp-quote (planner-task-description info))
 136                "\\)$")
 137               nil t)
 138         (replace-match (ad-get-arg 0) t t nil 1))
 139       (save-buffer)
 140       (kill-buffer (current-buffer)))))
 141
 142 ;;;###autoload
 143 (defun planner-timeclock-report-tag (beg end highlight-p)
 144   "Replace the region BEG to END with a timeclock report.
 145 If HIGHLIGHT-P is non-nil, the output is also displayed."
 146   (require 'timeclock)
 147   (if highlight-p
 148       (add-text-properties
 149        beg end (list 'display
 150                      (with-temp-buffer
 151                        (timeclock-generate-report muse-publishing-p)
 152                        (buffer-string))))
 153     (delete-region beg end)
 154     (timeclock-generate-report muse-publishing-p)
 155     (add-text-properties beg (point) '(read-only t))))
 156
 157 (add-to-list 'planner-markup-tags
 158              '("timeclock-report" nil nil t planner-timeclock-report-tag))
 159 (planner-option-customized 'planner-markup-tags planner-markup-tags)
 160
 161 (defun planner-timeclock-task-plan (info)
 162   "Return the first plan page associated with INFO."
 163   (car (elt info 0)))
 164
 165 (defun planner-timeclock-task-plan-as-list (info)
 166   "Return all the plan pages associated with INFO."
 167   (elt info 0))
 168
 169 (defun planner-timeclock-task-description (info)
 170   "Return the descrption associated with INFO."
 171   (elt info 1))
 172
 173 (defun planner-timeclock-task-length (info)
 174   "Return the length associated with INFO."
 175   (elt info 2))
 176
 177 (defun planner-timeclock-task-info (entry)
 178   "Parse ENTRY and return a list of the form (plan task length).
 179 See `timeclock-log-data' for the format of ENTRY. Note that the
 180 project field in `timeclock-log-data' is 'project: task' here."
 181    (let ((project (if (stringp entry) entry (timeclock-entry-project entry)))
 182          plan task)
 183     (when project
 184       (with-planner
 185         (cond
 186          ;; No plan, just the task
 187          ((string-match "^\\s-*:\\s-+" project)
 188           (setq task (substring project (match-end 0))))
 189          ;; Single link
 190          ((string-match (concat "^\\(" muse-explicit-link-regexp "\\): ") project)
 191           (setq plan (list (match-string 1 project)))
 192           (setq task (substring project (match-end 0))))
 193          ;; Multi link
 194          ((and
 195            (featurep 'planner-multi)
 196            (string-match
 197             (concat "^\\(\\(?:" muse-explicit-link-regexp "\\)"
 198                     "\\(?:" planner-multi-separator
 199                     "\\(?:" muse-explicit-link-regexp "\\)\\)*\\): ")
 200             project))
 201           (setq task (substring project (match-end 0)))
 202           (setq plan (planner-multi-split (match-string 1 project))))
 203          ;; Nothing whatsoever.
 204          (t (setq task project)))
 205         (list plan task (unless (stringp entry) (timeclock-entry-length entry)))))))
 206
 207 (condition-case nil
 208     (let ((map planner-mode-map))
 209       (define-key map "\C-c\C-i" 'planner-task-in-progress)
 210       (define-key map "\C-c\C-o" 'timeclock-out)
 211       (if (featurep 'xemacs)
 212           (progn
 213             (define-key map (kbd "C-c C-T C-i") 'planner-task-in-progress)
 214             (define-key map (kbd "C-c C-T C-o") 'timeclock-out))
 215         (define-key map (kbd "C-c C-S-t C-i") 'planner-task-in-progress)
 216         (define-key map (kbd "C-c C-S-t C-o") 'timeclock-out)))
 217   (error (message "Could not bind timeclock keys in planner mode")))
 218
 219 (condition-case nil
 220     ;; XEmacs seems to be missing this function in some released
 221     ;; versions of XEmacs21.
 222     (if (fboundp 'easy-menu-create-menu)
 223         (easy-menu-add-item planner-mode-map
 224                             '("Planner")
 225                             (easy-menu-create-menu
 226                              "Timeclock"
 227                              '(["Clock into a task" planner-timeclock-in]
 228                                ["Clock out" timeclock-out])))
 229       (easy-menu-add-item planner-menu
 230                           '("Timeclock")
 231                           ["Clock into a task" planner-timeclock-in t]
 232                           "Plan")
 233       (easy-menu-add-item planner-menu
 234                           '("Timeclock")
 235                           ["Clock out" timeclock-out t]
 236                           "Plan")))
 237
 238 (provide 'planner-timeclock)
 239
 240 ;;; planner-timeclock.el ends here