src/fe_utils/meson.build

   1 # Copyright (c) 2022-2023, PostgreSQL Global Development Group
   2
   3 fe_utils_sources = files(
   4   'archive.c',
   5   'cancel.c',
   6   'conditional.c',
   7   'connect_utils.c',
   8   'mbprint.c',
   9   'option_utils.c',
  10   'parallel_slot.c',
  11   'print.c',
  12   'query_utils.c',
  13   'recovery_gen.c',
  14   'simple_list.c',
  15   'string_utils.c',
  16 )
  17
  18 psqlscan = custom_target('psqlscan',
  19   input: 'psqlscan.l',
  20   output: 'psqlscan.c',
  21   command: [flex_cmd, '--no-backup', '--fix-warnings', '--', '-Cfe', '-p', '-p'],
  22 )
  23 generated_sources += psqlscan
  24 fe_utils_sources += psqlscan
  25
  26 fe_utils = static_library('libpgfeutils',
  27   fe_utils_sources + generated_headers,
  28   c_pch: pch_postgres_fe_h,
  29   include_directories: [postgres_inc, libpq_inc],
  30   c_args: host_system == 'windows' ? ['-DFD_SETSIZE=1024'] : [],
  31   dependencies: frontend_common_code,
  32   kwargs: default_lib_args,
  33 )