languages/WMLScript/runtime/wmlslang.pir

   1 # Copyright (C) 2006-2008, The Perl Foundation.
   2 # $Id$
   3
   4 =head1 NAME
   5
   6 runtime/wmlslang.pir - WMLScript Lang library
   7
   8 =head1 DESCRIPTION
   9
  10 This library contains a set of functions that are closely related to the
  11 WMLScript language core.
  12
  13 See "WMLScript Standard Libraries Specification", section 7 "Lang".
  14
  15 =head1 FUNCTIONS
  16
  17 =cut
  18
  19 .loadlib 'wmls_ops'
  20 .HLL 'WMLScript', 'wmls_group'
  21
  22
  23 .sub 'getLang'
  24     new $P0, 'Hash'
  25
  26     .const .Sub _lang_abs = '_lang_abs'
  27     $P0[0]  = _lang_abs
  28     .const .Sub _lang_min = '_lang_min'
  29     $P0[1]  = _lang_min
  30     .const .Sub _lang_max = '_lang_max'
  31     $P0[2]  = _lang_max
  32     .const .Sub _lang_parseInt = '_lang_parseInt'
  33     $P0[3]  = _lang_parseInt
  34     .const .Sub _lang_parseFloat = '_lang_parseFloat'
  35     $P0[4]  = _lang_parseFloat
  36     .const .Sub _lang_isInt = '_lang_isInt'
  37     $P0[5]  = _lang_isInt
  38     .const .Sub _lang_isFloat = '_lang_isFloat'
  39     $P0[6]  = _lang_isFloat
  40     .const .Sub _lang_maxInt = '_lang_maxInt'
  41     $P0[7]  = _lang_maxInt
  42     .const .Sub _lang_minInt = '_lang_minInt'
  43     $P0[8]  = _lang_minInt
  44     .const .Sub _lang_float = '_lang_float'
  45     $P0[9]  = _lang_float
  46     .const .Sub _lang_exit = '_lang_exit'
  47     $P0[10] = _lang_exit
  48     .const .Sub _lang_abort = '_lang_abort'
  49     $P0[11] = _lang_abort
  50     .const .Sub _lang_random = '_lang_random'
  51     $P0[12] = _lang_random
  52     .const .Sub _lang_seed = '_lang_seed'
  53     $P0[13] = _lang_seed
  54     .const .Sub _lang_characterSet = '_lang_characterSet'
  55     $P0[14] = _lang_characterSet
  56
  57     .return ($P0)
  58 .end
  59
  60
  61 =head2 C<abs(value)>
  62
  63 =head3 DESCRIPTION
  64
  65 Returns the absolute value of the given number. If the given number is of
  66 type integer then an integer value is returned. If the given number is of type
  67 floating-point then a floating-point value is returned.
  68
  69 =head3 PARAMETERS
  70
  71 value = Number
  72
  73 =head3 RETURN VALUE
  74
  75 Number or invalid.
  76
  77 =cut
  78
  79 .sub '_lang_abs' :anon
  80     .param pmc value
  81     .local pmc res
  82     res = clone value
  83     res = abs value
  84     .return (res)
  85 .end
  86
  87
  88 =head2 C<min(value1, value2)>
  89
  90 =head3 DESCRIPTION
  91
  92 Returns the minimum value of the given two numbers. The value and type
  93 returned is the same as the value and type of the selected number. The
  94 selection is done in the following way:
  95
  96 =over 4
  97
  98 =item *
  99
 100 WMLScript operator data type conversion rules for I<integers and
 101 floating-points> (see [WMLScript]) must be used to specify the data
 102 type (integer or floating-point ) for comparison.
 103
 104 =item *
 105
 106 Compare the numbers to select the smaller one.
 107
 108 =item *
 109
 110 If the values are equal then the first value is selected.
 111
 112 =back
 113
 114 =head3 PARAMETERS
 115
 116 value1 = Number
 117
 118 value2 = Number
 119
 120 =head3 RETURN VALUE
 121
 122 Number or invalid.
 123
 124 =cut
 125
 126 .sub '_lang_min' :anon
 127     .param pmc value1
 128     .param pmc value2
 129     .local pmc res
 130     $P1 = value1
 131     $I0 = isa value1, 'WmlsString'
 132     unless $I0 goto L1
 133     $P1 = value1.'parseNumber'()
 134   L1:
 135     $P2 = value2
 136     $I0 = isa value2, 'WmlsString'
 137     unless $I0 goto L2
 138     $P2 = value2.'parseNumber'()
 139   L2:
 140     $P0 = isle $P1, $P2
 141     $I0 = isa $P0, 'WmlsInvalid'
 142     unless $I0 goto L3
 143     .return ($P0)
 144   L3:
 145     $I0 = $P0
 146     unless $I0 goto L4
 147     res = clone value1
 148     goto L5
 149   L4:
 150     res = clone value2
 151   L5:
 152     .return (res)
 153 .end
 154
 155
 156 =head2 C<max(value1, value2)>
 157
 158 =head3 DESCRIPTION
 159
 160 Returns the maximum value of the given two numbers. The value and type
 161 returned is the same as the value and type of the selected number. The
 162 selection is done in the following way:
 163
 164 =over 4
 165
 166 =item *
 167
 168 WMLScript operator data type conversion rules for I<integers and
 169 floating-points> (see [WMLScript]) must be used to specify the data
 170 type (integer or floating-point ) for comparison.
 171
 172 =item *
 173
 174 Compare the numbers to select the larger one.
 175
 176 =item *
 177
 178 If the values are equal then the first value is selected.
 179
 180 =back
 181
 182 =head3 PARAMETERS
 183
 184 value1 = Number
 185
 186 value2 = Number
 187
 188 =head3 RETURN VALUE
 189
 190 Number or invalid.
 191
 192 =cut
 193
 194 .sub '_lang_max' :anon
 195     .param pmc value1
 196     .param pmc value2
 197     .local pmc res
 198     $P1 = value1
 199     $I0 = isa value1, 'WmlsString'
 200     unless $I0 goto L1
 201     $P1 = value1.'parseNumber'()
 202   L1:
 203     $P2 = value2
 204     $I0 = isa value2, 'WmlsString'
 205     unless $I0 goto L2
 206     $P2 = value2.'parseNumber'()
 207   L2:
 208     $P0 = isge $P1, $P2
 209     $I0 = isa $P0, 'WmlsInvalid'
 210     unless $I0 goto L3
 211     .return ($P0)
 212   L3:
 213     $I0 = $P0
 214     unless $I0 goto L4
 215     res = clone value1
 216     goto L5
 217   L4:
 218     res = clone value2
 219   L5:
 220     .return (res)
 221 .end
 222
 223
 224 =head2 C<parseInt(value)>
 225
 226 =head3 DESCRIPTION
 227
 228 Returns an integer value defined by the string value. The legal integer
 229 syntax is specified by the WMLScript (see [WMLScript]) numeric string
 230 grammar for I<decimal integer literals> with the following additional parsing
 231 rule:
 232
 233 =over 4
 234
 235 =item *
 236
 237 Parsing ends when the first character is encountered that is not a
 238 leading '+' or '-' or a decimal digit.
 239
 240 =back
 241
 242 The result is the parsed string converted to an integer value.
 243
 244 =head3 PARAMETERS
 245
 246 value = String
 247
 248 =head3 RETURN VALUE
 249
 250 Integer or invalid.
 251
 252 =head3 EXCEPTIONS
 253
 254 In case of a parsing error an C<invalid> value is returned.
 255
 256 =cut
 257
 258 .sub '_lang_parseInt' :anon
 259     .param pmc value
 260     .local pmc res
 261     $I0 = isa value, 'WmlsString'
 262     unless $I0 goto L1
 263     res = value.'parseInt'()
 264     .return (res)
 265   L1:
 266     res = value
 267     $I0 = isa value, 'WmlsInteger'
 268     if $I0 goto L2
 269     new res, 'WmlsInvalid'
 270   L2:
 271     .return (res)
 272 .end
 273
 274
 275 =head2 C<parseFloat(value)>
 276
 277 =head3 DESCRIPTION
 278
 279 Returns a floating-point value defined by the string value. The legal floatingpoint
 280 syntax is specified by the WMLScript (see [WMLScript]) numeric
 281 string grammar for I<decimal floating-point literals> with the following additional
 282 parsing rule:
 283
 284 =over 4
 285
 286 =item *
 287
 288 Parsing ends when the first character is encountered that cannot
 289 be parsed as being part of the floating-point representation.
 290
 291 =back
 292
 293 The result is the parsed string converted to a floating-point value.
 294
 295 =head3 PARAMETERS
 296
 297 value = String
 298
 299 =head3 RETURN VALUE
 300
 301 Floating-point or invalid.
 302
 303 =head3 EXCEPTIONS
 304
 305 In case of a parsing error an C<invalid> value is returned.
 306
 307 =cut
 308
 309 .sub '_lang_parseFloat' :anon
 310     .param pmc value
 311     .local pmc res
 312     $I0 = isa value, 'WmlsString'
 313     unless $I0 goto L1
 314     res = value.'parseFloat'()
 315     .return (res)
 316   L1:
 317     res = value
 318     $I0 = isa value, 'WmlsFloat'
 319     if $I0 goto L2
 320     $I0 = isa value, 'WmlsInteger'
 321     unless $I0 goto L3
 322     $I0 = value
 323     new res, 'WmlsFloat'
 324     set res, $I0
 325     goto L2
 326   L3:
 327     new res, 'WmlsInvalid'
 328   L2:
 329     .return (res)
 330 .end
 331
 332
 333 =head2 C<isInt(value)>
 334
 335 =head3 DESCRIPTION
 336
 337 Returns a boolean value that is C<true> if the given value can be converted
 338 into an integer number by using parseInt(value). Otherwise C<false> is
 339 returned.
 340
 341 =head3 PARAMETERS
 342
 343 value = Any
 344
 345 =head3 RETURN VALUE
 346
 347 Boolean or invalid.
 348
 349 =cut
 350
 351 .sub '_lang_isInt' :anon
 352     .param pmc value
 353     .local pmc res
 354     $I0 = isa value, 'WmlsString'
 355     unless $I0 goto L1
 356     $P0 = value.'parseInt'()
 357     res = defined $P0
 358     .return (res)
 359   L1:
 360     $I0 = isa value, 'WmlsInvalid'
 361     unless $I0 goto L2
 362     new res, 'WmlsInvalid'
 363     .return (res)
 364   L2:
 365     new res, 'WmlsBoolean'
 366     $I0 = isa value, 'WmlsInteger'
 367     set res, $I0
 368     .return (res)
 369 .end
 370
 371
 372 =head2 C<isFloat(value)>
 373
 374 =head3 DESCRIPTION
 375
 376 Returns a boolean value that is C<true> if the given value can be converted
 377 into a floating-point number using parseFloat(value). Otherwise C<false> is
 378 returned.
 379
 380 =head3 PARAMETERS
 381
 382 value = Any
 383
 384 =head3 RETURN VALUE
 385
 386 Boolean or invalid.
 387
 388 =cut
 389
 390 .sub '_lang_isFloat' :anon
 391     .param pmc value
 392     .local pmc res
 393     $I0 = isa value, 'WmlsString'
 394     unless $I0 goto L1
 395     $P0 = value.'parseFloat'()
 396     res = defined $P0
 397     .return (res)
 398   L1:
 399     $I0 = isa value, 'WmlsInvalid'
 400     unless $I0 goto L2
 401     new res, 'WmlsInvalid'
 402     .return (res)
 403   L2:
 404     new res, 'WmlsBoolean'
 405     $I0 = isa value, 'WmlsFloat'
 406     set res, $I0
 407     if $I0 goto L3
 408     $I0 = isa value, 'WmlsInteger'
 409     set res, $I0
 410   L3:
 411     .return (res)
 412 .end
 413
 414
 415 =head2 C<maxInt()>
 416
 417 =head3 DESCRIPTION
 418
 419 Returns the maximum integer value.
 420
 421 =head3 RETURN VALUE
 422
 423 Integer 2147483647.
 424
 425 =cut
 426
 427 .sub '_lang_maxInt' :anon
 428     .local pmc res
 429     new res, 'WmlsInteger'
 430     set res, 2147483647
 431     .return (res)
 432 .end
 433
 434
 435 =head2 C<minInt()>
 436
 437 =head3 DESCRIPTION
 438
 439 Returns the minimum integer value.
 440
 441 =head3 RETURN VALUE
 442
 443 Integer -2147483648.
 444
 445 =cut
 446
 447 .sub '_lang_minInt' :anon
 448     .local pmc res
 449     new res, 'WmlsInteger'
 450     set res, -2147483648
 451     .return (res)
 452 .end
 453
 454
 455 =head2 C<float()>
 456
 457 =head3 DESCRIPTION
 458
 459 Returns true if floating-points are supported and false if not.
 460
 461 =head3 RETURN VALUE
 462
 463 Boolean.
 464
 465 =cut
 466
 467 .sub '_lang_float' :anon
 468     .local pmc res
 469     new res, 'WmlsBoolean'
 470     set res, 1
 471     .return (res)
 472 .end
 473
 474
 475 =head2 C<exit(value)>
 476
 477 =head3 DESCRIPTION
 478
 479 Ends the interpretation of the WMLScript bytecode and returns the control
 480 back to the caller of the WMLScript interpreter with the given return value.
 481 This function can be used to perform a normal exit from a function in cases
 482 where the execution of the WMLScript bytecode should be discontinued.
 483
 484 =head3 PARAMETERS
 485
 486 value = Any
 487
 488 =head3 RETURN VALUE
 489
 490 None (this function ends the interpretation).
 491
 492 =cut
 493
 494 .sub '_lang_exit' :anon
 495     .param pmc value
 496     .local pmc res
 497     $I0 = isa value, 'WmlsString'
 498     unless $I0 goto L1
 499     $P0 = value.'parseInt'()
 500     $I0 = $P0
 501     exit $I0
 502   L1:
 503     $I0 = value
 504     exit $I0
 505 .end
 506
 507
 508 =head2 C<abort(errorDescription)>
 509
 510 =head3 DESCRIPTION
 511
 512 Aborts the interpretation of the WMLScript bytecode and returns the control
 513 back to the caller of the WMLScript interpreter with the return
 514 errorDescription. This function can be used to perform an abnormal exit in
 515 cases where the execution of the WMLScript should be discontinued due to
 516 serious errors detected by the program. If the type of the errorDescription is
 517 invalid, string "invalid" is used as the errorDescription instead.
 518
 519 =head3 PARAMETERS
 520
 521 errorDescription = String
 522
 523 =head3 RETURN VALUE
 524
 525 None (this function aborts the interpretation).
 526
 527 =cut
 528
 529 .sub '_lang_abort' :anon
 530     .param pmc value
 531     die value
 532 .end
 533
 534
 535 =head2 C<random(value)>
 536
 537 =head3 DESCRIPTION
 538
 539 Returns an integer value with positive sign that is greater than or equal to 0
 540 but less than or equal to the given value. The return value is chosen
 541 randomly or pseudo-randomly with approximately uniform distribution over
 542 that range, using an implementation-dependent algorithm or strategy.
 543
 544 If the value is of type floating-point, Float.int() is first used to calculate the
 545 actual integer value.
 546
 547 =head3 PARAMETERS
 548
 549 value = Number
 550
 551 =head3 RETURN VALUE
 552
 553 Integer or invalid.
 554
 555 =head3 EXCEPTIONS
 556
 557 If value is equal to zero (0), the function returns zero.
 558
 559 If value is less than zero (0), the function returns C<invalid>.
 560
 561 =cut
 562
 563 .sub '_lang_random' :anon
 564     .param pmc value
 565     .local pmc res
 566     $P0 = value
 567     $I0 = isa value, 'WmlsString'
 568     unless $I0 goto L1
 569     $P0 = value.'parseNumber'()
 570   L1:
 571     $I0 = isa $P0, 'WmlsInvalid'
 572     if $I0 goto L2
 573     $I0 = $P0
 574     if $I0 < 0 goto L2
 575     new $P0, 'Random'
 576     $N0 = $P0
 577     $N0 = mul $I0
 578     $I0 = $N0
 579     new res, 'WmlsInteger'
 580     set res, $I0
 581     goto L3
 582   L2:
 583     new res, 'WmlsInvalid'
 584   L3:
 585     .return (res)
 586 .end
 587
 588
 589 =head2 C<seed(value)>
 590
 591 =head3 DESCRIPTION
 592
 593 Initialises the pseudo-random number sequence and returns an empty
 594 string. If the value is zero or a positive integer then the given value is used
 595 for initialisation, otherwise a random, system dependent initialisation value
 596 is used. A seed value of greater than or equal to zero results in a repeatable
 597 sequence of pseudo-random numbers. A seed value of less than zero
 598 results in a non-repeatable sequence of random numbers.
 599
 600 If the value is of type floating-point, Float.int() is first used to calculate the
 601 actual integer value. . If the value is non-numeric, invalid is returned and the
 602 current seed is unchanged.
 603
 604 =head3 PARAMETERS
 605
 606 value = Number
 607
 608 =head3 RETURN VALUE
 609
 610 String or invalid.
 611
 612 =cut
 613
 614 .sub '_lang_seed' :anon
 615     .param pmc value
 616     .local pmc res
 617     $P0 = value
 618     $I0 = isa value, 'WmlsString'
 619     unless $I0 goto L1
 620     $P0 = value.'parseNumber'()
 621   L1:
 622     $I0 = isa $P0, 'WmlsInvalid'
 623     if $I0 goto L2
 624     $I0 = $P0
 625     if $I0 >= 0 goto L3
 626     $I0 = time
 627   L3:
 628     new $P0, 'Random'
 629     $P0 = $I0
 630     new res, 'WmlsString'
 631     set res, ''
 632     goto L4
 633   L2:
 634     new res, 'WmlsInvalid'
 635   L4:
 636     .return (res)
 637 .end
 638
 639
 640 =head2 C<characterSet()>
 641
 642 =head3 DESCRIPTION
 643
 644 Returns the character set supported by the WMLScript Interpreter. The
 645 return value is an integer that denotes a MIBEnum value assigned by the
 646 IANA for all character sets (see [WSP] for more information).
 647
 648 =head3 RETURN VALUE
 649
 650 Integer.
 651
 652 =cut
 653
 654 .sub '_lang_characterSet' :anon
 655     .local pmc res
 656     new res, 'WmlsInteger'
 657     res = 4     # latin1
 658     .return (res)
 659 .end
 660
 661
 662 =head1 AUTHORS
 663
 664 Francois Perrad.
 665
 666 =cut
 667
 668
 669 # Local Variables:
 670 #   mode: pir
 671 #   fill-column: 100
 672 # End:
 673 # vim: expandtab shiftwidth=4 ft=pir: