contrib/seg/meson.build

   1 # Copyright (c) 2022-2024, PostgreSQL Global Development Group
   2
   3 seg_sources = files(
   4   'seg.c',
   5 )
   6
   7 seg_scan = custom_target('segscan',
   8   input: 'segscan.l',
   9   output: 'segscan.c',
  10   command: flex_cmd,
  11 )
  12 generated_sources += seg_scan
  13 seg_sources += seg_scan
  14
  15 seg_parse = custom_target('segparse',
  16   input: 'segparse.y',
  17   kwargs: bison_kw,
  18 )
  19 generated_sources += seg_parse.to_list()
  20 seg_sources += seg_parse
  21
  22 if host_system == 'windows'
  23   seg_sources += rc_lib_gen.process(win32ver_rc, extra_args: [
  24     '--NAME', 'seg',
  25     '--FILEDESC', 'seg - line segment data type',])
  26 endif
  27
  28 seg = shared_module('seg',
  29   seg_sources,
  30   include_directories: include_directories('.'),
  31   kwargs: contrib_mod_args,
  32 )
  33 contrib_targets += seg
  34
  35 install_data(
  36   'seg.control',
  37   'seg--1.0--1.1.sql',
  38   'seg--1.1--1.2.sql',
  39   'seg--1.1.sql',
  40   'seg--1.2--1.3.sql',
  41   'seg--1.3--1.4.sql',
  42   kwargs: contrib_data_args,
  43 )
  44
  45 install_headers(
  46   'segdata.h',
  47   install_dir: dir_include_extension / 'seg',
  48 )
  49
  50 tests += {
  51   'name': 'seg',
  52   'sd': meson.current_source_dir(),
  53   'bd': meson.current_build_dir(),
  54   'regress': {
  55     'sql': [
  56       'security',
  57       'seg',
  58     ],
  59   },
  60 }