t/codingstd/c_code_coda.t

   1 #! perl
   2 # Copyright (C) 2006-2009, Parrot Foundation.
   3 # $Id$
   4
   5 use strict;
   6 use warnings;
   7
   8 use lib qw( . lib ../lib ../../lib );
   9 use Test::More tests => 2;
  10 use Parrot::Distribution;
  11 use Parrot::Test::Util::Runloop;
  12
  13 =head1 NAME
  14
  15 t/codingstd/c_code_coda.t - checks for editor hint coda in C source
  16
  17 =head1 SYNOPSIS
  18
  19     # test all files
  20     % prove t/codingstd/c_code_coda.t
  21
  22     # test specific files
  23     % perl t/codingstd/c_code_coda.t src/foo.c include/parrot/bar.h
  24
  25 =head1 DESCRIPTION
  26
  27 Checks that all C language source files have the proper editor hints coda,
  28 as specified in PDD07.
  29
  30 =head1 SEE ALSO
  31
  32 L<docs/pdds/pdd07_codingstd.pod>
  33
  34 =cut
  35
  36 ## L<PDD07/Smart Editor Style Support/"C source files, and files largely consisting of C" "must end with this coda">
  37
  38 my $coda = <<'CODA';
  39 /*
  40  * Local variables:
  41  *   c-file-style: "parrot"
  42  * End:
  43  * vim: expandtab shiftwidth=4:
  44  */
  45 CODA
  46
  47 my $DIST = Parrot::Distribution->new;
  48 my @files = @ARGV ? <@ARGV> : $DIST->get_c_language_files();
  49
  50 Parrot::Test::Util::Runloop->testloop(
  51     name        => 'every file has a coda',
  52     files       => [@files],
  53     per_file    => sub { shift =~ m{\Q$coda\E\n*\z} },
  54     diag_prefix => 'No coda found'
  55 );
  56
  57 Parrot::Test::Util::Runloop->testloop(
  58     name        => 'only one coda per file',
  59     files       => [@files],
  60     per_file    => \&check_duplicates,
  61     diag_prefix => 'Duplicate coda found'
  62 );
  63
  64 sub check_duplicates {
  65     my $buf = shift;
  66
  67     # append to the extra_coda array if coda-like text appears more than once
  68     my $vim_many = 0;
  69     $vim_many++ while $buf =~ m{^ [* \t]* vim[:] }gmx;
  70     my $emacs_many = 0;
  71     $emacs_many++ while $buf =~ m{^ [* \t]* Local \s variables: }gmx;
  72     return ($vim_many <= 1 && $emacs_many <= 1);
  73 }
  74
  75 # Local Variables:
  76 #   mode: cperl
  77 #   cperl-indent-level: 4
  78 #   fill-column: 100
  79 # End:
  80 # vim: expandtab shiftwidth=4: