configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.60)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43 #
  44 #   pacman_version_suffix should be similar to one of the following:
  45 #     For beta releases:          [beta2]
  46 #     For code under development: [devel]
  47 #     For production releases:    []
  48
  49 m4_define([lib_current], [5])
  50 m4_define([lib_revision], [1])
  51 m4_define([lib_age], [3])
  52
  53 m4_define([pacman_version_major], [3])
  54 m4_define([pacman_version_minor], [2])
  55 m4_define([pacman_version_micro], [0])
  56 m4_define([pacman_version_suffix], [devel])
  57 m4_define([pacman_version],
  58           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  59 m4_define([pacman_display_version],
  60                                         pacman_version[]m4_ifdef([pacman_version_suffix],[pacman_version_suffix]))
  61
  62 # Autoconf initialization
  63 AC_INIT([Pacman Package Manager], [pacman_display_version],
  64         [pacman-dev@archlinux.org], [pacman])
  65 AC_CONFIG_SRCDIR([config.h.in])
  66 AC_CONFIG_HEADERS([config.h])
  67
  68 AC_CANONICAL_HOST
  69 AM_INIT_AUTOMAKE
  70
  71 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  72 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  73
  74 # Set subsitution values for version stuff in Makefiles and anywhere else,
  75 # and put LIB_VERSION in config.h
  76 AC_SUBST(LIB_VERSION)
  77 AC_SUBST(LIB_VERSION_INFO)
  78 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  79
  80 # Help line for root directory
  81 AC_ARG_WITH(root-dir,
  82         AS_HELP_STRING([--with-root-dir=path], [set the location of pacman's root operating directory]),
  83         [ROOTDIR=$withval], [ROOTDIR=/])
  84
  85 # Help line for package extension
  86 AC_ARG_WITH(pkg-ext,
  87         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  88         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  89
  90 # Help line for source package directory
  91 AC_ARG_WITH(src-ext,
  92         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  93         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  94
  95 # Help line for database extension
  96 AC_ARG_WITH(db-ext,
  97         AS_HELP_STRING([--with-db-ext=ext], [set the file extension used by the database]),
  98         [DBEXT=$withval], [DBEXT=.db.tar.gz])
  99
 100 # Help line for libdownload/libfetch
 101 AC_ARG_ENABLE(internal-download,
 102         AS_HELP_STRING([--disable-internal-download], [do not build with libdownload/libfetch support]),
 103         [internaldownload=$enableval], [internaldownload=yes])
 104
 105 # Help line for documentation
 106 AC_ARG_ENABLE(doc,
 107         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 108         [wantdoc=$enableval], [wantdoc=yes])
 109
 110 # Help line for doxygen
 111 AC_ARG_ENABLE(doxygen,
 112         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 113         [wantdoxygen=$enableval], [wantdoxygen=no])
 114
 115 # Help line for asciidoc
 116 AC_ARG_ENABLE(asciidoc,
 117         AS_HELP_STRING([--enable-asciidoc], [build your own manpages with Asciidoc]),
 118         [wantasciidoc=$enableval], [wantasciidoc=no])
 119
 120 # Help line for debug
 121 AC_ARG_ENABLE(debug,
 122         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 123         [debug=$enableval], [debug=no])
 124
 125 # Help line for pacman.static
 126 AC_ARG_ENABLE(pacman-static,
 127         AS_HELP_STRING([--disable-pacman-static], [do not build static version of pacman]),
 128         [pacmanstatic=$enableval], [pacmanstatic=yes])
 129
 130 # Checks for programs.
 131 AC_PROG_AWK
 132 AC_PROG_CC_C99
 133 AC_PROG_INSTALL
 134 AC_PROG_LN_S
 135 AC_PROG_MAKE_SET
 136 AC_PROG_LIBTOOL
 137 AC_CHECK_PROGS([PYTHON], [python2.5 python2.4 python], [false])
 138
 139 # find installed gettext
 140 AM_GNU_GETTEXT([external])
 141 AM_GNU_GETTEXT_VERSION(0.13.1)
 142
 143 # Check for libarchive
 144 AC_CHECK_LIB([archive], [archive_read_data], ,
 145         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 146
 147 # Enable or disable usage of libdownload/libfetch
 148 AC_MSG_CHECKING(whether to link with download library)
 149 if test "x$internaldownload" = "xyes" ; then
 150         AC_MSG_RESULT(yes)
 151         AC_DEFINE([INTERNAL_DOWNLOAD], , [Use internal download library])
 152         # Check for libdownload if it was actually requested
 153         AC_CHECK_LIB([download], [downloadParseURL], ,
 154                 AC_MSG_ERROR([libdownload is needed to compile pacman!]))
 155 else
 156         AC_MSG_RESULT(no)
 157 fi
 158 AM_CONDITIONAL(INTERNAL_DOWNLOAD, test "x$internaldownload" = "xyes")
 159
 160 # Checks for header files.
 161 AC_CHECK_HEADERS([fcntl.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/statvfs.h sys/time.h syslog.h wchar.h])
 162
 163 # Checks for typedefs, structures, and compiler characteristics.
 164 AC_C_INLINE
 165 AC_TYPE_MODE_T
 166 AC_TYPE_OFF_T
 167 AC_TYPE_PID_T
 168 AC_TYPE_SIZE_T
 169 AC_STRUCT_TM
 170 AC_TYPE_UID_T
 171
 172 # Checks for library functions.
 173 AC_FUNC_FORK
 174 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 175 AC_FUNC_MKTIME
 176 AC_TYPE_SIGNAL
 177 AC_CHECK_FUNCS([geteuid realpath regcomp strcasecmp \
 178                 strndup strrchr strsep strverscmp swprintf \
 179                 wcwidth uname])
 180
 181 # Enable large file support if available
 182 AC_SYS_LARGEFILE
 183
 184 # Check if we can use symbol visibility support in GCC
 185 GCC_VISIBILITY_CC
 186 # Check if we have -fgnu89-inline flag
 187 GCC_GNU89_INLINE_CC
 188
 189 # Host-dependant flags
 190 case "${host}" in
 191         *-*-cygwin*)
 192                 CFLAGS="$CFLAGS -DCYGWIN"
 193                 ;;
 194 esac
 195
 196 # Check for architecture, used in default makepkg.conf
 197 # (Note single space left after CARCHFLAGS)
 198 case "${host}" in
 199         i686-*)
 200                 CARCH="i686"
 201                 CARCHFLAGS="-march=i686 "
 202                 ;;
 203         x86_64-*)
 204                 CARCH="x86_64"
 205                 CARCHFLAGS="-march=x86-64 "
 206                 ;;
 207         ia64-*)
 208                 CARCH="ia64"
 209                 CARCHFLAGS="-march=ia64 "
 210                 ;;
 211         sparc-*)
 212                 CARCH="sparc"
 213                 CARCHFLAGS="-mcpu=v9 "
 214                 ;;
 215         ppc-* | powerpc-*)
 216                 CARCH="ppc"
 217                 CARCHFLAGS="-mcpu=750 "
 218                 ;;
 219         i386-*)
 220                 CARCH="i386"
 221                 CARCHFLAGS="-march=i386 "
 222                 ;;
 223         arm-*)
 224                 CARCH="arm"
 225                 CARCHFLAGS="-march=armv4 "
 226                 ;;
 227         *)
 228                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 229                 CARCH="unknown"
 230                 CARCHFLAGS=""
 231                 ;;
 232 esac
 233
 234 # Now do some things common to all architectures
 235 CHOST="${host}"
 236 AC_SUBST(CARCH)
 237 AC_SUBST(CARCHFLAGS)
 238 AC_SUBST(CHOST)
 239
 240 # Check for documentation support and status
 241 AC_MSG_CHECKING([for building documentation])
 242 if test "x$wantdoc" = "xyes" ; then
 243         AC_MSG_RESULT([yes])
 244         wantdoc=yes
 245 else
 246         AC_MSG_RESULT([no, disabled by configure])
 247         wantdoc=no
 248 fi
 249 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 250
 251 # Check for doxygen support and status
 252 AC_MSG_CHECKING([for doxygen])
 253 if test "x$wantdoxygen" = "xyes" ; then
 254         AC_CHECK_PROGS([DOXYGEN], [doxygen])
 255         if test $DOXYGEN ; then
 256                 AC_MSG_RESULT([yes])
 257                 usedoxygen=yes
 258         else
 259                 AC_MSG_RESULT([no, doxygen missing])
 260                 usedoxygen=no
 261         fi
 262 else
 263         AC_MSG_RESULT([no, disabled by configure])
 264         usedoxygen=no
 265 fi
 266 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 267
 268 # Check for asciidoc support and status
 269 AC_MSG_CHECKING([for asciidoc])
 270 if test "x$wantasciidoc" = "xyes" ; then
 271         AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 272         if test $ASCIIDOC ; then
 273                 AC_MSG_RESULT([yes])
 274                 useasciidoc=yes
 275         else
 276                 AC_MSG_RESULT([no, asciidoc missing])
 277                 useasciidoc=no
 278         fi
 279 else
 280         AC_MSG_RESULT([no, disabled by configure])
 281         useasciidoc=no
 282 fi
 283 AM_CONDITIONAL(USE_ASCIIDOC, test "x$useasciidoc" = "xyes")
 284
 285 # Enable or disable debug code
 286 AC_MSG_CHECKING(for debug mode request)
 287 if test "x$debug" = "xyes" ; then
 288         AC_MSG_RESULT(yes)
 289         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 290         # Check for mcheck
 291         AC_CHECK_HEADERS([mcheck.h])
 292         # Check for -fstack-protector availability
 293         GCC_STACK_PROTECT_LIB
 294         GCC_STACK_PROTECT_CC
 295         CFLAGS="$CFLAGS -Wall -Werror"
 296 else
 297         AC_MSG_RESULT(no)
 298         CFLAGS="$CFLAGS -Wall"
 299 fi
 300
 301 # Enable or disable inclusion of pacman.static
 302 AC_MSG_CHECKING(whether to build pacman.static)
 303 if test "x$pacmanstatic" = "xyes" ; then
 304         AC_MSG_RESULT(yes)
 305         AC_DEFINE([INCLUDE_PACMAN_STATIC], , [Build pacman.static])
 306 else
 307         AC_MSG_RESULT(no)
 308 fi
 309 AM_CONDITIONAL(INCLUDE_PACMAN_STATIC, test "x$pacmanstatic" = "xyes")
 310
 311 # Set root directory
 312 AC_SUBST(ROOTDIR)
 313 # Set package file extension
 314 AC_SUBST(PKGEXT)
 315 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 316 # Set source package file extension
 317 AC_SUBST(SRCEXT)
 318 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 319 # Set database file extension
 320 AC_SUBST(DBEXT)
 321 AC_DEFINE_UNQUOTED([DBEXT], "$DBEXT", [The file extension used by pacman databases])
 322
 323 # Configuration files
 324 AC_CONFIG_FILES([
 325 lib/libalpm/Makefile
 326 lib/libalpm/po/Makefile.in
 327 src/pacman/Makefile
 328 src/util/Makefile
 329 scripts/Makefile
 330 doc/Makefile
 331 etc/Makefile
 332 po/Makefile.in
 333 pactest/Makefile
 334 contrib/Makefile
 335 Makefile
 336 ])
 337 AC_OUTPUT
 338
 339 echo "
 340 pacman_display_version:
 341
 342   Build information:
 343     source code location   : ${srcdir}
 344     prefix                 : ${prefix}
 345     sysconfdir             : $(eval echo ${sysconfdir})
 346        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 347     localstatedir          : $(eval echo ${localstatedir})
 348        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 349        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 350     compiler               : ${CC}
 351     compiler flags         : ${CFLAGS}
 352     defines                : ${DEFS}
 353
 354     Architecture           : ${CARCH}
 355     Architecture flags     : ${CARCHFLAGS}
 356     Host Type              : ${CHOST}
 357
 358     libalpm version        : ${LIB_VERSION}
 359     libalpm version info   : ${LIB_VERSION_INFO}
 360     pacman version         : ${PACKAGE_VERSION}
 361
 362   Directory and file information:
 363     root working directory : ${ROOTDIR}
 364     package extension      : ${PKGEXT}
 365     source pkg extension   : ${SRCEXT}
 366     database extension     : ${DBEXT}
 367
 368   Compilation options:
 369     Run make in doc/ dir   : ${wantdoc}
 370     Use download library   : ${internaldownload}
 371     Doxygen support        : ${usedoxygen}
 372     Asciidoc support       : ${useasciidoc}
 373     debug support          : ${debug}
 374     build pacman.static    : ${pacmanstatic}
 375 "
 376
 377 # vim:set ts=2 sw=2 noet: