m4/ax_detect_clang.m4

   1 AC_DEFUN([AX_DETECT_CLANG], [
   2 AC_SUBST(CLANG_CXXFLAGS)
   3 AC_SUBST(CLANG_LDFLAGS)
   4 AC_SUBST(CLANG_LIBS)
   5 AC_SUBST(CLANG_RFLAG)
   6 AX_SUBMODULE(clang,system,system)
   7 if test "x$with_clang_prefix" != "x"; then
   8         LLVM_CONFIG="$with_clang_prefix/bin/llvm-config"
   9 fi
  10 AC_PATH_PROG([LLVM_CONFIG], ["llvm-config"])
  11 if test -z "$LLVM_CONFIG" || test ! -x "$LLVM_CONFIG"; then
  12         AC_MSG_ERROR([llvm-config not found])
  13 fi
  14 CLANG_CXXFLAGS=`$LLVM_CONFIG --cxxflags | \
  15         $SED -e 's/-Wcovered-switch-default//' \
  16              -e 's/-gsplit-dwarf//' \
  17              -e 's/-Wl,--no-keep-files-mapped//'`
  18 CLANG_LDFLAGS=`$LLVM_CONFIG --ldflags`
  19 # Construct a -R argument for libtool.
  20 # This is needed in case some of the clang libraries are shared libraries.
  21 CLANG_RFLAG=`echo "$CLANG_LDFLAGS" | $SED -e 's/-L/-R/g'`
  22
  23 CLANG_VERSION=`$LLVM_CONFIG --version`
  24 CLANG_LIB="LLVM-$CLANG_VERSION"
  25
  26 SAVE_LDFLAGS="$LDFLAGS"
  27 LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
  28 AC_CHECK_LIB([$CLANG_LIB], [main], [have_lib_llvm=yes], [have_lib_llvm=no])
  29 LDFLAGS="$SAVE_LDFLAGS"
  30
  31 # Use single libLLVM shared library when available.
  32 # Otherwise, try and figure out all the required libraries
  33 if test "$have_lib_llvm" = yes; then
  34         CLANG_LIBS="-l$CLANG_LIB"
  35 else
  36         targets=`$LLVM_CONFIG --targets-built`
  37         components="$targets asmparser bitreader support mc"
  38         for c in option frontendopenmp; do
  39                 $LLVM_CONFIG --components | $GREP $c > /dev/null 2> /dev/null
  40                 if test $? -eq 0; then
  41                         components="$components $c"
  42                 fi
  43         done
  44         CLANG_LIBS=`$LLVM_CONFIG --libs $components`
  45 fi
  46 systemlibs=`$LLVM_CONFIG --system-libs 2> /dev/null | tail -1`
  47 if test $? -eq 0; then
  48         CLANG_LIBS="$CLANG_LIBS $systemlibs"
  49 fi
  50 CLANG_PREFIX=`$LLVM_CONFIG --prefix`
  51 AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"], [Clang installation prefix])
  52
  53 SAVE_CPPFLAGS="$CPPFLAGS"
  54 CPPFLAGS="$CLANG_CXXFLAGS -I$srcdir $CPPFLAGS"
  55 AC_LANG_PUSH(C++)
  56 AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
  57         [AC_MSG_ERROR([clang header file not found])])
  58 AC_CHECK_HEADER([llvm/TargetParser/Host.h],
  59         [AC_DEFINE([HAVE_TARGETPARSER_HOST_H], [],
  60                    [Define if llvm/TargetParser/Host.h exists])],
  61         [AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
  62                 [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
  63                 [Define to getHostTriple for older versions of clang])])
  64         ])
  65 AC_EGREP_HEADER([getExpansionLineNumber], [clang/Basic/SourceLocation.h], [],
  66         [AC_DEFINE([getExpansionLineNumber], [getInstantiationLineNumber],
  67         [Define to getInstantiationLineNumber for older versions of clang])])
  68 AC_EGREP_HEADER([getExpansionColumnNumber], [clang/Basic/SourceLocation.h], [],
  69         [AC_DEFINE([getExpansionColumnNumber], [getInstantiationColumnNumber],
  70         [Define to getInstantiationColumnNumber for older versions of clang])])
  71 AC_EGREP_HEADER([getExpansionLoc], [clang/Basic/SourceManager.h], [],
  72         [AC_DEFINE([getExpansionLoc], [getInstantiationLoc],
  73         [Define to getInstantiationLoc for older versions of clang])])
  74 AC_EGREP_HEADER([DiagnosticConsumer], [clang/Basic/Diagnostic.h], [],
  75         [AC_DEFINE([DiagnosticConsumer], [DiagnosticClient],
  76         [Define to DiagnosticClient for older versions of clang])])
  77 AC_EGREP_HEADER([DiagnosticsEngine], [clang/Basic/Diagnostic.h],
  78         [AC_DEFINE([DiagnosticInfo], [Diagnostic],
  79         [Define to Diagnostic for newer versions of clang])],
  80         [AC_DEFINE([DiagnosticsEngine], [Diagnostic],
  81         [Define to Diagnostic for older versions of clang])])
  82 AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
  83         [AC_DEFINE([USE_ARRAYREF], [],
  84                 [Define if Driver::BuildCompilation takes ArrayRef])
  85         AC_EGREP_HEADER([ArrayRef.*CommandLineArgs],
  86                 [clang/Frontend/CompilerInvocation.h],
  87                 [AC_DEFINE([CREATE_FROM_ARGS_TAKES_ARRAYREF], [],
  88                         [Define if CompilerInvocation::CreateFromArgs takes
  89                          ArrayRef])
  90                 ])
  91         ])
  92 AC_EGREP_HEADER([getReturnType], [clang/AST/Decl.h], [],
  93         [AC_DEFINE([getReturnType], [getResultType],
  94         [Define to getResultType for older versions of clang])])
  95 AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
  96         [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
  97                 [Define if Driver constructor takes CXXIsProduction argument])])
  98 AC_EGREP_HEADER([ IsProduction], [clang/Driver/Driver.h],
  99         [AC_DEFINE([HAVE_ISPRODUCTION], [],
 100                 [Define if Driver constructor takes IsProduction argument])])
 101 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <clang/Driver/Driver.h>]], [[
 102         using namespace clang;
 103         DiagnosticsEngine *Diags;
 104         new driver::Driver("", "", "", *Diags);
 105 ]])], [AC_DEFINE([DRIVER_CTOR_TAKES_DEFAULTIMAGENAME], [],
 106               [Define if Driver constructor takes default image name])])
 107 AC_EGREP_HEADER([void HandleTopLevelDecl\(], [clang/AST/ASTConsumer.h],
 108         [AC_DEFINE([HandleTopLevelDeclReturn], [void],
 109                    [Return type of HandleTopLevelDeclReturn])
 110          AC_DEFINE([HandleTopLevelDeclContinue], [],
 111                    [Return type of HandleTopLevelDeclReturn])],
 112         [AC_DEFINE([HandleTopLevelDeclReturn], [bool],
 113                    [Return type of HandleTopLevelDeclReturn])
 114          AC_DEFINE([HandleTopLevelDeclContinue], [true],
 115                    [Return type of HandleTopLevelDeclReturn])])
 116 AC_CHECK_HEADER([clang/Basic/DiagnosticOptions.h],
 117         [AC_DEFINE([HAVE_BASIC_DIAGNOSTICOPTIONS_H], [],
 118                    [Define if clang/Basic/DiagnosticOptions.h exists])])
 119 AC_CHECK_HEADER([clang/Lex/HeaderSearchOptions.h],
 120         [AC_DEFINE([HAVE_LEX_HEADERSEARCHOPTIONS_H], [],
 121                    [Define if clang/Lex/HeaderSearchOptions.h exists])], [],
 122         [#include <clang/Basic/LLVM.h>])
 123 AC_CHECK_HEADER([clang/Lex/PreprocessorOptions.h],
 124         [AC_DEFINE([HAVE_LEX_PREPROCESSOROPTIONS_H], [],
 125                    [Define if clang/Lex/PreprocessorOptions.h exists])], [],
 126         [#include <clang/Basic/LLVM.h>])
 127 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <clang/Basic/TargetInfo.h>]], [[
 128         using namespace clang;
 129         std::shared_ptr<TargetOptions> TO;
 130         DiagnosticsEngine *Diags;
 131         TargetInfo::CreateTargetInfo(*Diags, TO);
 132 ]])], [AC_DEFINE([CREATETARGETINFO_TAKES_SHARED_PTR], [],
 133               [Define if TargetInfo::CreateTargetInfo takes shared_ptr])])
 134 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <clang/Basic/TargetInfo.h>]], [[
 135         using namespace clang;
 136         TargetOptions *TO;
 137         DiagnosticsEngine *Diags;
 138         TargetInfo::CreateTargetInfo(*Diags, TO);
 139 ]])], [AC_DEFINE([CREATETARGETINFO_TAKES_POINTER], [],
 140               [Define if TargetInfo::CreateTargetInfo takes pointer])])
 141 AC_EGREP_HEADER([getLangOpts], [clang/Lex/Preprocessor.h], [],
 142         [AC_DEFINE([getLangOpts], [getLangOptions],
 143         [Define to getLangOptions for older versions of clang])])
 144 AC_EGREP_HEADER([findLocationAfterToken], [clang/Lex/Lexer.h],
 145         [AC_DEFINE([HAVE_FINDLOCATIONAFTERTOKEN], [],
 146         [Define if SourceManager has findLocationAfterToken method])])
 147 AC_EGREP_HEADER([translateLineCol], [clang/Basic/SourceManager.h],
 148         [AC_DEFINE([HAVE_TRANSLATELINECOL], [],
 149         [Define if SourceManager has translateLineCol method])])
 150 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 151                 [[#include <clang/Frontend/CompilerInstance.h>]], [[
 152         using namespace clang;
 153         DiagnosticConsumer *client;
 154         CompilerInstance *Clang;
 155         Clang->createDiagnostics(client);
 156 ]])], [], [AC_DEFINE([CREATEDIAGNOSTICS_TAKES_ARG], [],
 157         [Define if CompilerInstance::createDiagnostics takes argc and argv])])
 158 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 159                 [[#include <clang/Lex/HeaderSearchOptions.h>]], [[
 160         using namespace clang;
 161         HeaderSearchOptions HSO;
 162         HSO.AddPath("", frontend::Angled, false, false);
 163 ]])], [AC_DEFINE([ADDPATH_TAKES_4_ARGUMENTS], [],
 164         [Define if HeaderSearchOptions::AddPath takes 4 arguments])])
 165 AC_EGREP_HEADER([getLocWithOffset], [clang/Basic/SourceLocation.h], [],
 166         [AC_DEFINE([getLocWithOffset], [getFileLocWithOffset],
 167         [Define to getFileLocWithOffset for older versions of clang])])
 168 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 169                 [[#include <clang/Frontend/CompilerInstance.h>]], [[
 170         using namespace clang;
 171         CompilerInstance *Clang;
 172         Clang->createPreprocessor(TU_Complete);
 173 ]])], [AC_DEFINE([CREATEPREPROCESSOR_TAKES_TUKIND], [],
 174 [Define if CompilerInstance::createPreprocessor takes TranslationUnitKind])])
 175 AC_EGREP_HEADER([DecayedType], [clang/AST/Type.h],
 176         [AC_DEFINE([HAVE_DECAYEDTYPE], [], [Define if DecayedType is defined])])
 177 AC_EGREP_HEADER([setMainFileID], [clang/Basic/SourceManager.h],
 178         [AC_DEFINE([HAVE_SETMAINFILEID], [],
 179         [Define if SourceManager has a setMainFileID method])])
 180 AC_CHECK_HEADER([llvm/ADT/OwningPtr.h],
 181         [AC_DEFINE([HAVE_ADT_OWNINGPTR_H], [],
 182                    [Define if llvm/ADT/OwningPtr.h exists])])
 183 AC_EGREP_HEADER([TypeInfo getTypeInfo], [clang/AST/ASTContext.h],
 184         [AC_DEFINE([GETTYPEINFORETURNSTYPEINFO], [],
 185                 [Define if getTypeInfo returns TypeInfo object])])
 186 AC_EGREP_HEADER([TypedefNameDecl], [clang/AST/Type.h], [],
 187         [AC_DEFINE([TypedefNameDecl], [TypedefDecl],
 188                 [Define to TypedefDecl for older versions of clang])
 189          AC_DEFINE([getTypedefNameForAnonDecl], [getTypedefForAnonDecl],
 190                 [Define to getTypedefForAnonDecl for older versions of clang])])
 191 AC_EGREP_HEADER([StmtRange], [clang/AST/StmtIterator.h],
 192         [AC_DEFINE([HAVE_STMTRANGE], [],
 193         [Define if StmtRange class is available])])
 194 AC_EGREP_HEADER([initializeBuiltins],
 195         [clang/Basic/Builtins.h], [],
 196         [AC_DEFINE([initializeBuiltins], [InitializeBuiltins],
 197                 [Define to InitializeBuiltins for older versions of clang])])
 198 AC_EGREP_HEADER([IK_C], [clang/Frontend/FrontendOptions.h], [],
 199         [AC_CHECK_HEADER([clang/Basic/LangStandard.h],
 200                 [IK_C=Language::C], [IK_C=InputKind::C])
 201          AC_DEFINE_UNQUOTED([IK_C], [$IK_C],
 202          [Define to Language::C or InputKind::C for newer versions of clang])
 203         ])
 204 # llvmorg-15-init-7544-g93471e65df48
 205 AC_EGREP_HEADER([setLangDefaults], [clang/Basic/LangOptions.h],
 206         [SETLANGDEFAULTS=LangOptions],
 207         [SETLANGDEFAULTS=CompilerInvocation])
 208 AC_DEFINE_UNQUOTED([SETLANGDEFAULTS], [$SETLANGDEFAULTS],
 209         [Define to class with setLangDefaults method])
 210 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 211         #include <clang/Basic/TargetOptions.h>
 212         #include <clang/Lex/PreprocessorOptions.h>
 213         #include <clang/Frontend/CompilerInstance.h>
 214
 215         #include "set_lang_defaults_arg4.h"
 216 ]], [[
 217         using namespace clang;
 218         CompilerInstance *Clang;
 219         TargetOptions TO;
 220         llvm::Triple T(TO.Triple);
 221         PreprocessorOptions PO;
 222         SETLANGDEFAULTS::setLangDefaults(Clang->getLangOpts(), IK_C,
 223                         T, setLangDefaultsArg4(PO),
 224                         LangStandard::lang_unspecified);
 225 ]])], [AC_DEFINE([SETLANGDEFAULTS_TAKES_5_ARGUMENTS], [],
 226         [Define if CompilerInvocation::setLangDefaults takes 5 arguments])])
 227 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 228         #include <clang/Frontend/CompilerInstance.h>
 229         #include <clang/Frontend/CompilerInvocation.h>
 230 ]], [[
 231         using namespace clang;
 232         CompilerInvocation *invocation;
 233         CompilerInstance *Clang;
 234         Clang->setInvocation(std::make_shared<CompilerInvocation>(*invocation));
 235 ]])], [AC_DEFINE([SETINVOCATION_TAKES_SHARED_PTR], [],
 236         [Defined if CompilerInstance::setInvocation takes a shared_ptr])])
 237 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 238         #include <clang/AST/Decl.h>
 239 ]], [[
 240         clang::FunctionDecl *fd;
 241         fd->getBeginLoc();
 242         fd->getEndLoc();
 243 ]])],
 244         [AC_DEFINE([HAVE_BEGIN_END_LOC], [],
 245                 [Define if getBeginLoc and getEndLoc should be used])])
 246 AC_CHECK_HEADER([llvm/Option/Arg.h],
 247         [AC_DEFINE([HAVE_LLVM_OPTION_ARG_H], [],
 248                    [Define if llvm/Option/Arg.h exists])])
 249 AC_EGREP_HEADER([PragmaIntroducer ],
 250         [clang/Lex/Pragma.h], [],
 251         [AC_DEFINE([PragmaIntroducer], [PragmaIntroducerKind],
 252                 [Define to PragmaIntroducerKind for older versions of clang])])
 253 AC_CHECK_HEADER([clang/Basic/LangStandard.h],
 254         [AC_DEFINE([HAVE_CLANG_BASIC_LANGSTANDARD_H], [],
 255                    [Define if clang/Basic/LangStandard.h exists])])
 256 AC_EGREP_HEADER([setDiagnosticGroupWarningAsError], [clang/Basic/Diagnostic.h],
 257         [AC_DEFINE([HAVE_SET_DIAGNOSTIC_GROUP_WARNING_AS_ERROR], [],
 258         [Define if DiagnosticsEngine::setDiagnosticGroupWarningAsError \
 259         is available])])
 260 # llvmorg-15-init-8223-g7d644e1215b3
 261 AC_EGREP_HEADER([ext_implicit_function_decl_c99],
 262                 [clang/Basic/DiagnosticCategories.h], [],
 263         [AC_DEFINE([ext_implicit_function_decl_c99],
 264         [ext_implicit_function_decl],
 265         [Define to ext_implicit_function_decl for older versions of clang])])
 266 AC_LANG_POP
 267 CPPFLAGS="$SAVE_CPPFLAGS"
 268
 269 SAVE_LDFLAGS="$LDFLAGS"
 270 LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
 271
 272 # Use single libclang-cpp shared library when available.
 273 # Otherwise, use a selection of clang libraries that appears to work.
 274 AC_CHECK_LIB([clang-cpp], [main], [have_lib_clang=yes], [have_lib_clang=no])
 275 if test "$have_lib_clang" = yes; then
 276         CLANG_LIBS="-lclang-cpp $CLANG_LIBS"
 277 else
 278         CLANG_LIBS="-lclangBasic -lclangDriver $CLANG_LIBS"
 279         CLANG_LIBS="-lclangAnalysis -lclangAST -lclangLex $CLANG_LIBS"
 280         LDFLAGS="$CLANG_LDFLAGS $CLANG_LIBS $SAVE_LDFLAGS"
 281         AC_CHECK_LIB([clangEdit], [main], [LIB_CLANG_EDIT=-lclangEdit], [])
 282         CLANG_LIBS="$LIB_CLANG_EDIT $CLANG_LIBS"
 283         CLANG_LIBS="-lclangParse -lclangSema $CLANG_LIBS"
 284         CLANG_LIBS="-lclangFrontend -lclangSerialization $CLANG_LIBS"
 285 fi
 286
 287 LDFLAGS="$SAVE_LDFLAGS"
 288 ])