configure.ac

   1 AC_INIT([pet], [0.01], [isl-development@googlegroups.com])
   2 AC_CONFIG_AUX_DIR([build-aux])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6 AC_SUBST(versioninfo)
   7 versioninfo=1:0:0
   8
   9 AC_PROG_CC
  10 AC_PROG_CXX
  11 AC_PROG_LIBTOOL
  12
  13 AC_SUBST(CLANG_CXXFLAGS)
  14 AC_SUBST(CLANG_LDFLAGS)
  15 AC_SUBST(CLANG_LIBS)
  16 AX_SUBMODULE(clang,system,system)
  17 llvm_config="llvm-config"
  18 AC_CHECK_PROG([llvm_config_found], ["$llvm_config"], [yes])
  19 if test "x$with_clang_prefix" != "x"; then
  20         llvm_config="$with_clang_prefix/bin/llvm-config"
  21         if test -x "$llvm_config"; then
  22                 llvm_config_found=yes
  23         fi
  24 fi
  25 if test "$llvm_config_found" != yes; then
  26         AC_MSG_ERROR([llvm-config not found])
  27 fi
  28 CLANG_CXXFLAGS=`$llvm_config --cxxflags`
  29 CLANG_LDFLAGS=`$llvm_config --ldflags`
  30 CLANG_LIBS=`$llvm_config --libs analysis`
  31 CLANG_PREFIX=`$llvm_config --prefix`
  32 AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"], [Clang installation prefix])
  33
  34 SAVE_CPPFLAGS="$CPPFLAGS"
  35 CPPFLAGS="$CLANG_CXXFLAGS $CPPFLAGS"
  36 AC_LANG_PUSH(C++)
  37 AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
  38         [AC_ERROR([clang header file not found])])
  39 AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
  40         [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
  41         [Define to getHostTriple for older versions of clang])])
  42 AC_EGREP_HEADER([getExpansionLineNumber], [clang/Basic/SourceLocation.h], [],
  43         [AC_DEFINE([getExpansionLineNumber], [getInstantiationLineNumber],
  44         [Define to getInstantiationLineNumber for older versions of clang])])
  45 AC_EGREP_HEADER([DiagnosticConsumer], [clang/Basic/Diagnostic.h], [],
  46         [AC_DEFINE([DiagnosticConsumer], [DiagnosticClient],
  47         [Define to DiagnosticClient for older versions of clang])])
  48 AC_EGREP_HEADER([DiagnosticsEngine], [clang/Basic/Diagnostic.h],
  49         [AC_DEFINE([DiagnosticInfo], [Diagnostic],
  50         [Define to Diagnostic for newer versions of clang])],
  51         [AC_DEFINE([DiagnosticsEngine], [Diagnostic],
  52         [Define to Diagnostic for older versions of clang])])
  53 AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
  54         [AC_DEFINE([USE_ARRAYREF], [],
  55                 [Define if Driver::BuildCompilation takes ArrayRef])])
  56 AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
  57         [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
  58                 [Define if Driver constructor takes CXXIsProduction argument])])
  59 AC_EGREP_HEADER([void HandleTopLevelDecl\(], [clang/AST/ASTConsumer.h],
  60         [AC_DEFINE([HandleTopLevelDeclReturn], [void],
  61                    [Return type of HandleTopLevelDeclReturn])
  62          AC_DEFINE([HandleTopLevelDeclContinue], [],
  63                    [Return type of HandleTopLevelDeclReturn])],
  64         [AC_DEFINE([HandleTopLevelDeclReturn], [bool],
  65                    [Return type of HandleTopLevelDeclReturn])
  66          AC_DEFINE([HandleTopLevelDeclContinue], [true],
  67                    [Return type of HandleTopLevelDeclReturn])])
  68 AC_EGREP_HEADER([isEnclosingLocal,], [clang/AST/Expr.h],
  69         [AC_DEFINE([DECLREFEXPR_CREATE_REQUIRES_BOOL], [],
  70             [Define if DeclRefExpr::Create takes isEnclosingLocal argument])])
  71 AC_EGREP_HEADER([HasTemplateKWAndArgsInfo], [clang/AST/Expr.h],
  72         [AC_DEFINE([DECLREFEXPR_CREATE_REQUIRES_SOURCELOCATION], [],
  73                 [Define if DeclRefExpr::Create takes SourceLocation argument])])
  74 AC_LANG_POP
  75 CPPFLAGS="$SAVE_CPPFLAGS"
  76
  77 SAVE_LDFLAGS="$LDFLAGS"
  78 LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
  79 AC_SUBST(LIB_CLANG_EDIT)
  80 AC_CHECK_LIB([clangEdit], [main], [LIB_CLANG_EDIT=-lclangEdit], [])
  81 LDFLAGS="$SAVE_LDFLAGS"
  82
  83 AX_SUBMODULE(gmp,system|build,system)
  84
  85 AC_SUBST(GMP_LDFLAGS)
  86 AC_SUBST(GMP_LIBS)
  87 case "$with_gmp" in
  88 system)
  89         if test "x$with_gmp_prefix" != "x"; then
  90                 GMP_CPPFLAGS="-I$with_gmp_prefix/include"
  91                 GMP_LDFLAGS="-L$with_gmp_prefix/lib"
  92         fi
  93         GMP_LIBS=-lgmp
  94         ;;
  95 build)
  96         GMP_CPPFLAGS="-I$gmp_srcdir -I$with_gmp_builddir"
  97         GMP_LIBS="$with_gmp_builddir/libgmp.la"
  98         ;;
  99 esac
 100
 101 AX_SUBMODULE(isl,build|bundled|system,bundled)
 102 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 103
 104 AC_SUBST(ISL_CFLAGS)
 105 AC_SUBST(ISL_LIBS)
 106 case "$with_isl" in
 107 bundled)
 108         ISL_CFLAGS="-I\$(top_srcdir)/isl/include -I\$(top_builddir)/isl/include"
 109         ISL_CFLAGS="$ISL_CFLAGS $GMP_CPPFLAGS"
 110         ;;
 111 build)
 112         ISL_BUILDDIR=`echo @abs_builddir@ | $with_isl_builddir/config.status --file=-`
 113         ISL_CFLAGS="-I$isl_srcdir/include -I$ISL_BUILDDIR/include"
 114         ISL_CFLAGS="$ISL_CFLAGS $GMP_CPPFLAGS"
 115         ISL_LIBS="$with_isl_builddir/libisl.la $GMP_LDFLAGS $GMP_LIBS"
 116         ;;
 117 system)
 118         PKG_CHECK_MODULES([ISL], [isl])
 119         PACKAGE_CFLAGS_ISL="$ISL_CFLAGS"
 120 esac
 121
 122 AX_SUBMODULE(libyaml,system,system)
 123 AC_SUBST(LIBYAML_CPPFLAGS)
 124 AC_SUBST(LIBYAML_LDFLAGS)
 125 if test "x$with_libyaml_prefix" != "x"; then
 126         LIBYAML_CPPFLAGS="-I$with_libyaml_prefix/include"
 127 fi
 128 if test "x$with_libyaml_exec_prefix" != "x"; then
 129         LIBYAML_LDFLAGS="-L$with_libyaml_exec_prefix/lib"
 130 fi
 131
 132 PACKAGE_CFLAGS="$PACKAGE_CFLAGS_ISL"
 133 PACKAGE_LIBS="-lpet -lisl"
 134 AX_CREATE_PKGCONFIG_INFO
 135
 136 AX_DETECT_GIT_HEAD
 137 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > gitversion.h
 138
 139 AC_CONFIG_HEADERS(config.h)
 140 AC_CONFIG_FILES(Makefile)
 141 AC_CONFIG_FILES([pet_test.sh], [chmod +x pet_test.sh])
 142 if test $with_isl = bundled; then
 143         AC_CONFIG_SUBDIRS(isl)
 144 fi
 145 AC_OUTPUT