examples/sdl/bounce_parrot_logo.pir

   1 # $Id$
   2
   3 =head1 TITLE
   4
   5 bounce_parrot_logo.pir - bounce a Parrot logo with the SDL Parrot bindings
   6
   7 =head1 SYNOPSIS
   8
   9 To run this file, run the following command from the Parrot directory:
  10
  11     $ parrot examples/sdl/bounce_parrot_logo.pir
  12     $
  13
  14 You'll see the happy Parrot logo in the middle of a new SDL window.  Use the
  15 cursor keys to apply velocity in the appropriate directions.  Watch it bounce!
  16 Use the Escape key or close the window when you've had enough.
  17
  18 =cut
  19
  20 .sub _main :main
  21     load_bytecode "SDL/App.pir"
  22     load_bytecode "SDL/Color.pir"
  23     load_bytecode "SDL/Rect.pir"
  24     load_bytecode "SDL/Image.pir"
  25     load_bytecode "SDL/Sprite.pir"
  26     load_bytecode "SDL/EventHandler.pir"
  27     load_bytecode "SDL/Event.pir"
  28
  29     .local pmc app
  30     app = new ['SDL'; 'App']
  31     app.'init'( 'width' => 640, 'height' => 480, 'bpp' => 0, 'flags' => 0 )
  32
  33     .local pmc main_screen
  34     main_screen = app.'surface'()
  35
  36     .local pmc black
  37     black = new ['SDL'; 'Color']
  38     black.'init'( 'r' => 0, 'g' => 0, 'b' => 0 )
  39
  40     .local pmc image
  41     image = new ['SDL'; 'Image']
  42     image.'init'( 'examples/sdl/parrot_small.png' )
  43
  44     .local pmc sprite
  45     sprite = new ['SDL'; 'Sprite']
  46     sprite.'init'( 'surface' => image, 'source_x' => 0, 'source_y' => 0, 'dest_x' => 270, 'dest_y' => 212, 'bgcolor' => black )
  47
  48     _main_loop( main_screen, sprite )
  49     end
  50 .end
  51
  52 .sub _main_loop
  53     .param pmc main_screen
  54     .param pmc sprite
  55
  56     .local pmc parent_class
  57     .local pmc class_type
  58     get_class parent_class, ['SDL'; 'EventHandler']
  59     subclass class_type, parent_class, 'MoveLogo::EventHandler'
  60
  61     .local pmc event_handler
  62     event_handler = new 'MoveLogo::EventHandler'
  63
  64     .local pmc event
  65     event = new ['SDL'; 'Event']
  66     event.'init'()
  67
  68     .local pmc handler_args
  69     handler_args = new 'Hash'
  70     handler_args[ 'screen' ] = main_screen
  71     handler_args[ 'sprite' ] = sprite
  72
  73     .local num last_time
  74     last_time = time
  75
  76     .local num counter
  77     counter = 0
  78
  79     .local num current_time
  80     current_time = 0
  81
  82     .local int frame_count
  83     frame_count = 1
  84
  85     .local int updated
  86     event_handler.'draw_screen'( main_screen, sprite )
  87
  88 loop:
  89     last_time = current_time
  90     updated   = event_handler.'update_position'( sprite, frame_count )
  91
  92     if updated == 0 goto increase_count
  93
  94     event_handler.'draw_screen'( main_screen, sprite )
  95
  96 increase_count:
  97     inc frame_count
  98     if  frame_count < 6 goto get_event
  99     frame_count = 0
 100
 101 get_event:
 102     event.'handle_event'( event_handler, handler_args )
 103
 104     current_time = time
 105     counter      = current_time - last_time
 106
 107     if counter < 0.016 goto get_event
 108     goto loop
 109
 110 .end
 111
 112 .namespace [ 'MoveLogo::EventHandler' ]
 113
 114 .sub update_position :method
 115     .param pmc sprite
 116     .param int frame_count
 117
 118     .local int updated
 119     updated = 0
 120
 121     .local int x_velocity
 122     .local int y_velocity
 123
 124     x_velocity = sprite.'x_velocity'()
 125     y_velocity = sprite.'y_velocity'()
 126
 127     .local int abs_velocity
 128     .local int delta
 129
 130 check_x_update:
 131     if x_velocity == 0 goto check_y_update
 132
 133     abs abs_velocity, x_velocity
 134     set delta, frame_count
 135     sub delta, abs_velocity
 136
 137     if delta        > 0 goto check_y_update
 138
 139     updated = 1
 140
 141     if x_velocity   < 0 goto neg_x_dir
 142
 143     self.'move_sprite_x'( sprite,  1 )
 144     goto check_y_update
 145
 146 neg_x_dir:
 147     self.'move_sprite_x'( sprite, -1 )
 148
 149 check_y_update:
 150     if y_velocity == 0 goto return
 151
 152     abs abs_velocity, y_velocity
 153     set delta, frame_count
 154     sub delta, abs_velocity
 155
 156     if delta      > 0 goto return
 157
 158     updated = 1
 159
 160     if y_velocity < 0 goto neg_y_dir
 161
 162     self.'move_sprite_y'( sprite,  1 )
 163     goto return
 164
 165 neg_y_dir:
 166     self.'move_sprite_y'( sprite, -1 )
 167
 168 return:
 169     .return( updated )
 170 .end
 171
 172 .sub draw_screen :method
 173     .param pmc screen
 174     .param pmc sprite
 175
 176     .local pmc prev_rect
 177     .local pmc rect
 178     .local pmc rect_array
 179     rect_array = new 'ResizablePMCArray'
 180     set rect_array, 2
 181
 182     (prev_rect, rect) = sprite.'draw_undraw'( screen )
 183     set rect_array[ 0 ], prev_rect
 184     set rect_array[ 1 ], rect
 185
 186     screen.'update_rects'( rect_array )
 187 #    screen.'update_rect'( rect )
 188
 189 .end
 190
 191 .sub move_sprite_x :method
 192     .param pmc sprite
 193     .param int direction
 194
 195     .local int x
 196     x = sprite.'x'()
 197
 198     add x, direction
 199
 200     if x >= 0 goto check_x_max
 201     x = 0
 202     goto x_bounce
 203
 204 check_x_max:
 205     if x < 540 goto x_update
 206     x = 540
 207
 208 x_bounce:
 209     .local int x_velocity
 210     x_velocity = sprite.'x_velocity'()
 211     x_velocity = -x_velocity
 212     sprite.'x_velocity'( x_velocity )
 213
 214 x_update:
 215     sprite.'x'( x )
 216
 217 .end
 218
 219 .sub move_sprite_y :method
 220     .param pmc sprite
 221     .param int direction
 222
 223     .local int y
 224     y = sprite.'y'()
 225
 226     add y, direction
 227
 228     if y >= 0 goto check_y_max
 229     y = 0
 230     goto y_bounce
 231
 232 check_y_max:
 233     if y < 424 goto y_update
 234     y = 424
 235
 236 y_bounce:
 237     .local int y_velocity
 238     y_velocity = sprite.'y_velocity'()
 239     y_velocity = -y_velocity
 240     sprite.'y_velocity'( y_velocity )
 241
 242 y_update:
 243     sprite.'y'( y )
 244
 245 .end
 246
 247 .sub key_down_down :method
 248     .param pmc event_args
 249
 250     .local pmc screen
 251     .local pmc sprite
 252
 253     screen = event_args[ 'screen' ]
 254     sprite = event_args[ 'sprite' ]
 255
 256     .local int y_vel
 257     y_vel = sprite.'y_velocity'()
 258
 259     if  y_vel == 5 goto return
 260     inc y_vel
 261
 262     sprite.'y_velocity'( y_vel )
 263
 264 return:
 265
 266 .end
 267
 268 .sub key_down_up :method
 269     .param pmc event_args
 270
 271     .local pmc screen
 272     .local pmc sprite
 273
 274     screen = event_args[ 'screen' ]
 275     sprite = event_args[ 'sprite' ]
 276
 277     .local int y_vel
 278     y_vel = sprite.'y_velocity'()
 279
 280     if  y_vel == -5 goto return
 281     dec y_vel
 282
 283     sprite.'y_velocity'( y_vel )
 284
 285 return:
 286
 287 .end
 288
 289 .sub key_down_left :method
 290     .param pmc event_args
 291
 292     .local pmc screen
 293     .local pmc sprite
 294
 295     screen = event_args[ 'screen' ]
 296     sprite = event_args[ 'sprite' ]
 297
 298     .local int x_vel
 299     x_vel = sprite.'x_velocity'()
 300
 301     if  x_vel == -5 goto return
 302     dec x_vel
 303
 304     sprite.'x_velocity'( x_vel )
 305
 306 return:
 307
 308 .end
 309
 310 .sub key_down_right :method
 311     .param pmc event_args
 312
 313     .local pmc screen
 314     .local pmc sprite
 315
 316     screen = event_args[ 'screen' ]
 317     sprite = event_args[ 'sprite' ]
 318
 319     .local int x_vel
 320     x_vel = sprite.'x_velocity'()
 321
 322     if  x_vel == 5 goto return
 323     inc x_vel
 324
 325     sprite.'x_velocity'( x_vel )
 326
 327 return:
 328
 329 .end
 330
 331 .sub key_down_escape :method
 332     .param pmc event_args
 333
 334     # XXX: a silly way to quit
 335     end
 336 .end
 337
 338 =head1 AUTHOR
 339
 340 chromatic, E<lt>chromatic at wgz dot orgE<gt>.
 341
 342 =head1 COPYRIGHT
 343
 344 Copyright (C) 2004-2008, Parrot Foundation.
 345
 346 =cut
 347
 348 # Local Variables:
 349 #   mode: pir
 350 #   fill-column: 100
 351 # End:
 352 # vim: expandtab shiftwidth=4 ft=pir: