contrib/cube/meson.build

   1 # Copyright (c) 2022-2024, PostgreSQL Global Development Group
   2
   3 cube_sources = files(
   4   'cube.c',
   5 )
   6
   7 cube_scan = custom_target('cubescan',
   8   input: 'cubescan.l',
   9   output: 'cubescan.c',
  10   command: flex_cmd,
  11 )
  12 generated_sources += cube_scan
  13 cube_sources += cube_scan
  14
  15 cube_parse = custom_target('cubeparse',
  16   input: 'cubeparse.y',
  17   kwargs: bison_kw,
  18 )
  19 generated_sources += cube_parse.to_list()
  20 cube_sources += cube_parse
  21
  22 if host_system == 'windows'
  23   cube_sources += rc_lib_gen.process(win32ver_rc, extra_args: [
  24     '--NAME', 'cube',
  25     '--FILEDESC', 'cube - multidimensional cube data type',])
  26 endif
  27
  28 cube = shared_module('cube',
  29   cube_sources,
  30   include_directories: include_directories('.'),
  31   kwargs: contrib_mod_args,
  32 )
  33 contrib_targets += cube
  34
  35 install_data(
  36   'cube.control',
  37   'cube--1.0--1.1.sql',
  38   'cube--1.1--1.2.sql',
  39   'cube--1.2.sql',
  40   'cube--1.2--1.3.sql',
  41   'cube--1.3--1.4.sql',
  42   'cube--1.4--1.5.sql',
  43   kwargs: contrib_data_args,
  44 )
  45
  46 install_headers(
  47   'cubedata.h',
  48   install_dir: dir_include_extension / 'cube',
  49 )
  50
  51 tests += {
  52   'name': 'cube',
  53   'sd': meson.current_source_dir(),
  54   'bd': meson.current_build_dir(),
  55   'regress': {
  56     'sql': [
  57       'cube',
  58       'cube_sci',
  59     ],
  60   },
  61 }