tools/dev/cc_flags.pl

   1 #! perl
   2 ################################################################################
   3 # Copyright (C) 2001-2003, Parrot Foundation.
   4 # $Id$
   5 ################################################################################
   6
   7 =head1 NAME
   8
   9 tools/dev/cc_flags.pl - Process compiler flags
  10
  11 =head1 SYNOPSIS
  12
  13     % perl tools/dev/cc_flags.pl transform compiler flags
  14
  15 =head1 DESCRIPTION
  16
  17 This script is used in a F<Makefile> to process the flags to pass to the
  18 compiler for each C file.
  19
  20 See F<config/gen/makefiles/CFLAGS.in> for the transformation file format.
  21
  22 =head1 SEE ALSO
  23
  24 F<config/gen/cflags/root.in>.
  25
  26 =cut
  27
  28 ################################################################################
  29
  30 use strict;
  31 use warnings;
  32
  33 my $return_only;
  34 my $verbose;
  35
  36 if ($ARGV[0] eq '--return-only') {
  37     $return_only = 1;
  38     shift;
  39 }
  40
  41 if ($ARGV[0] eq '-v') {
  42     $verbose = 1;
  43     shift;
  44 }
  45
  46 my $cflags = shift;
  47
  48 open my $F, '<', $cflags or die "open $cflags: $!\n";
  49
  50 my @options;
  51
  52 while (<$F>) {
  53     chomp;
  54     s/#.*//;
  55     next unless /\S/;
  56
  57     my $regex;
  58     if (s/^\{(.*?)\}\s*//) {
  59         next unless $1;
  60         $regex = qr/$1/;
  61     }
  62     elsif (s/^(\S+)\s*//) {
  63         $regex = qr/^\Q$1\E$/;
  64     }
  65     else {
  66         die "syntax error in $cflags: line $., $_\n";
  67     }
  68
  69     for ( ; ; ) {
  70         if (s/^([-+])\{(.*?)\}\s*//) {
  71             next unless $2;
  72             my ( $sign, $options ) = ( $1, $2 );
  73             foreach my $option ( split ' ', $options ) {
  74                 push @options, [ $regex, $sign, $option ];
  75             }
  76         }
  77         elsif (s{s(.)(.*?)\1(.*?)\1([imsx]*)\s*}{}) {
  78             my $mod = "";
  79             $mod = "(?$4)" if $4;
  80
  81             push @options, [ $regex, 's', "$mod$2", $3 ];
  82         }
  83         elsif (/\S/) {
  84             die "syntax error in $cflags: line $., $_\n";
  85         }
  86         else {
  87             last;
  88         }
  89     }
  90 }
  91
  92 my ($cfile) = grep /\.c$/, @ARGV;
  93
  94 my ( $inject_point, $where );
  95
  96 foreach (@ARGV) {
  97     last if $_ eq '';
  98     ++$where;
  99 }
 100 if ($where) {
 101
 102     # Found a "" - remove it
 103     splice @ARGV, $where, 1;
 104     $inject_point = $where;
 105 }
 106 else {
 107     $inject_point = 1;
 108 }
 109
 110 if ($cfile) {
 111     foreach my $option (@options) {
 112         if ( $cfile =~ $option->[0] ) {
 113             if ( $option->[1] eq '+' ) {
 114                 splice @ARGV, $inject_point, 0, $option->[2];
 115             }
 116             elsif ( $option->[1] eq '-' ) {
 117                 @ARGV = grep { $_ ne $option->[2] } @ARGV;
 118             }
 119             else {
 120                 foreach my $arg (@ARGV) {
 121                     $arg =~ s/$option->[2]/$option->[3]/;
 122                 }
 123             }
 124         }
 125     }
 126
 127     # print "@ARGV\n";
 128
 129     # Visual C++ already prints the source file name...
 130     if ( $ARGV[0] =~ /cl(?:\.exe)?/i ) {
 131
 132         # ...but only the file name, so we print the path
 133         # to the directory first
 134         if ( $cfile =~ /(.*[\/\\])/ ) {
 135             print $1;
 136         }
 137     }
 138     else {
 139         print "$cfile\n";
 140     }
 141 }
 142
 143 if ($return_only) {
 144     print join ' ', @ARGV;
 145     exit;
 146 }
 147
 148 if ($verbose) {
 149     print join ' ', @ARGV;
 150 }
 151
 152 exit system(@ARGV) / 256;
 153
 154 # Local Variables:
 155 #   mode: cperl
 156 #   cperl-indent-level: 4
 157 #   fill-column: 100
 158 # End:
 159 # vim: expandtab shiftwidth=4: