configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [5])
  45 m4_define([lib_revision], [1])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [4])
  50 m4_define([pacman_version_micro], [1])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for buildscript filename
  87 AC_ARG_WITH(buildscript,
  88         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  89         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  90
  91 # Help line for using OpenSSL
  92 AC_ARG_WITH(openssl,
  93         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  94         [], [with_openssl=check])
  95
  96 # Help line for libfetch
  97 AC_ARG_WITH(fetch,
  98         AS_HELP_STRING([--with-fetch], [use libfetch as an internal downloader]),
  99         [], [with_fetch=check])
 100
 101 # Help line for documentation
 102 AC_ARG_ENABLE(doc,
 103         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 104         [wantdoc=$enableval], [wantdoc=yes])
 105
 106 # Help line for doxygen
 107 AC_ARG_ENABLE(doxygen,
 108         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 109         [wantdoxygen=$enableval], [wantdoxygen=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Checks for programs.
 123 AC_PROG_AWK
 124 AC_PROG_CC_C99
 125 AC_PROG_INSTALL
 126 AC_PROG_LN_S
 127 AC_PROG_MAKE_SET
 128 AC_PROG_LIBTOOL
 129 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 130 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 131
 132 # find installed gettext
 133 AM_GNU_GETTEXT([external])
 134 AM_GNU_GETTEXT_VERSION(0.13.1)
 135
 136 # Check for libarchive
 137 AC_CHECK_LIB([archive], [archive_read_data], ,
 138         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 139
 140 # Check for OpenSSL
 141 AC_MSG_CHECKING(whether to link with libssl)
 142 AS_IF([test "x$with_openssl" != "xno"],
 143         [AC_MSG_RESULT(yes)
 144         AC_CHECK_LIB([ssl], [MD5_Final], ,
 145         [if test "x$with_openssl" != "xcheck"; then
 146                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 147         fi],
 148         [-lcrypto])],
 149         AC_MSG_RESULT(no))
 150 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$ac_cv_lib_ssl_MD5_Final" = "xyes"])
 151
 152 # Enable or disable usage of libfetch
 153 AC_MSG_CHECKING(whether to link with libfetch)
 154 AS_IF([test "x$with_fetch" != "xno"],
 155         [AC_MSG_RESULT(yes)
 156         AC_CHECK_LIB([fetch], [fetchParseURL], ,
 157         [if test "x$with_fetch" != "xcheck"; then
 158                 AC_MSG_FAILURE([--with-fetch was given, but -lfetch was not found])
 159         fi],
 160         [-lcrypto -ldl])
 161         # Check if libfetch supports connnection caching which we use
 162         AS_IF([test "x$ac_cv_lib_fetch_fetchParseURL" = "xyes"],
 163         [AC_CHECK_DECL(fetchConnectionCacheInit, ,
 164                 AC_MSG_ERROR([libfetch must be version 2.28 or greater]),
 165                 [#include <fetch.h>])
 166         ])
 167         ],
 168         AC_MSG_RESULT(no))
 169 AM_CONDITIONAL([HAVE_LIBFETCH], [test "x$ac_cv_lib_fetch_fetchParseURL" = "xyes"])
 170
 171 # Checks for header files.
 172 AC_CHECK_HEADERS([fcntl.h glob.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/param.h sys/statvfs.h sys/syslimits.h sys/time.h syslog.h wchar.h])
 173
 174 # Checks for typedefs, structures, and compiler characteristics.
 175 AC_C_INLINE
 176 AC_TYPE_MODE_T
 177 AC_TYPE_OFF_T
 178 AC_TYPE_PID_T
 179 AC_TYPE_SIZE_T
 180 AC_STRUCT_TM
 181 AC_TYPE_UID_T
 182 AC_STRUCT_DIRENT_D_TYPE
 183
 184 # Checks for library functions.
 185 AC_FUNC_FORK
 186 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 187 AC_FUNC_MKTIME
 188 AC_TYPE_SIGNAL
 189 AC_CHECK_FUNCS([geteuid realpath regcomp strcasecmp \
 190                 strndup strrchr strsep swprintf \
 191                 wcwidth uname])
 192
 193 # Enable large file support if available
 194 AC_SYS_LARGEFILE
 195
 196 # Check if we can use symbol visibility support in GCC
 197 GCC_VISIBILITY_CC
 198 # Check if we have -fgnu89-inline flag
 199 GCC_GNU89_INLINE_CC
 200
 201 # Host-dependant definitions
 202 SIZECMD="stat -L -c %s"
 203 SEDINPLACE="sed -i"
 204 STRIP_BINARIES="--strip-all"
 205 STRIP_SHARED="--strip-unneeded"
 206 STRIP_STATIC="--strip-debug"
 207 case "${host_os}" in
 208         *bsd*)
 209                 SIZECMD="stat -L -f %z"
 210                 SEDINPLACE="sed -i ''"
 211                 ;;
 212         cygwin*)
 213                 host_os_cygwin=yes
 214                 CFLAGS="$CFLAGS -DCYGWIN"
 215                 ;;
 216         darwin*)
 217                 host_os_darwin=yes
 218                 SIZECMD="/usr/bin/stat -L -f %z"
 219                 SEDINPLACE="/usr/bin/sed -i ''"
 220                 STRIP_BINARIES=""
 221                 STRIP_SHARED="-S"
 222                 STRIP_STATIC="-S"
 223                 ;;
 224 esac
 225
 226 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 227 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 228 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 229 AC_SUBST(SIZECMD)
 230 AC_SUBST(SEDINPLACE)
 231 AC_SUBST(STRIP_BINARIES)
 232 AC_SUBST(STRIP_SHARED)
 233 AC_SUBST(STRIP_STATIC)
 234
 235 # Check for architecture, used in default makepkg.conf
 236 # (Note single space left after CARCHFLAGS)
 237 case "${host}" in
 238         i686-*)
 239                 CARCH="i686"
 240                 CARCHFLAGS="-march=i686 "
 241                 ;;
 242         x86_64-*)
 243                 CARCH="x86_64"
 244                 CARCHFLAGS="-march=x86-64 "
 245                 ;;
 246         ia64-*)
 247                 CARCH="ia64"
 248                 CARCHFLAGS="-march=ia64 "
 249                 ;;
 250         sparc-*)
 251                 CARCH="sparc"
 252                 CARCHFLAGS="-mcpu=v9 "
 253                 ;;
 254         ppc-* | powerpc-*)
 255                 CARCH="ppc"
 256                 CARCHFLAGS="-mcpu=750 "
 257                 ;;
 258         i386-*)
 259                 CARCH="i386"
 260                 CARCHFLAGS="-march=i386 "
 261                 ;;
 262         arm-*)
 263                 CARCH="arm"
 264                 CARCHFLAGS="-march=armv4 "
 265                 ;;
 266         *)
 267                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 268                 CARCH="unknown"
 269                 CARCHFLAGS=""
 270                 ;;
 271 esac
 272
 273 # Now do some things common to all architectures
 274 CHOST="${host}"
 275 AC_SUBST(CARCH)
 276 AC_SUBST(CARCHFLAGS)
 277 AC_SUBST(CHOST)
 278
 279 # Check for documentation support and status
 280 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 281 AC_MSG_CHECKING([for building documentation])
 282 if test "x$wantdoc" = "xyes" ; then
 283         if test $ASCIIDOC ; then
 284                 AC_MSG_RESULT([yes, enabled by configure])
 285         else
 286                 asciidoc="(warning : asciidoc not installed)"
 287                 AC_MSG_RESULT([yes $asciidoc])
 288         fi
 289         wantdoc=yes
 290 else
 291         AC_MSG_RESULT([no, disabled by configure])
 292         wantdoc=no
 293 fi
 294 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 295
 296 # Check for doxygen support and status
 297 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 298 AC_MSG_CHECKING([for doxygen])
 299 if test "x$wantdoxygen" = "xyes" ; then
 300         if test $DOXYGEN ; then
 301                 AC_MSG_RESULT([yes])
 302                 usedoxygen=yes
 303         else
 304                 AC_MSG_RESULT([no, doxygen missing])
 305                 usedoxygen=no
 306         fi
 307 else
 308         AC_MSG_RESULT([no, disabled by configure])
 309         usedoxygen=no
 310 fi
 311 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 312
 313 # Enable or disable debug code
 314 AC_MSG_CHECKING(for debug mode request)
 315 if test "x$debug" = "xyes" ; then
 316         AC_MSG_RESULT(yes)
 317         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 318         # Check for mcheck
 319         AC_CHECK_HEADERS([mcheck.h])
 320         # Check for -fstack-protector availability
 321         GCC_STACK_PROTECT_LIB
 322         GCC_STACK_PROTECT_CC
 323         GCC_FORTIFY_SOURCE_CC
 324         CFLAGS="$CFLAGS -g -Wall -Werror"
 325 else
 326         AC_MSG_RESULT(no)
 327         CFLAGS="$CFLAGS -Wall"
 328 fi
 329
 330 # Enable or disable use of git version in pacman version string
 331 AC_MSG_CHECKING(whether to use git version if available)
 332 if test "x$wantgitver" = "xyes" ; then
 333         AC_CHECK_PROGS([GIT], [git])
 334         AC_CHECK_FILE([.git/], hasgitdir=yes)
 335         if test $GIT -a "x$hasgitdir" = "xyes"; then
 336                 AC_MSG_RESULT([yes])
 337                 usegitver=yes
 338                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 339         else
 340                 AC_MSG_RESULT([no, git or .git dir missing])
 341                 usegitver=no
 342         fi
 343 else
 344         AC_MSG_RESULT([no, disabled by configure])
 345         usegitver=no
 346 fi
 347 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 348
 349 # Set root directory
 350 AC_SUBST(ROOTDIR)
 351 # Set package file extension
 352 AC_SUBST(PKGEXT)
 353 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 354 # Set source package file extension
 355 AC_SUBST(SRCEXT)
 356 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 357 # Set makepkg build script name
 358 AC_SUBST(BUILDSCRIPT)
 359 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 360
 361 # Configuration files
 362 AC_CONFIG_FILES([
 363 lib/libalpm/Makefile
 364 lib/libalpm/po/Makefile.in
 365 src/pacman/Makefile
 366 src/util/Makefile
 367 scripts/Makefile
 368 doc/Makefile
 369 etc/Makefile
 370 po/Makefile.in
 371 test/pacman/Makefile
 372 test/pacman/tests/Makefile
 373 test/util/Makefile
 374 contrib/Makefile
 375 Makefile
 376 ])
 377 AC_OUTPUT
 378
 379 echo "
 380 ${PACKAGE_NAME}:
 381
 382   Build information:
 383     source code location   : ${srcdir}
 384     prefix                 : ${prefix}
 385     sysconfdir             : $(eval echo ${sysconfdir})
 386        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 387     localstatedir          : $(eval echo ${localstatedir})
 388        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 389        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 390     compiler               : ${CC}
 391     compiler flags         : ${CFLAGS}
 392     defines                : ${DEFS}
 393
 394     Architecture           : ${CARCH}
 395     Architecture flags     : ${CARCHFLAGS}
 396     Host Type              : ${CHOST}
 397     Filesize command       : ${SIZECMD}
 398     In-place sed command   : ${SEDINPLACE}
 399
 400     libalpm version        : ${LIB_VERSION}
 401     libalpm version info   : ${LIB_VERSION_INFO}
 402     pacman version         : ${PACKAGE_VERSION}
 403     using git version      : ${usegitver}
 404
 405   Directory and file information:
 406     root working directory : ${ROOTDIR}
 407     package extension      : ${PKGEXT}
 408     source pkg extension   : ${SRCEXT}
 409     build script name      : ${BUILDSCRIPT}
 410
 411   Compilation options:
 412     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 413     Doxygen support        : ${usedoxygen}
 414     debug support          : ${debug}
 415 "
 416
 417 # vim:set ts=2 sw=2 noet: