configure.ac

   1 AC_INIT([pet], [0.05], [isl-development@googlegroups.com])
   2 AC_CONFIG_AUX_DIR([build-aux])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6 AC_SUBST(versioninfo)
   7 versioninfo=5:0:0
   8
   9 AC_PROG_CC
  10 AC_PROG_CXX
  11 AC_PROG_GREP
  12 AC_PROG_LIBTOOL
  13
  14 AC_SUBST(CLANG_CXXFLAGS)
  15 AC_SUBST(CLANG_LDFLAGS)
  16 AC_SUBST(CLANG_LIBS)
  17 AX_SUBMODULE(clang,system,system)
  18 llvm_config="llvm-config"
  19 AC_CHECK_PROG([llvm_config_found], ["$llvm_config"], [yes])
  20 if test "x$with_clang_prefix" != "x"; then
  21         llvm_config="$with_clang_prefix/bin/llvm-config"
  22         if test -x "$llvm_config"; then
  23                 llvm_config_found=yes
  24         fi
  25 fi
  26 if test "$llvm_config_found" != yes; then
  27         AC_MSG_ERROR([llvm-config not found])
  28 fi
  29 CLANG_CXXFLAGS=`$llvm_config --cxxflags`
  30 CLANG_LDFLAGS=`$llvm_config --ldflags`
  31 targets=`$llvm_config --targets-built`
  32 components="$targets asmparser bitreader support mc"
  33 $llvm_config --components | $GREP option > /dev/null 2> /dev/null
  34 if test $? -eq 0; then
  35         components="$components option"
  36 fi
  37 CLANG_LIBS=`$llvm_config --libs $components`
  38 systemlibs=`$llvm_config --system-libs 2> /dev/null | tail -1`
  39 if test $? -eq 0; then
  40         CLANG_LIBS="$CLANG_LIBS $systemlibs"
  41 fi
  42 CLANG_PREFIX=`$llvm_config --prefix`
  43 AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"], [Clang installation prefix])
  44
  45 SAVE_CPPFLAGS="$CPPFLAGS"
  46 CPPFLAGS="$CLANG_CXXFLAGS $CPPFLAGS"
  47 AC_LANG_PUSH(C++)
  48 AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
  49         [AC_ERROR([clang header file not found])])
  50 AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
  51         [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
  52         [Define to getHostTriple for older versions of clang])])
  53 AC_EGREP_HEADER([getExpansionLineNumber], [clang/Basic/SourceLocation.h], [],
  54         [AC_DEFINE([getExpansionLineNumber], [getInstantiationLineNumber],
  55         [Define to getInstantiationLineNumber for older versions of clang])])
  56 AC_EGREP_HEADER([getExpansionColumnNumber], [clang/Basic/SourceLocation.h], [],
  57         [AC_DEFINE([getExpansionColumnNumber], [getInstantiationColumnNumber],
  58         [Define to getInstantiationColumnNumber for older versions of clang])])
  59 AC_EGREP_HEADER([getExpansionLoc], [clang/Basic/SourceManager.h], [],
  60         [AC_DEFINE([getExpansionLoc], [getInstantiationLoc],
  61         [Define to getInstantiationLoc for older versions of clang])])
  62 AC_EGREP_HEADER([DiagnosticConsumer], [clang/Basic/Diagnostic.h], [],
  63         [AC_DEFINE([DiagnosticConsumer], [DiagnosticClient],
  64         [Define to DiagnosticClient for older versions of clang])])
  65 AC_EGREP_HEADER([DiagnosticsEngine], [clang/Basic/Diagnostic.h],
  66         [AC_DEFINE([DiagnosticInfo], [Diagnostic],
  67         [Define to Diagnostic for newer versions of clang])],
  68         [AC_DEFINE([DiagnosticsEngine], [Diagnostic],
  69         [Define to Diagnostic for older versions of clang])])
  70 AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
  71         [AC_DEFINE([USE_ARRAYREF], [],
  72                 [Define if Driver::BuildCompilation takes ArrayRef])])
  73 AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
  74         [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
  75                 [Define if Driver constructor takes CXXIsProduction argument])])
  76 AC_EGREP_HEADER([ IsProduction], [clang/Driver/Driver.h],
  77         [AC_DEFINE([HAVE_ISPRODUCTION], [],
  78                 [Define if Driver constructor takes IsProduction argument])])
  79 AC_TRY_COMPILE([#include <clang/Driver/Driver.h>], [
  80         using namespace clang;
  81         DiagnosticsEngine *Diags;
  82         new driver::Driver("", "", "", *Diags);
  83 ], [AC_DEFINE([DRIVER_CTOR_TAKES_DEFAULTIMAGENAME], [],
  84               [Define if Driver constructor takes default image name])])
  85 AC_EGREP_HEADER([void HandleTopLevelDecl\(], [clang/AST/ASTConsumer.h],
  86         [AC_DEFINE([HandleTopLevelDeclReturn], [void],
  87                    [Return type of HandleTopLevelDeclReturn])
  88          AC_DEFINE([HandleTopLevelDeclContinue], [],
  89                    [Return type of HandleTopLevelDeclReturn])],
  90         [AC_DEFINE([HandleTopLevelDeclReturn], [bool],
  91                    [Return type of HandleTopLevelDeclReturn])
  92          AC_DEFINE([HandleTopLevelDeclContinue], [true],
  93                    [Return type of HandleTopLevelDeclReturn])])
  94 AC_EGREP_HEADER([isEnclosingLocal,], [clang/AST/Expr.h],
  95         [AC_DEFINE([DECLREFEXPR_CREATE_REQUIRES_BOOL], [],
  96             [Define if DeclRefExpr::Create takes isEnclosingLocal argument])])
  97 AC_EGREP_HEADER([HasTemplateKWAndArgsInfo], [clang/AST/Expr.h],
  98         [AC_DEFINE([DECLREFEXPR_CREATE_REQUIRES_SOURCELOCATION], [],
  99                 [Define if DeclRefExpr::Create takes SourceLocation argument])])
 100 AC_CHECK_HEADER([clang/Basic/DiagnosticOptions.h],
 101         [AC_DEFINE([HAVE_BASIC_DIAGNOSTICOPTIONS_H], [],
 102                    [Define if clang/Basic/DiagnosticOptions.h exists])])
 103 AC_CHECK_HEADER([clang/Lex/HeaderSearchOptions.h],
 104         [AC_DEFINE([HAVE_LEX_HEADERSEARCHOPTIONS_H], [],
 105                    [Define if clang/Lex/HeaderSearchOptions.h exists])], [],
 106         [#include <clang/Basic/LLVM.h>])
 107 AC_CHECK_HEADER([clang/Lex/PreprocessorOptions.h],
 108         [AC_DEFINE([HAVE_LEX_PREPROCESSOROPTIONS_H], [],
 109                    [Define if clang/Lex/PreprocessorOptions.h exists])], [],
 110         [#include <clang/Basic/LLVM.h>])
 111 AC_TRY_COMPILE([#include <clang/Basic/TargetInfo.h>], [
 112         using namespace clang;
 113         TargetOptions *TO;
 114         DiagnosticsEngine *Diags;
 115         TargetInfo::CreateTargetInfo(*Diags, TO);
 116 ], [AC_DEFINE([CREATETARGETINFO_TAKES_POINTER], [],
 117               [Define if TargetInfo::CreateTargetInfo takes pointer])])
 118 AC_EGREP_HEADER([getLangOpts], [clang/Lex/Preprocessor.h], [],
 119         [AC_DEFINE([getLangOpts], [getLangOptions],
 120         [Define to getLangOptions for older versions of clang])])
 121 AC_EGREP_HEADER([findLocationAfterToken], [clang/Lex/Lexer.h],
 122         [AC_DEFINE([HAVE_FINDLOCATIONAFTERTOKEN], [],
 123         [Define if SourceManager has findLocationAfterToken method])])
 124 AC_EGREP_HEADER([translateLineCol], [clang/Basic/SourceManager.h],
 125         [AC_DEFINE([HAVE_TRANSLATELINECOL], [],
 126         [Define if SourceManager has translateLineCol method])])
 127 AC_TRY_COMPILE([#include <clang/Frontend/CompilerInstance.h>], [
 128         using namespace clang;
 129         DiagnosticConsumer *client;
 130         CompilerInstance *Clang;
 131         Clang->createDiagnostics(client);
 132 ], [], [AC_DEFINE([CREATEDIAGNOSTICS_TAKES_ARG], [],
 133         [Define if CompilerInstance::createDiagnostics takes argc and argv])])
 134 AC_TRY_COMPILE([#include <clang/Lex/HeaderSearchOptions.h>], [
 135         using namespace clang;
 136         HeaderSearchOptions HSO;
 137         HSO.AddPath("", frontend::Angled, false, false);
 138 ], [AC_DEFINE([ADDPATH_TAKES_4_ARGUMENTS], [],
 139         [Define if HeaderSearchOptions::AddPath takes 4 arguments])])
 140 AC_EGREP_HEADER([getLocWithOffset], [clang/Basic/SourceLocation.h], [],
 141         [AC_DEFINE([getLocWithOffset], [getFileLocWithOffset],
 142         [Define to getFileLocWithOffset for older versions of clang])])
 143 AC_TRY_COMPILE([#include <clang/Frontend/CompilerInstance.h>], [
 144         using namespace clang;
 145         CompilerInstance *Clang;
 146         Clang->createPreprocessor(TU_Complete);
 147 ], [AC_DEFINE([CREATEPREPROCESSOR_TAKES_TUKIND], [],
 148 [Define if CompilerInstance::createPreprocessor takes TranslationUnitKind])])
 149 AC_EGREP_HEADER([DecayedType], [clang/AST/Type.h],
 150         [AC_DEFINE([HAVE_DECAYEDTYPE], [], [Define if DecayedType is defined])])
 151 AC_LANG_POP
 152 CPPFLAGS="$SAVE_CPPFLAGS"
 153
 154 SAVE_LDFLAGS="$LDFLAGS"
 155 LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
 156 AC_SUBST(LIB_CLANG_EDIT)
 157 AC_CHECK_LIB([clangEdit], [main], [LIB_CLANG_EDIT=-lclangEdit], [])
 158 LDFLAGS="$SAVE_LDFLAGS"
 159
 160 AX_SUBMODULE(isl,build|bundled|system,bundled)
 161 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 162
 163 AC_SUBST(ISL_CFLAGS)
 164 AC_SUBST(ISL_LIBS)
 165 AC_SUBST(ISL_SRCDIR)
 166 case "$with_isl" in
 167 bundled)
 168         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
 169         ISL_CFLAGS="$ISL_CFLAGS"
 170         ISL_SRCDIR="$srcdir/isl"
 171         ;;
 172 build)
 173         ISL_SRCDIR="$isl_srcdir"
 174         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
 175         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
 176         ISL_CFLAGS="$ISL_CFLAGS"
 177         ISL_LIBS="$with_isl_builddir/libisl.la"
 178         ;;
 179 system)
 180         PKG_CHECK_MODULES([ISL], [isl])
 181         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
 182 esac
 183
 184 AX_SUBMODULE(libyaml,system|no,system)
 185 AC_SUBST(LIBYAML_CPPFLAGS)
 186 AC_SUBST(LIBYAML_LDFLAGS)
 187 if test "x$with_libyaml_prefix" != "x"; then
 188         LIBYAML_CPPFLAGS="-I$with_libyaml_prefix/include"
 189 fi
 190 if test "x$with_libyaml_exec_prefix" != "x"; then
 191         LIBYAML_LDFLAGS="-L$with_libyaml_exec_prefix/lib"
 192 fi
 193
 194 if test "$with_libyaml" = "system"; then
 195         SAVE_CPPFLAGS=$CPPFLAGS
 196         CPPFLAGS="$CPPFLAGS $LIBYAML_CPPFLAGS"
 197         AC_CHECK_HEADER([yaml.h],[],[with_libyaml="no"])
 198         CPPFLAGS="$SAVE_CPPFLAGS"
 199 fi
 200
 201 AC_SUBST(extra_bin_programs)
 202 AC_SUBST(extra_noinst_programs)
 203 AC_SUBST(extra_tests)
 204
 205 if test "$with_libyaml" != "no"; then
 206         extra_bin_programs="pet"
 207         extra_noinst_programs="pet_scop_cmp"
 208         extra_tests="pet_test.sh"
 209 fi
 210 if test "$with_isl" != "system"; then
 211         extra_tests="$extra_tests codegen_test.sh"
 212 fi
 213
 214 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
 215 PACKAGE_LIBS="-lpet -lisl"
 216 AX_CREATE_PKGCONFIG_INFO
 217
 218 AX_DETECT_GIT_HEAD
 219 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > gitversion.h
 220
 221 AC_CONFIG_HEADERS(config.h)
 222 AC_CONFIG_FILES(Makefile)
 223 AC_CONFIG_FILES([pet_test.sh], [chmod +x pet_test.sh])
 224 AC_CONFIG_FILES([codegen_test.sh], [chmod +x codegen_test.sh])
 225 if test $with_isl = bundled; then
 226         AC_CONFIG_SUBDIRS(isl)
 227 fi
 228 AC_OUTPUT