editor/indent_pir.vim

   1 " Description:  PIR indenter
   2 " Author:   Andrew Rodland <arodland@entermail.net>
   3 " Maintainer: Jimmy Zhuo <zhuomingliang@yahoo.com.cn>
   4 " Last Change: 2009 Jan 16
   5
   6 " As usual, we want to be alone
   7 if exists("b:did_indent")
   8     finish
   9 endif
  10 let b:did_indent=1
  11
  12 setlocal indentexpr=PIRIndent()
  13 setlocal indentkeys=o,O,*<Return>,<bs>,:,=.end,0#
  14
  15 fun! InPOD(lnum)
  16     return synIDattr(synID(a:lnum, 1, 1), "name") =~? '^myPod$\|^pod[A-Z]'
  17 endfun
  18
  19 fun! PIRIndent()
  20     let thisline = getline(v:lnum)
  21
  22     let POD_START = '^=[a-z]'
  23
  24     if thisline =~? POD_START
  25         return 0
  26     endif
  27
  28
  29     if InPOD(v:lnum)
  30         return -1
  31     endif
  32
  33     let COMMENT = '^#'
  34     if thisline =~? COMMENT
  35         return 0
  36     endif
  37
  38     let lnum=v:lnum
  39     while lnum > 0
  40         let lnum = prevnonblank(lnum-1)
  41         let prevline = getline(lnum)
  42
  43         if prevline !~? COMMENT
  44             if !InPOD(lnum)
  45                 break
  46             endif
  47         endif
  48     endwhile
  49
  50     if lnum < 1
  51         return 0
  52     endif
  53
  54     let ind = indent(lnum)
  55
  56     let SUB = '^\s*\.pcc_sub\s\+\|^\s*\.sub\s\+\|^\s*\.macro\s\+'
  57     let RETURNBLOCK = '\s*\.begin_return\s*$'
  58     let END = '^\s*\.end\s*$\|^\s*\.end_return\s*\|^\s*\.endm$'
  59     let LABEL = '^\s*\k\+:'
  60
  61     if prevline =~? SUB
  62         let ind = ind + &sw
  63     endif
  64
  65     if prevline =~? RETURNBLOCK
  66         let ind = ind + &sw
  67     endif
  68
  69     if prevline =~? LABEL
  70         let ind = ind + 2
  71     endif
  72
  73     if thisline =~? END
  74         let ind = ind - &sw
  75     endif
  76
  77     if thisline =~? LABEL
  78         let ind = ind - 2
  79     endif
  80
  81     return ind
  82
  83 endfun
  84
  85