contrib/ltree/meson.build

   1 # Copyright (c) 2022-2024, PostgreSQL Global Development Group
   2
   3 ltree_sources = files(
   4   '_ltree_gist.c',
   5   '_ltree_op.c',
   6   'crc32.c',
   7   'lquery_op.c',
   8   'ltree_gist.c',
   9   'ltree_io.c',
  10   'ltree_op.c',
  11   'ltxtquery_io.c',
  12   'ltxtquery_op.c',
  13 )
  14
  15 # .. so that includes of ltree/ltree.h work
  16 ltree_inc = include_directories('.', '../')
  17
  18 if host_system == 'windows'
  19   ltree_sources += rc_lib_gen.process(win32ver_rc, extra_args: [
  20     '--NAME', 'ltree',
  21     '--FILEDESC', 'ltree - hierarchical label data type',])
  22 endif
  23
  24 ltree = shared_module('ltree',
  25   ltree_sources,
  26   kwargs: contrib_mod_args,
  27 )
  28 contrib_targets += ltree
  29
  30 install_data(
  31   'ltree.control',
  32   'ltree--1.0--1.1.sql',
  33   'ltree--1.1.sql',
  34   'ltree--1.1--1.2.sql',
  35   'ltree--1.2--1.3.sql',
  36   kwargs: contrib_data_args,
  37 )
  38
  39 install_headers(
  40   'ltree.h',
  41   install_dir: dir_include_extension / 'ltree',
  42 )
  43
  44 tests += {
  45   'name': 'ltree',
  46   'sd': meson.current_source_dir(),
  47   'bd': meson.current_build_dir(),
  48   'regress': {
  49     'sql': [
  50       'ltree',
  51     ],
  52   },
  53 }