configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [9.3devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.63], [], [m4_fatal([Autoconf version 2.63 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2013, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58   cygwin*) template=cygwin ;;
  59   darwin*) template=darwin ;;
  60 dragonfly*) template=netbsd ;;
  61  freebsd*) template=freebsd ;;
  62     hpux*) template=hpux ;;
  63     irix*) template=irix ;;
  64  linux*|gnu*|k*bsd*-gnu)
  65            template=linux ;;
  66    mingw*) template=win32 ;;
  67   netbsd*) template=netbsd ;;
  68  openbsd*) template=openbsd ;;
  69      osf*) template=osf ;;
  70      sco*) template=sco ;;
  71  solaris*) template=solaris ;;
  72    sysv5*) template=unixware ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage: enabled by default.
 126 #
 127 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 128 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 129               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 130                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 131 AC_MSG_RESULT([$enable_integer_datetimes])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 #
 167 # '-rpath'-like feature can be disabled
 168 #
 169 PGAC_ARG_BOOL(enable, rpath, yes,
 170               [do not embed shared library search path in executables])
 171 AC_SUBST(enable_rpath)
 172
 173 #
 174 # Spinlocks
 175 #
 176 PGAC_ARG_BOOL(enable, spinlocks, yes,
 177               [do not use spinlocks])
 178
 179 #
 180 # --enable-debug adds -g to compiler flags
 181 #
 182 PGAC_ARG_BOOL(enable, debug, no,
 183               [build with debugging symbols (-g)])
 184 AC_SUBST(enable_debug)
 185
 186 #
 187 # --enable-profiling enables gcc profiling
 188 #
 189 PGAC_ARG_BOOL(enable, profiling, no,
 190               [build with profiling enabled ])
 191
 192 #
 193 # --enable-coverage enables generation of code coverage metrics with gcov
 194 #
 195 PGAC_ARG_BOOL(enable, coverage, no,
 196               [build with coverage testing instrumentation],
 197 [AC_CHECK_PROGS(GCOV, gcov)
 198 if test -z "$GCOV"; then
 199   AC_MSG_ERROR([gcov not found])
 200 fi
 201 AC_CHECK_PROGS(LCOV, lcov)
 202 if test -z "$LCOV"; then
 203   AC_MSG_ERROR([lcov not found])
 204 fi
 205 AC_CHECK_PROGS(GENHTML, genhtml)
 206 if test -z "$GENHTML"; then
 207   AC_MSG_ERROR([genhtml not found])
 208 fi])
 209 AC_SUBST(enable_coverage)
 210
 211 #
 212 # DTrace
 213 #
 214 PGAC_ARG_BOOL(enable, dtrace, no,
 215               [build with DTrace support],
 216 [AC_CHECK_PROGS(DTRACE, dtrace)
 217 if test -z "$DTRACE"; then
 218   AC_MSG_ERROR([dtrace not found])
 219 fi
 220 AC_SUBST(DTRACEFLAGS)])
 221 AC_SUBST(enable_dtrace)
 222
 223 #
 224 # Block size
 225 #
 226 AC_MSG_CHECKING([for block size])
 227 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 228              [blocksize=$withval],
 229              [blocksize=8])
 230 case ${blocksize} in
 231   1) BLCKSZ=1024;;
 232   2) BLCKSZ=2048;;
 233   4) BLCKSZ=4096;;
 234   8) BLCKSZ=8192;;
 235  16) BLCKSZ=16384;;
 236  32) BLCKSZ=32768;;
 237   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 238 esac
 239 AC_MSG_RESULT([${blocksize}kB])
 240
 241 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 242  Size of a disk block --- this also limits the size of a tuple.  You
 243  can set it bigger if you need bigger tuples (although TOAST should
 244  reduce the need to have large tuples, since fields can be spread
 245  across multiple tuples).
 246
 247  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 248  is currently 2^15 (32768).  This is determined by the 15-bit widths
 249  of the lp_off and lp_len fields in ItemIdData (see
 250  include/storage/itemid.h).
 251
 252  Changing BLCKSZ requires an initdb.
 253 ])
 254
 255 #
 256 # Relation segment size
 257 #
 258 AC_MSG_CHECKING([for segment size])
 259 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 260              [segsize=$withval],
 261              [segsize=1])
 262 # this expression is set up to avoid unnecessary integer overflow
 263 # blocksize is already guaranteed to be a factor of 1024
 264 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 265 test $? -eq 0 || exit 1
 266 AC_MSG_RESULT([${segsize}GB])
 267
 268 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 269  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 270  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 271  relations bigger than that are divided into multiple files.
 272
 273  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 274  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 275  have large file support enabled.  By default, we make the limit 1 GB
 276  to avoid any possible integer-overflow problems within the OS.
 277  A limit smaller than necessary only means we divide a large
 278  relation into more chunks than necessary, so it seems best to err
 279  in the direction of a small limit.
 280
 281  A power-of-2 value is recommended to save a few cycles in md.c,
 282  but is not absolutely required.
 283
 284  Changing RELSEG_SIZE requires an initdb.
 285 ])
 286
 287 #
 288 # WAL block size
 289 #
 290 AC_MSG_CHECKING([for WAL block size])
 291 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 292              [wal_blocksize=$withval],
 293              [wal_blocksize=8])
 294 case ${wal_blocksize} in
 295   1) XLOG_BLCKSZ=1024;;
 296   2) XLOG_BLCKSZ=2048;;
 297   4) XLOG_BLCKSZ=4096;;
 298   8) XLOG_BLCKSZ=8192;;
 299  16) XLOG_BLCKSZ=16384;;
 300  32) XLOG_BLCKSZ=32768;;
 301  64) XLOG_BLCKSZ=65536;;
 302   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 303 esac
 304 AC_MSG_RESULT([${wal_blocksize}kB])
 305
 306 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 307  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 308  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 309  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 310  buffers, else direct I/O may fail.
 311
 312  Changing XLOG_BLCKSZ requires an initdb.
 313 ])
 314
 315 #
 316 # WAL segment size
 317 #
 318 AC_MSG_CHECKING([for WAL segment size])
 319 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 320              [wal_segsize=$withval],
 321              [wal_segsize=16])
 322 case ${wal_segsize} in
 323   1) ;;
 324   2) ;;
 325   4) ;;
 326   8) ;;
 327  16) ;;
 328  32) ;;
 329  64) ;;
 330   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 331 esac
 332 AC_MSG_RESULT([${wal_segsize}MB])
 333
 334 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 335  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 336  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 337  XLOG_BLCKSZ).
 338
 339  Changing XLOG_SEG_SIZE requires an initdb.
 340 ])
 341
 342 #
 343 # C compiler
 344 #
 345
 346 # For historical reasons you can also use --with-CC to specify the C compiler
 347 # to use, although the standard way to do this is to set the CC environment
 348 # variable.
 349 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 350
 351 case $template in
 352   aix) pgac_cc_list="gcc xlc";;
 353  irix) pgac_cc_list="cc";; # no gcc
 354     *) pgac_cc_list="gcc cc";;
 355 esac
 356
 357 AC_PROG_CC([$pgac_cc_list])
 358
 359 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 360 # but has idiosyncrasies of its own.  We assume icc will define
 361 # __INTEL_COMPILER regardless of CFLAGS.
 362 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 363 choke me
 364 @%:@endif], [ICC=[yes]], [ICC=[no]])
 365
 366 # Check if it's Sun Studio compiler. We assume that
 367 # __SUNPRO_C will be defined for Sun Studio compilers
 368 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 369 choke me
 370 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 371
 372 AC_SUBST(SUN_STUDIO_CC)
 373
 374 unset CFLAGS
 375
 376 #
 377 # Read the template
 378 #
 379 . "$srcdir/src/template/$template" || exit
 380
 381 # CFLAGS are selected so:
 382 # If the user specifies something in the environment, that is used.
 383 # else:  If the template file set something, that is used.
 384 # else:  If coverage was enabled, don't set anything.
 385 # else:  If the compiler is GCC, then we use -O2.
 386 # else:  If the compiler is something else, then we use -O, unless debugging.
 387
 388 if test "$ac_env_CFLAGS_set" = set; then
 389   CFLAGS=$ac_env_CFLAGS_value
 390 elif test "${CFLAGS+set}" = set; then
 391   : # (keep what template set)
 392 elif test "$enable_coverage" = yes; then
 393   : # no optimization by default
 394 elif test "$GCC" = yes; then
 395   CFLAGS="-O2"
 396 else
 397   # if the user selected debug mode, don't use -O
 398   if test "$enable_debug" != yes; then
 399     CFLAGS="-O"
 400   fi
 401 fi
 402
 403 # Some versions of GCC support some additional useful warning flags.
 404 # Check whether they are supported, and add them to CFLAGS if so.
 405 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 406 # but has its own.  Also check other compiler-specific flags here.
 407
 408 if test "$GCC" = yes -a "$ICC" = no; then
 409   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 410   # These work in some but not all gcc versions
 411   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 412   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 413   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 414   # This was included in -Wall/-Wformat in older GCC versions
 415   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 416   # Disable strict-aliasing rules; needed for gcc 3.3+
 417   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 418   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 419   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 420   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 421   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 422 elif test "$ICC" = yes; then
 423   # Intel's compiler has a bug/misoptimization in checking for
 424   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 425   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 426   # Make sure strict aliasing is off (though this is said to be the default)
 427   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 428 elif test "$PORTNAME" = "aix"; then
 429   # AIX's xlc has to have strict aliasing turned off too
 430   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 431 elif test "$PORTNAME" = "hpux"; then
 432   # On some versions of HP-UX, libm functions do not set errno by default.
 433   # Fix that by using +Olibmerrno if the compiler recognizes it.
 434   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 435 fi
 436
 437 # supply -g if --enable-debug
 438 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 439   CFLAGS="$CFLAGS -g"
 440 fi
 441
 442 # enable code coverage if --enable-coverage
 443 if test "$enable_coverage" = yes; then
 444   if test "$GCC" = yes; then
 445     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 446   else
 447     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 448   fi
 449 fi
 450
 451 # enable profiling if --enable-profiling
 452 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 453   if test "$GCC" = yes; then
 454     AC_DEFINE([PROFILE_PID_DIR], 1,
 455            [Define to 1 to allow profiling output to be saved separately for each process.])
 456     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 457   else
 458     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 459   fi
 460 fi
 461
 462 # We already have this in Makefile.win32, but configure needs it too
 463 if test "$PORTNAME" = "win32"; then
 464   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 465 fi
 466
 467 # Check if the compiler still works with the template settings
 468 AC_MSG_CHECKING([whether the C compiler still works])
 469 AC_TRY_LINK([], [return 0;],
 470   [AC_MSG_RESULT(yes)],
 471   [AC_MSG_RESULT(no)
 472    AC_MSG_ERROR([cannot proceed])])
 473
 474 # Defend against gcc -ffast-math
 475 if test "$GCC" = yes; then
 476 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 477 choke me
 478 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 479 fi
 480
 481 AC_PROG_CPP
 482 AC_SUBST(GCC)
 483
 484
 485 #
 486 # Set up TAS assembly code if needed; the template file has now had its
 487 # chance to request this.
 488 #
 489 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 490
 491 if test "$need_tas" = yes ; then
 492   TAS=tas.o
 493 else
 494   TAS=""
 495 fi
 496 AC_SUBST(TAS)
 497
 498
 499 #
 500 # Automatic dependency tracking
 501 #
 502 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 503               [autodepend=yes])
 504 AC_SUBST(autodepend)
 505
 506
 507 #
 508 # Enable assert checks
 509 #
 510 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 511               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 512                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 513
 514
 515 #
 516 # Include directories
 517 #
 518 ac_save_IFS=$IFS
 519 IFS="${IFS}${PATH_SEPARATOR}"
 520 # SRCH_INC comes from the template file
 521 for dir in $with_includes $SRCH_INC; do
 522   if test -d "$dir"; then
 523     INCLUDES="$INCLUDES -I$dir"
 524   else
 525     AC_MSG_WARN([*** Include directory $dir does not exist.])
 526   fi
 527 done
 528 IFS=$ac_save_IFS
 529 AC_SUBST(INCLUDES)
 530
 531
 532 #
 533 # Library directories
 534 #
 535 ac_save_IFS=$IFS
 536 IFS="${IFS}${PATH_SEPARATOR}"
 537 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 538 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 539   if test -d "$dir"; then
 540     LIBDIRS="$LIBDIRS -L$dir"
 541   else
 542     AC_MSG_WARN([*** Library directory $dir does not exist.])
 543   fi
 544 done
 545 IFS=$ac_save_IFS
 546
 547 #
 548 # Enable thread-safe client libraries
 549 #
 550 AC_MSG_CHECKING([allow thread-safe client libraries])
 551 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 552 if test "$enable_thread_safety" = yes; then
 553   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 554           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 555 fi
 556 AC_MSG_RESULT([$enable_thread_safety])
 557 AC_SUBST(enable_thread_safety)
 558
 559 #
 560 # Optionally build Tcl modules (PL/Tcl)
 561 #
 562 AC_MSG_CHECKING([whether to build with Tcl])
 563 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 564 AC_MSG_RESULT([$with_tcl])
 565 AC_SUBST([with_tcl])
 566
 567 # We see if the path to the Tcl/Tk configuration scripts is specified.
 568 # This will override the use of tclsh to find the paths to search.
 569
 570 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 571
 572 #
 573 # Optionally build Perl modules (PL/Perl)
 574 #
 575 AC_MSG_CHECKING([whether to build Perl modules])
 576 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 577 AC_MSG_RESULT([$with_perl])
 578 AC_SUBST(with_perl)
 579
 580 #
 581 # Optionally build Python modules (PL/Python)
 582 #
 583 AC_MSG_CHECKING([whether to build Python modules])
 584 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 585 AC_MSG_RESULT([$with_python])
 586 AC_SUBST(with_python)
 587
 588 #
 589 # GSSAPI
 590 #
 591 AC_MSG_CHECKING([whether to build with GSSAPI support])
 592 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 593 [
 594   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 595   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 596 ])
 597 AC_MSG_RESULT([$with_gssapi])
 598
 599 #
 600 # Kerberos 5
 601 #
 602 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 603 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 604 [
 605   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 606   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 607 ])
 608 AC_MSG_RESULT([$with_krb5])
 609
 610
 611 AC_SUBST(krb_srvtab)
 612
 613
 614 #
 615 # Kerberos configuration parameters
 616 #
 617 PGAC_ARG_REQ(with, krb-srvnam,
 618              [NAME], [default service principal name in Kerberos [postgres]],
 619              [],
 620              [with_krb_srvnam="postgres"])
 621 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 622                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 623
 624
 625 #
 626 # PAM
 627 #
 628 AC_MSG_CHECKING([whether to build with PAM support])
 629 PGAC_ARG_BOOL(with, pam, no,
 630               [build with PAM support],
 631               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 632 AC_MSG_RESULT([$with_pam])
 633
 634
 635 #
 636 # LDAP
 637 #
 638 AC_MSG_CHECKING([whether to build with LDAP support])
 639 PGAC_ARG_BOOL(with, ldap, no,
 640               [build with LDAP support],
 641               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 642 AC_MSG_RESULT([$with_ldap])
 643
 644
 645 #
 646 # Bonjour
 647 #
 648 AC_MSG_CHECKING([whether to build with Bonjour support])
 649 PGAC_ARG_BOOL(with, bonjour, no,
 650               [build with Bonjour support],
 651               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 652 AC_MSG_RESULT([$with_bonjour])
 653
 654
 655 #
 656 # OpenSSL
 657 #
 658 AC_MSG_CHECKING([whether to build with OpenSSL support])
 659 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 660               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 661 AC_MSG_RESULT([$with_openssl])
 662 AC_SUBST(with_openssl)
 663
 664 #
 665 # SELinux
 666 #
 667 AC_MSG_CHECKING([whether to build with SELinux support])
 668 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 669 AC_SUBST(with_selinux)
 670 AC_MSG_RESULT([$with_selinux])
 671
 672 #
 673 # Readline
 674 #
 675 PGAC_ARG_BOOL(with, readline, yes,
 676               [do not use GNU Readline nor BSD Libedit for editing])
 677 # readline on MinGW has problems with backslashes in psql and other bugs.
 678 # This is particularly a problem with non-US code pages.
 679 # Therefore disable its use until we understand the cause. 2004-07-20
 680 if test "$PORTNAME" = "win32"; then
 681   if test "$with_readline" = yes; then
 682     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 683     with_readline=no
 684   fi
 685 fi
 686
 687
 688 #
 689 # Prefer libedit
 690 #
 691 PGAC_ARG_BOOL(with, libedit-preferred, no,
 692               [prefer BSD Libedit over GNU Readline])
 693
 694
 695 #
 696 # OSSP UUID library
 697 #
 698 PGAC_ARG_BOOL(with, ossp-uuid, no, [build contrib/uuid-ossp, requires OSSP UUID library])
 699 AC_SUBST(with_ossp_uuid)
 700
 701
 702 #
 703 # XML
 704 #
 705 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 706               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 707
 708 if test "$with_libxml" = yes ; then
 709   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 710   if test -n "$XML2_CONFIG"; then
 711     for pgac_option in `$XML2_CONFIG --cflags`; do
 712       case $pgac_option in
 713         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 714       esac
 715     done
 716     for pgac_option in `$XML2_CONFIG --libs`; do
 717       case $pgac_option in
 718         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 719       esac
 720     done
 721   fi
 722 fi
 723
 724 AC_SUBST(with_libxml)
 725
 726 #
 727 # XSLT
 728 #
 729 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 730               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 731
 732
 733 AC_SUBST(with_libxslt)
 734
 735 #
 736 # tzdata
 737 #
 738 PGAC_ARG_REQ(with, system-tzdata,
 739              [DIR], [use system time zone data in DIR])
 740 AC_SUBST(with_system_tzdata)
 741
 742 #
 743 # Zlib
 744 #
 745 PGAC_ARG_BOOL(with, zlib, yes,
 746               [do not use Zlib])
 747 AC_SUBST(with_zlib)
 748
 749 #
 750 # Elf
 751 #
 752
 753 # Assume system is ELF if it predefines __ELF__ as 1,
 754 # otherwise believe host_os based default.
 755 case $host_os in
 756     freebsd1*|freebsd2*) elf=no;;
 757     freebsd3*|freebsd4*) elf=yes;;
 758 esac
 759
 760 AC_EGREP_CPP(yes,
 761 [#if __ELF__
 762   yes
 763 #endif
 764 ],
 765 [ELF_SYS=true],
 766 [if test "X$elf" = "Xyes" ; then
 767   ELF_SYS=true
 768 else
 769   ELF_SYS=
 770 fi])
 771 AC_SUBST(ELF_SYS)
 772
 773 #
 774 # Assignments
 775 #
 776
 777 CPPFLAGS="$CPPFLAGS $INCLUDES"
 778 LDFLAGS="$LDFLAGS $LIBDIRS"
 779
 780 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 781 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 782
 783 PGAC_PROG_LD
 784 AC_SUBST(LD)
 785 AC_SUBST(with_gnu_ld)
 786 case $host_os in sysv5*)
 787   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 788   [
 789     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 790     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 791     LDFLAGS=$pgac_save_LDFLAGS
 792   ])
 793   ld_R_works=$pgac_cv_prog_ld_R
 794   AC_SUBST(ld_R_works)
 795 esac
 796 AC_PROG_RANLIB
 797 PGAC_CHECK_STRIP
 798 AC_CHECK_TOOL(AR, ar, ar)
 799 if test "$PORTNAME" = "win32"; then
 800   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 801   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 802   AC_CHECK_TOOL(WINDRES, windres, windres)
 803 fi
 804
 805 AC_PROG_INSTALL
 806 # When Autoconf chooses install-sh as install program it tries to generate
 807 # a relative path to it in each makefile where it subsitutes it. This clashes
 808 # with our Makefile.global concept. This workaround helps.
 809 case $INSTALL in
 810   *install-sh*) install_bin='';;
 811   *) install_bin=$INSTALL;;
 812 esac
 813 AC_SUBST(install_bin)
 814
 815 AC_PATH_PROG(TAR, tar)
 816 AC_PROG_LN_S
 817 AC_PROG_AWK
 818 AC_PROG_MKDIR_P
 819 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 820 # a relative path to it in each makefile where it subsitutes it. This clashes
 821 # with our Makefile.global concept. This workaround helps.
 822 case $MKDIR_P in
 823   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 824 esac
 825
 826 PGAC_PATH_BISON
 827 PGAC_PATH_FLEX
 828
 829 PGAC_PATH_PERL
 830 if test "$with_perl" = yes; then
 831   if test -z "$PERL"; then
 832     AC_MSG_ERROR([Perl not found])
 833   fi
 834   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 835   PGAC_CHECK_PERL_EMBED_LDFLAGS
 836 fi
 837
 838 if test "$with_python" = yes; then
 839   PGAC_PATH_PYTHON
 840   PGAC_CHECK_PYTHON_EMBED_SETUP
 841 fi
 842
 843 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 844   AC_PATH_PROG(ZIC, zic)
 845   if test -z "$ZIC"; then
 846     AC_MSG_ERROR([
 847 When cross-compiling, either use the option --with-system-tzdata to use
 848 existing time-zone data, or set the environment variable ZIC to a zic
 849 program to use during the build.])
 850   fi
 851 fi
 852
 853
 854 ##
 855 ## Libraries
 856 ##
 857 ## Most libraries are included only if they demonstrably provide a function
 858 ## we need, but libm is an exception: always include it, because there are
 859 ## too many compilers that play cute optimization games that will break
 860 ## probes for standard functions such as pow().
 861 ##
 862
 863 AC_CHECK_LIB(m, main)
 864 AC_SEARCH_LIBS(setproctitle, util)
 865 AC_SEARCH_LIBS(dlopen, dl)
 866 AC_SEARCH_LIBS(socket, [socket wsock32])
 867 AC_SEARCH_LIBS(shl_load, dld)
 868 # We only use libld in port/dynloader/aix.c
 869 case $host_os in
 870      aix*)
 871         AC_SEARCH_LIBS(ldopen, ld)
 872         ;;
 873 esac
 874 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 875 AC_SEARCH_LIBS(crypt, crypt)
 876 # Solaris:
 877 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 878 # Required for thread_test.c on Solaris 2.5:
 879 # Other ports use it too (HP-UX) so test unconditionally
 880 AC_SEARCH_LIBS(gethostbyname_r, nsl)
 881 # Cygwin:
 882 AC_SEARCH_LIBS(shmget, cygipc)
 883
 884 if test "$with_readline" = yes; then
 885   PGAC_CHECK_READLINE
 886   if test x"$pgac_cv_check_readline" = x"no"; then
 887     AC_MSG_ERROR([readline library not found
 888 If you have readline already installed, see config.log for details on the
 889 failure.  It is possible the compiler isn't looking in the proper directory.
 890 Use --without-readline to disable readline support.])
 891   fi
 892 fi
 893
 894 if test "$with_zlib" = yes; then
 895   AC_CHECK_LIB(z, inflate, [],
 896                [AC_MSG_ERROR([zlib library not found
 897 If you have zlib already installed, see config.log for details on the
 898 failure.  It is possible the compiler isn't looking in the proper directory.
 899 Use --without-zlib to disable zlib support.])])
 900 fi
 901
 902 if test "$enable_spinlocks" = yes; then
 903   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 904 else
 905   AC_MSG_WARN([
 906 *** Not using spinlocks will cause poor performance.])
 907 fi
 908
 909 if test "$with_gssapi" = yes ; then
 910   if test "$PORTNAME" != "win32"; then
 911     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 912                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 913   else
 914     LIBS="$LIBS -lgssapi32"
 915   fi
 916 fi
 917
 918 if test "$with_krb5" = yes ; then
 919   if test "$PORTNAME" != "win32"; then
 920      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err 'com_err -lssl -lcrypto'], [],
 921                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 922      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 923                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 924   else
 925      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 926                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 927   fi
 928 fi
 929
 930 if test "$with_openssl" = yes ; then
 931   dnl Order matters!
 932   if test "$PORTNAME" != "win32"; then
 933      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 934      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 935   else
 936      AC_SEARCH_LIBS(CRYPTO_new_ex_data, eay32 crypto, [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
 937      AC_SEARCH_LIBS(SSL_library_init, ssleay32 ssl, [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
 938   fi
 939 fi
 940
 941 if test "$with_pam" = yes ; then
 942   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 943 fi
 944
 945 if test "$with_libxml" = yes ; then
 946   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 947 fi
 948
 949 if test "$with_libxslt" = yes ; then
 950   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 951 fi
 952
 953 # for contrib/sepgsql
 954 if test "$with_selinux" = yes; then
 955   AC_CHECK_LIB(selinux, selinux_status_open, [],
 956                [AC_MSG_ERROR([library 'libselinux', version 2.0.99 or newer, is required for SELinux support])])
 957 fi
 958
 959 # for contrib/uuid-ossp
 960 if test "$with_ossp_uuid" = yes ; then
 961   AC_CHECK_LIB(ossp-uuid, uuid_export,
 962     [OSSP_UUID_LIBS="-lossp-uuid"],
 963     [AC_CHECK_LIB(uuid, uuid_export,
 964       [OSSP_UUID_LIBS="-luuid"],
 965       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 966 fi
 967 AC_SUBST(OSSP_UUID_LIBS)
 968
 969
 970 ##
 971 ## Header files
 972 ##
 973
 974 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 975 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h poll.h pwd.h sys/ioctl.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/socket.h sys/sockio.h sys/tas.h sys/time.h sys/ucred.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
 976
 977 # On BSD, cpp test for net/if.h will fail unless sys/socket.h
 978 # is included first.
 979 AC_CHECK_HEADERS(net/if.h, [], [],
 980 [AC_INCLUDES_DEFAULT
 981 #ifdef HAVE_SYS_SOCKET_H
 982 #include <sys/socket.h>
 983 #endif
 984 ])
 985
 986 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 987 # netinet/in.h is included first.
 988 AC_CHECK_HEADERS(netinet/in.h)
 989 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 990 [AC_INCLUDES_DEFAULT
 991 #ifdef HAVE_NETINET_IN_H
 992 #include <netinet/in.h>
 993 #endif
 994 ])
 995
 996 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 997   AC_CHECK_HEADERS(readline/readline.h, [],
 998         [AC_CHECK_HEADERS(readline.h, [],
 999                 [AC_MSG_ERROR([readline header not found
1000 If you have readline already installed, see config.log for details on the
1001 failure.  It is possible the compiler isn't looking in the proper directory.
1002 Use --without-readline to disable readline support.])])])
1003   AC_CHECK_HEADERS(readline/history.h, [],
1004         [AC_CHECK_HEADERS(history.h, [],
1005                 [AC_MSG_ERROR([history header not found
1006 If you have readline already installed, see config.log for details on the
1007 failure.  It is possible the compiler isn't looking in the proper directory.
1008 Use --without-readline to disable readline support.])])])
1009 fi
1010
1011 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1012 # Some installations of libedit usurp /usr/include/readline/, which seems
1013 # bad practice, since in combined installations readline will have its headers
1014 # there.  We might have to resort to AC_EGREP checks to make sure we found
1015 # the proper header...
1016   AC_CHECK_HEADERS(editline/readline.h, [],
1017         [AC_CHECK_HEADERS(readline.h, [],
1018                 [AC_CHECK_HEADERS(readline/readline.h, [],
1019                         [AC_MSG_ERROR([readline header not found
1020 If you have libedit already installed, see config.log for details on the
1021 failure.  It is possible the compiler isn't looking in the proper directory.
1022 Use --without-readline to disable libedit support.])])])])
1023 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1024 # not be there at all.  Hence, don't complain if not found.  We must check
1025 # though, since in yet other versions it is an independent header.
1026   AC_CHECK_HEADERS(editline/history.h, [],
1027         [AC_CHECK_HEADERS(history.h, [],
1028                 [AC_CHECK_HEADERS(readline/history.h)])])
1029 fi
1030
1031 if test "$with_zlib" = yes; then
1032   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1033 If you have zlib already installed, see config.log for details on the
1034 failure.  It is possible the compiler isn't looking in the proper directory.
1035 Use --without-zlib to disable zlib support.])])
1036 fi
1037
1038 if test "$with_gssapi" = yes ; then
1039   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1040         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1041 fi
1042
1043 if test "$with_krb5" = yes ; then
1044   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1045 fi
1046
1047 if test "$with_openssl" = yes ; then
1048   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1049   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1050 fi
1051
1052 if test "$with_pam" = yes ; then
1053   AC_CHECK_HEADERS(security/pam_appl.h, [],
1054                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1055                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1056 fi
1057
1058 if test "$with_libxml" = yes ; then
1059   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1060 fi
1061
1062 if test "$with_libxslt" = yes ; then
1063   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1064 fi
1065
1066 if test "$with_ldap" = yes ; then
1067   if test "$PORTNAME" != "win32"; then
1068      AC_CHECK_HEADERS(ldap.h, [],
1069                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1070   else
1071      AC_CHECK_HEADERS(winldap.h, [],
1072                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1073                       [AC_INCLUDES_DEFAULT
1074 #include <windows.h>
1075                       ])
1076   fi
1077 fi
1078
1079 if test "$with_bonjour" = yes ; then
1080   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1081 fi
1082
1083 # for contrib/uuid-ossp
1084 if test "$with_ossp_uuid" = yes ; then
1085   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1086     AC_CHECK_HEADERS(uuid.h, [],
1087       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1088 fi
1089
1090 if test "$PORTNAME" = "win32" ; then
1091    AC_CHECK_HEADERS(crtdefs.h)
1092 fi
1093
1094 ##
1095 ## Types, structures, compiler characteristics
1096 ##
1097
1098 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1099 AC_C_BIGENDIAN
1100 AC_C_CONST
1101 PGAC_C_INLINE
1102 AC_C_STRINGIZE
1103 AC_C_FLEXIBLE_ARRAY_MEMBER
1104 PGAC_C_SIGNED
1105 AC_C_VOLATILE
1106 PGAC_C_FUNCNAME_SUPPORT
1107 PGAC_C_STATIC_ASSERT
1108 PGAC_C_TYPES_COMPATIBLE
1109 PGAC_C_BUILTIN_CONSTANT_P
1110 PGAC_C_BUILTIN_UNREACHABLE
1111 PGAC_C_VA_ARGS
1112 PGAC_STRUCT_TIMEZONE
1113 PGAC_UNION_SEMUN
1114 PGAC_STRUCT_SOCKADDR_UN
1115 PGAC_STRUCT_SOCKADDR_STORAGE
1116 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1117 PGAC_STRUCT_ADDRINFO
1118 AC_TYPE_INTPTR_T
1119 AC_TYPE_UINTPTR_T
1120 AC_TYPE_LONG_LONG_INT
1121
1122 PGAC_TYPE_LOCALE_T
1123
1124 AC_CHECK_TYPES([struct cmsgcred], [], [],
1125 [#include <sys/socket.h>
1126 #ifdef HAVE_SYS_UCRED_H
1127 #include <sys/ucred.h>
1128 #endif])
1129
1130 AC_CHECK_TYPES([struct option], [], [],
1131 [#ifdef HAVE_GETOPT_H
1132 #include <getopt.h>
1133 #endif])
1134
1135 if test "$with_zlib" = yes; then
1136   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1137   # did not).  While we could work around the lack of z_streamp, it
1138   # seems unwise to encourage people to use such old zlib versions...
1139   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1140 Use --without-zlib to disable zlib support.])],
1141                 [#include <zlib.h>])
1142 fi
1143
1144 if test "$with_krb5" = yes; then
1145 # Check for differences between MIT and Heimdal (KTH) releases
1146   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1147                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1148                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1149                                      [#include <krb5.h>])],
1150                    [#include <krb5.h>])
1151   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1152                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1153                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1154                                      [#include <krb5.h>])],
1155                    [#include <krb5.h>])
1156
1157 # Win32 requires headers to be loaded for __stdcall, so can't use
1158 # AC_CHECK_FUNCS here.
1159   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1160   AC_TRY_LINK([#include <krb5.h>],
1161               [krb5_free_unparsed_name(NULL,NULL);],
1162               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name.])
1163 AC_MSG_RESULT(yes)],
1164               [AC_MSG_RESULT(no)])
1165 fi
1166
1167 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1168 case $host_cpu in
1169   ppc*|powerpc*)
1170     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1171     AC_TRY_COMPILE([],
1172         [int a = 0; int *p = &a; int r;
1173          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));],
1174         [pgac_cv_have_ppc_mutex_hint=yes],
1175         [pgac_cv_have_ppc_mutex_hint=no])
1176     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1177     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1178         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1179     fi
1180   ;;
1181 esac
1182
1183 # Check largefile support.  You might think this is a system service not a
1184 # compiler characteristic, but you'd be wrong.  We must check this before
1185 # probing existence of related functions such as fseeko, since the largefile
1186 # defines can affect what is generated for that.
1187 if test "$PORTNAME" != "win32"; then
1188    AC_SYS_LARGEFILE
1189 fi
1190
1191 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1192 AC_CHECK_SIZEOF([off_t])
1193
1194 # If we don't have largefile support, can't handle segsize >= 2GB.
1195 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1196    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1197 fi
1198
1199
1200 ##
1201 ## Functions, global variables
1202 ##
1203
1204 PGAC_VAR_INT_TIMEZONE
1205 AC_FUNC_ACCEPT_ARGTYPES
1206 PGAC_FUNC_GETTIMEOFDAY_1ARG
1207
1208 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1209 # symbols that that library has no business exposing to the world.  Pending
1210 # acquisition of a clue by those developers, ignore libedit (including its
1211 # possible alias of libreadline) while checking for everything else.
1212 LIBS_including_readline="$LIBS"
1213 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1214
1215 AC_CHECK_FUNCS([cbrt dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll pstat readlink setproctitle setsid sigprocmask symlink sync_file_range towlower utime utimes wcstombs wcstombs_l])
1216
1217 AC_REPLACE_FUNCS(fseeko)
1218 case $host_os in
1219         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1220         # Mingw uses macros to access Win32 API calls
1221         netbsd*|mingw*)
1222                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1223                 ac_cv_func_fseeko=yes;;
1224         *)
1225                 AC_FUNC_FSEEKO;;
1226 esac
1227
1228 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1229 # by calling it, 2009-04-02
1230 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1231 if test "$PORTNAME" != "solaris"; then
1232 AC_CHECK_FUNCS(posix_fadvise)
1233 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1234 fi
1235
1236 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1237 AC_CHECK_DECLS([strlcat, strlcpy])
1238 # This is probably only present on Darwin, but may as well check always
1239 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1240
1241 HAVE_IPV6=no
1242 AC_CHECK_TYPE([struct sockaddr_in6],
1243         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1244          HAVE_IPV6=yes],
1245         [],
1246 [$ac_includes_default
1247 #include <netinet/in.h>])
1248 AC_SUBST(HAVE_IPV6)
1249
1250 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1251 [AC_TRY_LINK(
1252 [#include <machine/vmparam.h>
1253 #include <sys/exec.h>
1254 ],
1255 [PS_STRINGS->ps_nargvstr = 1;
1256 PS_STRINGS->ps_argvstr = "foo";],
1257 [pgac_cv_var_PS_STRINGS=yes],
1258 [pgac_cv_var_PS_STRINGS=no])])
1259 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1260   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1261 fi
1262
1263
1264 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1265 # is missing.  Yes, there are machines that have only one.  We may
1266 # also decide to use snprintf.c if snprintf() is present but does not
1267 # have all the features we need --- see below.
1268
1269 if test "$PORTNAME" = "win32"; then
1270   # Win32 gets snprintf.c built unconditionally.
1271   #
1272   # To properly translate all NLS languages strings, we must support the
1273   # *printf() %$ format, which allows *printf() arguments to be selected
1274   # by position in the translated string.
1275   #
1276   # libintl versions < 0.13 use the native *printf() functions, and Win32
1277   # *printf() doesn't understand %$, so we must use our /port versions,
1278   # which do understand %$. libintl versions >= 0.13 include their own
1279   # *printf versions on Win32.  The libintl 0.13 release note text is:
1280   #
1281   #   C format strings with positions, as they arise when a translator
1282   #   needs to reorder a sentence, are now supported on all platforms.
1283   #   On those few platforms (NetBSD and Woe32) for which the native
1284   #   printf()/fprintf()/... functions don't support such format
1285   #   strings, replacements are provided through <libintl.h>.
1286   #
1287   # We could use libintl >= 0.13's *printf() if we were sure that we had
1288   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1289   # to guarantee that, it is best to just use our own, so we are sure to
1290   # get %$ support. In include/port.h we disable the *printf() macros
1291   # that might have been defined by libintl.
1292   #
1293   # We do this unconditionally whether NLS is used or not so we are sure
1294   # that all Win32 libraries and binaries behave the same.
1295   pgac_need_repl_snprintf=yes
1296 else
1297   pgac_need_repl_snprintf=no
1298   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1299   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1300 fi
1301
1302
1303 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1304 # include/c.h will provide declarations.  Note this is a separate test
1305 # from whether the functions exist in the C library --- there are
1306 # systems that have the functions but don't bother to declare them :-(
1307
1308 AC_CHECK_DECLS([snprintf, vsnprintf])
1309
1310
1311 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1312 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1313 [AC_TRY_LINK([
1314 #include <math.h>
1315 double glob_double;
1316 ],
1317 [return isinf(glob_double) ? 0 : 1;],
1318 [ac_cv_func_isinf=yes],
1319 [ac_cv_func_isinf=no])])
1320
1321 if test $ac_cv_func_isinf = yes ; then
1322   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1323 else
1324   AC_LIBOBJ(isinf)
1325   # Look for a way to implement a substitute for isinf()
1326   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1327 fi
1328
1329 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton random rint srandom strerror strlcat strlcpy])
1330
1331 case $host_os in
1332
1333         # Windows uses a specialised env handler
1334         # and doesn't need a replacement getpeereid because it doesn't use
1335         # Unix sockets.
1336         mingw*)
1337                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1338                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1339                 ac_cv_func_unsetenv=yes
1340                 ac_cv_func_getpeereid=yes;;
1341         *)
1342                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1343                 ;;
1344 esac
1345
1346 # System's version of getaddrinfo(), if any, may be used only if we found
1347 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1348 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1349 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1350 # because we want to use our own getaddrinfo.c on Windows anyway.)
1351 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1352   AC_REPLACE_FUNCS([getaddrinfo])
1353 else
1354   AC_LIBOBJ(getaddrinfo)
1355 fi
1356
1357 # Similarly, use system's getopt_long() only if system provides struct option.
1358 if test x"$ac_cv_type_struct_option" = xyes ; then
1359   AC_REPLACE_FUNCS([getopt_long])
1360 else
1361   AC_LIBOBJ(getopt_long)
1362 fi
1363
1364 # Solaris' getopt() doesn't do what we want for long options, so always use
1365 # our version on that platform.
1366 if test "$PORTNAME" = "solaris"; then
1367   AC_LIBOBJ(getopt)
1368 fi
1369
1370 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1371 # so always use our version on Windows.
1372 if test "$PORTNAME" = "win32"; then
1373   AC_LIBOBJ(getopt)
1374   AC_LIBOBJ(getopt_long)
1375 fi
1376
1377 # Win32 support
1378 if test "$PORTNAME" = "win32"; then
1379   AC_REPLACE_FUNCS(gettimeofday)
1380   AC_LIBOBJ(kill)
1381   AC_LIBOBJ(open)
1382   AC_LIBOBJ(win32env)
1383   AC_LIBOBJ(win32error)
1384   AC_LIBOBJ(win32setlocale)
1385   AC_DEFINE([HAVE_SYMLINK], 1,
1386             [Define to 1 if you have the `symlink' function.])
1387   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1388 #define WIN32_LEAN_AND_MEAN
1389 #include <windows.h>
1390 #include <string.h>
1391 #include <dbghelp.h>])
1392 fi
1393 if test x"$pgac_minidump_type" = x"yes" ; then
1394   AC_SUBST(have_win32_dbghelp,yes)
1395 else
1396   AC_SUBST(have_win32_dbghelp,no)
1397 fi
1398
1399 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1400 dnl (especially on GNU libc)
1401 dnl See also comments in c.h.
1402 AC_CACHE_CHECK([for sigsetjmp], pgac_cv_func_sigsetjmp,
1403 [AC_TRY_LINK([#include <setjmp.h>],
1404             [sigjmp_buf x; sigsetjmp(x, 1);],
1405             [pgac_cv_func_sigsetjmp=yes],
1406             [pgac_cv_func_sigsetjmp=no])])
1407 if test x"$pgac_cv_func_sigsetjmp" = x"yes"; then
1408   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1409 fi
1410
1411 AC_DECL_SYS_SIGLIST
1412
1413 AC_CHECK_FUNC(syslog,
1414               [AC_CHECK_HEADER(syslog.h,
1415                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1416
1417 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1418 [AC_TRY_LINK([#include <unistd.h>],
1419   [extern int opterr; opterr = 1;],
1420   [pgac_cv_var_int_opterr=yes],
1421   [pgac_cv_var_int_opterr=no])])
1422 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1423   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1424 fi
1425
1426 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1427 [AC_TRY_LINK([#include <unistd.h>],
1428   [extern int optreset; optreset = 1;],
1429   [pgac_cv_var_int_optreset=yes],
1430   [pgac_cv_var_int_optreset=no])])
1431 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1432   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1433 fi
1434
1435 AC_CHECK_FUNCS([strtoll strtoq], [break])
1436 AC_CHECK_FUNCS([strtoull strtouq], [break])
1437
1438 AC_CACHE_CHECK([for builtin locking functions], pgac_cv_gcc_int_atomics,
1439 [AC_TRY_LINK([],
1440   [int lock = 0;
1441    __sync_lock_test_and_set(&lock, 1);
1442    __sync_lock_release(&lock);],
1443   [pgac_cv_gcc_int_atomics="yes"],
1444   [pgac_cv_gcc_int_atomics="no"])])
1445 if test x"$pgac_cv_gcc_int_atomics" = x"yes"; then
1446   AC_DEFINE(HAVE_GCC_INT_ATOMICS, 1, [Define to 1 if you have __sync_lock_test_and_set(int *) and friends.])
1447 fi
1448
1449 # Lastly, restore full LIBS list and check for readline/libedit symbols
1450 LIBS="$LIBS_including_readline"
1451
1452 if test "$with_readline" = yes; then
1453   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1454   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1455   AC_CHECK_FUNCS([append_history history_truncate_file])
1456 fi
1457
1458
1459 #
1460 # Pthreads
1461 #
1462 # For each platform, we need to know about any special compile and link
1463 # libraries, and whether the normal C function names are thread-safe.
1464 # See the comment at the top of src/port/thread.c for more information.
1465 # WIN32 doesn't need the pthread tests;  it always uses threads
1466 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1467 ACX_PTHREAD     # set thread flags
1468
1469 # Some platforms use these, so just define them.  They can't hurt if they
1470 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1471 # enables 5-arg getpwuid_r, among other things.
1472 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1473
1474
1475 # At this point, we don't want to muck with the compiler name for threading.
1476 # Let's see who fails, perhaps AIX.  2004-04-23
1477 if test "$PTHREAD_CC" != "$CC"; then
1478 AC_MSG_ERROR([
1479 PostgreSQL does not support platforms that require a special compiler
1480 for thread safety;  use --disable-thread-safety to disable thread safety.])
1481 fi
1482
1483 # Check for *_r functions
1484 _CFLAGS="$CFLAGS"
1485 _LIBS="$LIBS"
1486 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1487 LIBS="$LIBS $PTHREAD_LIBS"
1488
1489 if test "$PORTNAME" != "win32"; then
1490 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1491 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1492 fi
1493
1494 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1495
1496 # Do test here with the proper thread flags
1497 PGAC_FUNC_GETPWUID_R_5ARG
1498 PGAC_FUNC_STRERROR_R_INT
1499
1500 CFLAGS="$_CFLAGS"
1501 LIBS="$_LIBS"
1502
1503 else
1504 # do not use values from template file
1505 PTHREAD_CFLAGS=
1506 PTHREAD_LIBS=
1507 fi
1508
1509 AC_SUBST(PTHREAD_CFLAGS)
1510 AC_SUBST(PTHREAD_LIBS)
1511
1512
1513 # We can test for libldap_r only after we know PTHREAD_LIBS
1514 if test "$with_ldap" = yes ; then
1515   _LIBS="$LIBS"
1516   if test "$PORTNAME" != "win32"; then
1517     AC_CHECK_LIB(ldap, ldap_bind, [],
1518                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1519                  [$EXTRA_LDAP_LIBS])
1520     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1521     if test "$enable_thread_safety" = yes; then
1522       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1523       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1524                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1525                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1526       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1527     else
1528       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1529     fi
1530   else
1531     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1532     LDAP_LIBS_FE="-lwldap32"
1533     LDAP_LIBS_BE="-lwldap32"
1534   fi
1535   LIBS="$_LIBS"
1536 fi
1537 AC_SUBST(LDAP_LIBS_FE)
1538 AC_SUBST(LDAP_LIBS_BE)
1539
1540
1541 # This test makes sure that run tests work at all.  Sometimes a shared
1542 # library is found by the linker, but the runtime linker can't find it.
1543 # This check should come after all modifications of compiler or linker
1544 # variables, and before any other run tests.
1545 AC_MSG_CHECKING([test program])
1546 AC_TRY_RUN([int main() { return 0; }],
1547 [AC_MSG_RESULT(ok)],
1548 [AC_MSG_RESULT(failed)
1549 AC_MSG_ERROR([[
1550 Could not execute a simple test program.  This may be a problem
1551 related to locating shared libraries.  Check the file 'config.log'
1552 for the exact reason.]])],
1553 [AC_MSG_RESULT([cross-compiling])])
1554
1555 # --------------------
1556 # Run tests below here
1557 # --------------------
1558
1559 # Force use of our snprintf if system's doesn't do arg control
1560 # See comment above at snprintf test for details.
1561 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1562   PGAC_FUNC_PRINTF_ARG_CONTROL
1563   if test $pgac_cv_printf_arg_control != yes ; then
1564     pgac_need_repl_snprintf=yes
1565   fi
1566 fi
1567
1568
1569 dnl Check to see if we have a working 64-bit integer type.
1570 dnl This breaks down into two steps:
1571 dnl (1) figure out if the compiler has a 64-bit int type with working
1572 dnl arithmetic, and if so
1573 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1574 dnl snprintf is the only library routine we really need for int8 support.)
1575 dnl It's entirely possible to have a compiler that handles a 64-bit type
1576 dnl when the C library doesn't; this is fairly likely when using gcc on
1577 dnl an older platform, for example.
1578 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1579 dnl we force our own version of snprintf() to be used instead.
1580 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1581
1582 dnl As of Postgres 8.4, we no longer support compilers without a working
1583 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1584
1585 PGAC_TYPE_64BIT_INT([long int])
1586
1587 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1588   pg_int64_type="long int"
1589 else
1590   PGAC_TYPE_64BIT_INT([long long int])
1591   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1592     pg_int64_type="long long int"
1593   else
1594     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1595   fi
1596 fi
1597
1598 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1599   [Define to the name of a signed 64-bit integer type.])
1600
1601 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1602
1603 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1604   AC_TRY_COMPILE([
1605 #define INT64CONST(x)  x##LL
1606 long long int foo = INT64CONST(0x1234567890123456);
1607 ],
1608         [],
1609         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1610         [])
1611 fi
1612
1613
1614 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1615 # we found we need to use "long long int", better check.  We cope with
1616 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1617 # work, fall back to our own snprintf emulation (which we know uses %lld).
1618
1619 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1620   if test $pgac_need_repl_snprintf = no; then
1621     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1622     if test "$LONG_LONG_INT_FORMAT" = ""; then
1623       # Force usage of our own snprintf, since system snprintf is broken
1624       pgac_need_repl_snprintf=yes
1625       LONG_LONG_INT_FORMAT='%lld'
1626     fi
1627   else
1628     # Here if we previously decided we needed to use our own snprintf
1629     LONG_LONG_INT_FORMAT='%lld'
1630   fi
1631   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1632   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1633   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1634 else
1635   # Here if we are not using 'long long int' at all
1636   INT64_FORMAT='"%ld"'
1637   UINT64_FORMAT='"%lu"'
1638 fi
1639
1640 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1641                    [Define to the appropriate snprintf format for 64-bit ints.])
1642
1643 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1644                    [Define to the appropriate snprintf format for unsigned 64-bit ints.])
1645
1646 # Now we have checked all the reasons to replace snprintf
1647 if test $pgac_need_repl_snprintf = yes; then
1648   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1649   AC_LIBOBJ(snprintf)
1650 fi
1651
1652 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1653 AC_CHECK_SIZEOF([void *])
1654 AC_CHECK_SIZEOF([size_t])
1655 AC_CHECK_SIZEOF([long])
1656
1657 # Decide whether float4 is passed by value: user-selectable, enabled by default
1658 AC_MSG_CHECKING([whether to build with float4 passed by value])
1659 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1660               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1661                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1662                float4passbyval=true],
1663               [float4passbyval=false])
1664 AC_MSG_RESULT([$enable_float4_byval])
1665 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1666
1667 # Decide whether float8 is passed by value.
1668 # Note: this setting also controls int8 and related types such as timestamp.
1669 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1670 # If not, trying to select it is an error.
1671 AC_MSG_CHECKING([whether to build with float8 passed by value])
1672 if test $ac_cv_sizeof_void_p -ge 8 ; then
1673   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1674 else
1675   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1676   if test "$enable_float8_byval" = yes ; then
1677     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1678   fi
1679 fi
1680 if test "$enable_float8_byval" = yes ; then
1681   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1682             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1683   float8passbyval=true
1684 else
1685   float8passbyval=false
1686 fi
1687 AC_MSG_RESULT([$enable_float8_byval])
1688 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1689
1690 # Determine memory alignment requirements for the basic C data types.
1691
1692 AC_CHECK_ALIGNOF(short)
1693 AC_CHECK_ALIGNOF(int)
1694 AC_CHECK_ALIGNOF(long)
1695 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1696   AC_CHECK_ALIGNOF(long long int)
1697 fi
1698 AC_CHECK_ALIGNOF(double)
1699
1700 # Compute maximum alignment of any basic type.
1701 # We assume long's alignment is at least as strong as char, short, or int;
1702 # but we must check long long (if it exists) and double.
1703
1704 MAX_ALIGNOF=$ac_cv_alignof_long
1705 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1706   MAX_ALIGNOF=$ac_cv_alignof_double
1707 fi
1708 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1709   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1710 fi
1711 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1712
1713
1714 # Some platforms predefine the types int8, int16, etc.  Only check
1715 # a (hopefully) representative subset.
1716 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1717 [#include <stdio.h>])
1718
1719 # We also check for sig_atomic_t, which *should* be defined per ANSI
1720 # C, but is missing on some old platforms.
1721 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1722
1723
1724 if test "$PORTNAME" != "win32"
1725 then
1726 PGAC_FUNC_POSIX_SIGNALS
1727 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1728   AC_MSG_ERROR([
1729 Thread-safety requires POSIX signals, which are not supported by this
1730 operating system;  use --disable-thread-safety to disable thread safety.])
1731 fi
1732 fi
1733
1734 # SunOS doesn't handle negative byte comparisons properly with +/- return
1735 AC_FUNC_MEMCMP
1736
1737
1738 # Select semaphore implementation type.
1739 if test "$PORTNAME" != "win32"; then
1740   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1741     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1742     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1743   else
1744     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1745       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1746       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1747     else
1748       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1749       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1750     fi
1751   fi
1752 else
1753   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1754   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1755 fi
1756
1757
1758 # Select shared-memory implementation type.
1759 if test "$PORTNAME" != "win32"; then
1760   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1761   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1762 else
1763   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1764   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1765 fi
1766
1767 # Select latch implementation type.
1768 if test "$PORTNAME" != "win32"; then
1769   LATCH_IMPLEMENTATION="src/backend/port/unix_latch.c"
1770 else
1771   LATCH_IMPLEMENTATION="src/backend/port/win32_latch.c"
1772 fi
1773
1774 # If not set in template file, set bytes to use libc memset()
1775 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1776   MEMSET_LOOP_LIMIT=1024
1777 fi
1778 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1779
1780
1781 if test "$enable_nls" = yes ; then
1782   PGAC_CHECK_GETTEXT
1783 fi
1784
1785 # Check for Tcl configuration script tclConfig.sh
1786 if test "$with_tcl" = yes; then
1787     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1788     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1789                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1790     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1791     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1792     ac_save_CPPFLAGS=$CPPFLAGS
1793     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1794     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1795     CPPFLAGS=$ac_save_CPPFLAGS
1796 fi
1797
1798 # check for <perl.h>
1799 if test "$with_perl" = yes; then
1800   ac_save_CPPFLAGS=$CPPFLAGS
1801   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
1802   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
1803                   [#include <EXTERN.h>])
1804   # While we're at it, check that we can link to libperl.
1805   # On most platforms, if perl.h is there then libperl.so will be too, but at
1806   # this writing Debian packages them separately.  There is no known reason to
1807   # waste cycles on separate probes for the Tcl or Python libraries, though.
1808   pgac_save_LIBS=$LIBS
1809   LIBS="$perl_embed_ldflags"
1810   AC_MSG_CHECKING([for libperl])
1811   AC_TRY_LINK([
1812 #include <EXTERN.h>
1813 #include <perl.h>
1814 ],  [perl_alloc();],
1815     [AC_MSG_RESULT(yes)],
1816     [AC_MSG_RESULT(no)
1817      AC_MSG_ERROR([libperl library is required for Perl])])
1818   LIBS=$pgac_save_LIBS
1819   CPPFLAGS=$ac_save_CPPFLAGS
1820 fi
1821
1822 # check for <Python.h>
1823 if test "$with_python" = yes; then
1824   ac_save_CPPFLAGS=$CPPFLAGS
1825   CPPFLAGS="$python_includespec $CPPFLAGS"
1826   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
1827   CPPFLAGS=$ac_save_CPPFLAGS
1828 fi
1829
1830 #
1831 # Check for DocBook and tools
1832 #
1833 PGAC_PROG_NSGMLS
1834 PGAC_PROG_JADE
1835 PGAC_CHECK_DOCBOOK(4.2)
1836 PGAC_PATH_DOCBOOK_STYLESHEETS
1837 PGAC_PATH_COLLATEINDEX
1838 AC_CHECK_PROGS(XSLTPROC, xsltproc)
1839 AC_CHECK_PROGS(OSX, [osx sgml2xml sx])
1840
1841 # Thread testing
1842
1843 # We have to run the thread test near the end so we have all our symbols
1844 # defined.  Cross compiling throws a warning.
1845 #
1846 if test "$enable_thread_safety" = yes; then
1847 if test "$PORTNAME" != "win32"
1848 then
1849 AC_MSG_CHECKING([thread safety of required library functions])
1850
1851 _CFLAGS="$CFLAGS"
1852 _LIBS="$LIBS"
1853 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1854 LIBS="$LIBS $PTHREAD_LIBS"
1855 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1856   [AC_MSG_RESULT(yes)],
1857   [AC_MSG_RESULT(no)
1858   AC_MSG_ERROR([thread test program failed
1859 This platform is not thread-safe.  Check the file 'config.log' or compile
1860 and run src/test/thread/thread_test for the exact reason.
1861 Use --disable-thread-safety to disable thread safety.])],
1862   [AC_MSG_RESULT(maybe)
1863   AC_MSG_WARN([
1864 *** Skipping thread test program because of cross-compile build.
1865 *** Run the program in src/test/thread on the target machine.
1866 ])])
1867 CFLAGS="$_CFLAGS"
1868 LIBS="$_LIBS"
1869 else
1870 AC_MSG_WARN([*** skipping thread test on Win32])
1871 fi
1872 fi
1873
1874 # If compiler will take -Wl,--as-needed (or various platform-specific
1875 # spellings thereof) then add that to LDFLAGS.  This is much easier than
1876 # trying to filter LIBS to the minimum for each executable.
1877 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1878 # libreadline; therefore we postpone testing it until we know what library
1879 # dependencies readline has.  The test code will try to link with $LIBS.
1880 if test "$with_readline" = yes; then
1881   link_test_func=readline
1882 else
1883   link_test_func=exit
1884 fi
1885
1886 if test "$PORTNAME" = "darwin"; then
1887   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1888 elif test "$PORTNAME" = "openbsd"; then
1889   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
1890 else
1891   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1892 fi
1893
1894 # Create compiler version string
1895 if test x"$GCC" = x"yes" ; then
1896   cc_string=`${CC} --version | sed q`
1897   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
1898 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
1899   cc_string=`${CC} -V 2>&1 | sed q`
1900 else
1901   cc_string=$CC
1902 fi
1903
1904 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
1905                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
1906                    [A string containing the version number, platform, and C compiler])
1907
1908 # Supply a numeric version string for use by 3rd party add-ons
1909 # awk -F is a regex on some platforms, and not on others, so make "." a tab
1910 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
1911 tr '.' '        ' |
1912 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
1913 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
1914
1915
1916 # Begin output steps
1917
1918 AC_MSG_NOTICE([using compiler=$cc_string])
1919 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1920 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1921 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1922
1923 # prepare build tree if outside source tree
1924 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1925 # Note 2: /bin/pwd might be better than shell's built-in at getting
1926 #         a symlink-free name.
1927 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1928   vpath_build=no
1929 else
1930   vpath_build=yes
1931   if test "$no_create" != yes; then
1932     _AS_ECHO_N([preparing build tree... ])
1933     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1934     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1935       || AC_MSG_ERROR(failed)
1936     AC_MSG_RESULT(done)
1937   fi
1938 fi
1939 AC_SUBST(vpath_build)
1940
1941
1942 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1943
1944 AC_CONFIG_LINKS([
1945   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1946   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1947   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1948   src/backend/port/pg_latch.c:${LATCH_IMPLEMENTATION}
1949   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1950   src/include/pg_config_os.h:src/include/port/${template}.h
1951   src/Makefile.port:src/makefiles/Makefile.${template}
1952 ])
1953
1954 if test "$PORTNAME" = "win32"; then
1955 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1956 # Links sometimes fail undetected on Mingw -
1957 # so here we detect it and warn the user
1958 for FILE in $CONFIG_LINKS
1959  do
1960         # test -e works for symlinks in the MinGW console
1961         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1962  done
1963 ])
1964 fi
1965
1966 AC_CONFIG_HEADERS([src/include/pg_config.h],
1967 [
1968 # Update timestamp for pg_config.h (see Makefile.global)
1969 echo >src/include/stamp-h
1970 ])
1971
1972 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
1973 [
1974 # Update timestamp for pg_config_ext.h (see Makefile.global)
1975 echo >src/include/stamp-ext-h
1976 ])
1977
1978 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
1979                   [echo >src/interfaces/ecpg/include/stamp-h])
1980
1981 AC_OUTPUT