t/harness

   1 #!perl
   2 # Copyright (C) 2001-2008, The Perl Foundation.
   3 # $Id$
   4
   5 use strict;
   6 use warnings;
   7 use lib qw( lib );
   8
   9 use Getopt::Std;
  10
  11 # need runtests from T::H, but avoid running all our parrot invocations with -w
  12 use Test::Harness ();
  13 undef $Test::Harness::Switches;
  14
  15 use Parrot::Harness::DefaultTests qw(
  16     get_default_tests
  17     @developing_tests
  18 );
  19 use Parrot::Harness::Options qw(
  20     handle_long_options
  21     get_test_prog_args
  22     Usage
  23 );
  24 use Parrot::Harness::Smoke qw(
  25     generate_html_smoke_report
  26     send_archive_to_smolder
  27 );
  28
  29 local @ARGV = @ARGV;
  30 (my $longopts, @ARGV) = handle_long_options(@ARGV);
  31
  32 $ENV{RUNNING_MAKE_TEST} = $longopts->{running_make_test};
  33
  34 # Suck the short options into the TEST_PROG_ARGS
  35 # environmental variable.
  36 my %opts;
  37 getopts('wgjPCSefbvdr?hO:D:', \%opts);
  38
  39 if ($opts{'?'} || $opts{h} || $longopts->{help}) {
  40     Usage();
  41     exit;
  42 }
  43
  44 # add -D40;  merge it with any existing -D argument
  45 $opts{D} = sprintf( '%x', hex(40) | (exists $opts{D} ? hex($opts{D}) : 0));
  46
  47 my $args = get_test_prog_args(
  48     \%opts, $longopts->{gc_debug}, $longopts->{run_exec}
  49 );
  50 $ENV{TEST_PROG_ARGS} = $args;
  51
  52 # now build the list of tests to run, either from the command
  53 # line or from @default tests
  54 my @default_tests = get_default_tests(
  55     $longopts->{core_tests_only},
  56     $longopts->{runcore_tests_only}
  57 );
  58
  59 my @tests;
  60 if ($longopts->{code}) {
  61     @tests = @developing_tests;
  62 } else {
  63     @tests = map { glob($_) } (@ARGV ? @ARGV : @default_tests);
  64 }
  65
  66 if ($longopts->{html}) {
  67     generate_html_smoke_report(
  68         {
  69             tests => \@tests,
  70             args  => $args,
  71             file  => 'smoke.html',
  72         }
  73     );
  74 } else {
  75     my $harness;
  76     if ($longopts->{archive}) {
  77         eval { require TAP::Harness::Archive };
  78         if ($@) {
  79             die "\n" . ('-' x 55) . "\nCould not load TAP::Harness::Archive."
  80                 . "\nPlease install it if you want to create TAP archives.\n"
  81                 . ('-' x 55) . "\n\n$@\n";
  82         }
  83         $harness = TAP::Harness::Archive->new(
  84             {
  85                 verbosity => $ENV{HARNESS_VERBOSE},
  86                 archive   => 'parrot_test_run.tar.gz',
  87                 merge     => 1,
  88             }
  89         );
  90     } else {
  91         eval { require TAP::Harness };
  92         if ($@) {
  93             Test::Harness::runtests(@tests);
  94             exit;
  95         }
  96         else {
  97             $harness = TAP::Harness->new({
  98                 verbosity => $ENV{HARNESS_VERBOSE}, merge => 0
  99             });
 100         }
 101     }
 102
 103     $harness->runtests(@tests);
 104
 105     if ($longopts->{send_to_smolder}) {
 106         send_archive_to_smolder();
 107     }
 108 }
 109
 110 =head1 NAME
 111
 112 t/harness - Parrot Test Harness
 113
 114 =head1 SYNOPSIS
 115
 116     % perl t/harness [options] [testfiles]
 117
 118 =head1 DESCRIPTION
 119
 120 The short command line options are:
 121
 122 =over 4
 123
 124 =item C<-w>
 125
 126 Turn warnings on.
 127
 128 =item C<-g>
 129
 130 Run the C<CGoto> core.
 131
 132 =item C<-j>
 133
 134 Run with JIT enabled.
 135
 136 =item C<-C>
 137
 138 Run the C<CGP> core.
 139
 140 =item C<-S>
 141
 142 Run Switched.
 143
 144 =item C<-b>
 145
 146 Run bounds checking enabled.
 147
 148 =item C<-d>
 149
 150 Run with debugging enabled.
 151
 152 =item C<-f>
 153
 154 Run fast core.
 155
 156 =item C<-r>
 157
 158 compile to Parrot bytecode and then run the bytecode.
 159
 160 =item C<-O[012]>
 161
 162 Run optimized to the specified level.
 163
 164 =item C<-D[number]>
 165
 166 Pass the specified debug bits to the parrot interpreter.  Note that
 167 C<-D40> (fill I, N registers with garbage) is always enabled.
 168 See 'parrot --help-debug' for available flags.
 169
 170 =back
 171
 172 There are also long command line options:
 173
 174 =over 4
 175
 176 =item C<--running-make-test>
 177
 178 Some test scripts run more quickly when this is set.
 179
 180 =item C<--gc-debug>
 181
 182 Invoke parrot with '--gc-debug'.
 183
 184 =item C<--html>
 185
 186 Emit a C<smoke.html> file instead of displaying results.
 187
 188 =item C<--code-tests>
 189
 190 Run only the file metadata and basic coding standards tests.
 191
 192 =back
 193
 194 =head1 HISTORY
 195
 196 Mike Lambert stole F<t/harness> for F<languages/perl6/t/harness>.
 197
 198 Leo Toetsch stole F<languages/perl6/t/harness> for F<imcc/t/harness>.
 199
 200 Bernhard Schmalhofer merged F<imcc/t/harness> back into F<t/harness>.
 201
 202 =cut
 203
 204
 205 # Local Variables:
 206 #   mode: cperl
 207 #   cperl-indent-level: 4
 208 #   fill-column: 100
 209 # End:
 210 # vim: expandtab shiftwidth=4: