m4/ax_gcc_archflag.m4

   1 # ===========================================================================
   2 #            http://autoconf-archive.cryp.to/ax_gcc_archflag.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_GCC_ARCHFLAG([PORTABLE?], [ACTION-SUCCESS], [ACTION-FAILURE])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro tries to guess the "native" arch corresponding to the target
  12 #   architecture for use with gcc's -march=arch or -mtune=arch flags. If
  13 #   found, the cache variable $ax_cv_gcc_archflag is set to this flag and
  14 #   ACTION-SUCCESS is executed; otherwise $ax_cv_gcc_archflag is is set to
  15 #   "unknown" and ACTION-FAILURE is executed. The default ACTION-SUCCESS is
  16 #   to add $ax_cv_gcc_archflag to the end of $CFLAGS.
  17 #
  18 #   PORTABLE? should be either [yes] (default) or [no]. In the former case,
  19 #   the flag is set to -mtune (or equivalent) so that the architecture is
  20 #   only used for tuning, but the instruction set used is still portable. In
  21 #   the latter case, the flag is set to -march (or equivalent) so that
  22 #   architecture-specific instructions are enabled.
  23 #
  24 #   The user can specify --with-gcc-arch=<arch> in order to override the
  25 #   macro's choice of architecture, or --without-gcc-arch to disable this.
  26 #
  27 #   When cross-compiling, or if $CC is not gcc, then ACTION-FAILURE is
  28 #   called unless the user specified --with-gcc-arch manually.
  29 #
  30 #   Requires macros: AX_CHECK_COMPILER_FLAGS, AX_GCC_X86_CPUID
  31 #
  32 #   (The main emphasis here is on recent CPUs, on the principle that doing
  33 #   high-performance computing on old hardware is uncommon.)
  34 #
  35 # LAST MODIFICATION
  36 #
  37 #   2008-04-12
  38 #
  39 # COPYLEFT
  40 #
  41 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  42 #   Copyright (c) 2008 Matteo Frigo
  43 #
  44 #   This program is free software: you can redistribute it and/or modify it
  45 #   under the terms of the GNU General Public License as published by the
  46 #   Free Software Foundation, either version 3 of the License, or (at your
  47 #   option) any later version.
  48 #
  49 #   This program is distributed in the hope that it will be useful, but
  50 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  51 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  52 #   Public License for more details.
  53 #
  54 #   You should have received a copy of the GNU General Public License along
  55 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  56 #
  57 #   As a special exception, the respective Autoconf Macro's copyright owner
  58 #   gives unlimited permission to copy, distribute and modify the configure
  59 #   scripts that are the output of Autoconf when processing the Macro. You
  60 #   need not follow the terms of the GNU General Public License when using
  61 #   or distributing such scripts, even though portions of the text of the
  62 #   Macro appear in them. The GNU General Public License (GPL) does govern
  63 #   all other use of the material that constitutes the Autoconf Macro.
  64 #
  65 #   This special exception to the GPL applies to versions of the Autoconf
  66 #   Macro released by the Autoconf Macro Archive. When you make and
  67 #   distribute a modified version of the Autoconf Macro, you may extend this
  68 #   special exception to the GPL to apply to your modified version as well.
  69
  70 AC_DEFUN([AX_GCC_ARCHFLAG],
  71 [AC_REQUIRE([AC_PROG_CC])
  72 AC_REQUIRE([AC_CANONICAL_HOST])
  73
  74 AC_ARG_WITH(gcc-arch, [AC_HELP_STRING([--with-gcc-arch=<arch>], [use architecture <arch> for gcc -march/-mtune, instead of guessing])],
  75         ax_gcc_arch=$withval, ax_gcc_arch=yes)
  76
  77 AC_MSG_CHECKING([for gcc architecture flag])
  78 AC_MSG_RESULT([])
  79 AC_CACHE_VAL(ax_cv_gcc_archflag,
  80 [
  81 ax_cv_gcc_archflag="unknown"
  82
  83 if test "$GCC" = yes; then
  84
  85 if test "x$ax_gcc_arch" = xyes; then
  86 ax_gcc_arch=""
  87 if test "$cross_compiling" = no; then
  88 case $host_cpu in
  89   i[[3456]]86*|x86_64*) # use cpuid codes, in part from x86info-1.7 by D. Jones
  90      AX_GCC_X86_CPUID(0)
  91      AX_GCC_X86_CPUID(1)
  92      case $ax_cv_gcc_x86_cpuid_0 in
  93        *:756e6547:*:*) # Intel
  94           case $ax_cv_gcc_x86_cpuid_1 in
  95             *5[[48]]?:*:*:*) ax_gcc_arch="pentium-mmx pentium" ;;
  96             *5??:*:*:*) ax_gcc_arch=pentium ;;
  97             *6[[3456]]?:*:*:*) ax_gcc_arch="pentium2 pentiumpro" ;;
  98             *6a?:*[[01]]:*:*) ax_gcc_arch="pentium2 pentiumpro" ;;
  99             *6a?:*[[234]]:*:*) ax_gcc_arch="pentium3 pentiumpro" ;;
 100             *6[[9d]]?:*:*:*) ax_gcc_arch="pentium-m pentium3 pentiumpro" ;;
 101             *6[[78b]]?:*:*:*) ax_gcc_arch="pentium3 pentiumpro" ;;
 102             *6??:*:*:*) ax_gcc_arch=pentiumpro ;;
 103             *f3[[347]]:*:*:*|*f4[1347]:*:*:*)
 104                 case $host_cpu in
 105                   x86_64*) ax_gcc_arch="nocona pentium4 pentiumpro" ;;
 106                   *) ax_gcc_arch="prescott pentium4 pentiumpro" ;;
 107                 esac ;;
 108             *f??:*:*:*) ax_gcc_arch="pentium4 pentiumpro";;
 109           esac ;;
 110        *:68747541:*:*) # AMD
 111           case $ax_cv_gcc_x86_cpuid_1 in
 112             *5[[67]]?:*:*:*) ax_gcc_arch=k6 ;;
 113             *5[[8d]]?:*:*:*) ax_gcc_arch="k6-2 k6" ;;
 114             *5[[9]]?:*:*:*) ax_gcc_arch="k6-3 k6" ;;
 115             *60?:*:*:*) ax_gcc_arch=k7 ;;
 116             *6[[12]]?:*:*:*) ax_gcc_arch="athlon k7" ;;
 117             *6[[34]]?:*:*:*) ax_gcc_arch="athlon-tbird k7" ;;
 118             *67?:*:*:*) ax_gcc_arch="athlon-4 athlon k7" ;;
 119             *6[[68a]]?:*:*:*)
 120                AX_GCC_X86_CPUID(0x80000006) # L2 cache size
 121                case $ax_cv_gcc_x86_cpuid_0x80000006 in
 122                  *:*:*[[1-9a-f]]??????:*) # (L2 = ecx >> 16) >= 256
 123                         ax_gcc_arch="athlon-xp athlon-4 athlon k7" ;;
 124                  *) ax_gcc_arch="athlon-4 athlon k7" ;;
 125                esac ;;
 126             *f[[4cef8b]]?:*:*:*) ax_gcc_arch="athlon64 k8" ;;
 127             *f5?:*:*:*) ax_gcc_arch="opteron k8" ;;
 128             *f7?:*:*:*) ax_gcc_arch="athlon-fx opteron k8" ;;
 129             *f??:*:*:*) ax_gcc_arch="k8" ;;
 130           esac ;;
 131         *:746e6543:*:*) # IDT
 132            case $ax_cv_gcc_x86_cpuid_1 in
 133              *54?:*:*:*) ax_gcc_arch=winchip-c6 ;;
 134              *58?:*:*:*) ax_gcc_arch=winchip2 ;;
 135              *6[[78]]?:*:*:*) ax_gcc_arch=c3 ;;
 136              *69?:*:*:*) ax_gcc_arch="c3-2 c3" ;;
 137            esac ;;
 138      esac
 139      if test x"$ax_gcc_arch" = x; then # fallback
 140         case $host_cpu in
 141           i586*) ax_gcc_arch=pentium ;;
 142           i686*) ax_gcc_arch=pentiumpro ;;
 143         esac
 144      fi
 145      ;;
 146
 147   sparc*)
 148      AC_PATH_PROG([PRTDIAG], [prtdiag], [prtdiag], [$PATH:/usr/platform/`uname -i`/sbin/:/usr/platform/`uname -m`/sbin/])
 149      cputype=`(((grep cpu /proc/cpuinfo | cut -d: -f2) ; ($PRTDIAG -v |grep -i sparc) ; grep -i cpu /var/run/dmesg.boot ) | head -n 1) 2> /dev/null`
 150      cputype=`echo "$cputype" | tr -d ' -' |tr $as_cr_LETTERS $as_cr_letters`
 151      case $cputype in
 152          *ultrasparciv*) ax_gcc_arch="ultrasparc4 ultrasparc3 ultrasparc v9" ;;
 153          *ultrasparciii*) ax_gcc_arch="ultrasparc3 ultrasparc v9" ;;
 154          *ultrasparc*) ax_gcc_arch="ultrasparc v9" ;;
 155          *supersparc*|*tms390z5[[05]]*) ax_gcc_arch="supersparc v8" ;;
 156          *hypersparc*|*rt62[[056]]*) ax_gcc_arch="hypersparc v8" ;;
 157          *cypress*) ax_gcc_arch=cypress ;;
 158      esac ;;
 159
 160   alphaev5) ax_gcc_arch=ev5 ;;
 161   alphaev56) ax_gcc_arch=ev56 ;;
 162   alphapca56) ax_gcc_arch="pca56 ev56" ;;
 163   alphapca57) ax_gcc_arch="pca57 pca56 ev56" ;;
 164   alphaev6) ax_gcc_arch=ev6 ;;
 165   alphaev67) ax_gcc_arch=ev67 ;;
 166   alphaev68) ax_gcc_arch="ev68 ev67" ;;
 167   alphaev69) ax_gcc_arch="ev69 ev68 ev67" ;;
 168   alphaev7) ax_gcc_arch="ev7 ev69 ev68 ev67" ;;
 169   alphaev79) ax_gcc_arch="ev79 ev7 ev69 ev68 ev67" ;;
 170
 171   powerpc*)
 172      cputype=`((grep cpu /proc/cpuinfo | head -n 1 | cut -d: -f2 | cut -d, -f1 | sed 's/ //g') ; /usr/bin/machine ; /bin/machine; grep CPU /var/run/dmesg.boot | head -n 1 | cut -d" " -f2) 2> /dev/null`
 173      cputype=`echo $cputype | sed -e 's/ppc//g;s/ *//g'`
 174      case $cputype in
 175        *750*) ax_gcc_arch="750 G3" ;;
 176        *740[[0-9]]*) ax_gcc_arch="$cputype 7400 G4" ;;
 177        *74[[4-5]][[0-9]]*) ax_gcc_arch="$cputype 7450 G4" ;;
 178        *74[[0-9]][[0-9]]*) ax_gcc_arch="$cputype G4" ;;
 179        *970*) ax_gcc_arch="970 G5 power4";;
 180        *POWER4*|*power4*|*gq*) ax_gcc_arch="power4 970";;
 181        *POWER5*|*power5*|*gr*|*gs*) ax_gcc_arch="power5 power4 970";;
 182        603ev|8240) ax_gcc_arch="$cputype 603e 603";;
 183        *) ax_gcc_arch=$cputype ;;
 184      esac
 185      ax_gcc_arch="$ax_gcc_arch powerpc"
 186      ;;
 187 esac
 188 fi # not cross-compiling
 189 fi # guess arch
 190
 191 if test "x$ax_gcc_arch" != x -a "x$ax_gcc_arch" != xno; then
 192 for arch in $ax_gcc_arch; do
 193   if test "x[]m4_default([$1],yes)" = xyes; then # if we require portable code
 194     flags="-mtune=$arch"
 195     # -mcpu=$arch and m$arch generate nonportable code on every arch except
 196     # x86.  And some other arches (e.g. Alpha) don't accept -mtune.  Grrr.
 197     case $host_cpu in i*86|x86_64*) flags="$flags -mcpu=$arch -m$arch";; esac
 198   else
 199     flags="-march=$arch -mcpu=$arch -m$arch"
 200   fi
 201   for flag in $flags; do
 202     AX_CHECK_COMPILER_FLAGS($flag, [ax_cv_gcc_archflag=$flag; break])
 203   done
 204   test "x$ax_cv_gcc_archflag" = xunknown || break
 205 done
 206 fi
 207
 208 fi # $GCC=yes
 209 ])
 210 AC_MSG_CHECKING([for gcc architecture flag])
 211 AC_MSG_RESULT($ax_cv_gcc_archflag)
 212 if test "x$ax_cv_gcc_archflag" = xunknown; then
 213   m4_default([$3],:)
 214 else
 215   m4_default([$2], [CFLAGS="$CFLAGS $ax_cv_gcc_archflag"])
 216 fi
 217 ])