configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.60)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43 #
  44 #   pacman_version_suffix should be similar to one of the following:
  45 #     For beta releases:          [beta2]
  46 #     For code under development: [devel]
  47 #     For production releases:    []
  48
  49 m4_define([lib_current], [4])
  50 m4_define([lib_revision], [0])
  51 m4_define([lib_age], [2])
  52
  53 m4_define([pacman_version_major], [3])
  54 m4_define([pacman_version_minor], [2])
  55 m4_define([pacman_version_micro], [0])
  56 m4_define([pacman_version_suffix], [devel])
  57 m4_define([pacman_version],
  58           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  59 m4_define([pacman_display_version],
  60                                         pacman_version[]m4_ifdef([pacman_version_suffix],[pacman_version_suffix]))
  61
  62 # Autoconf initialization
  63 # AC_INIT(FULL-PACKAGE-NAME, VERSION, BUG-REPORT-ADDRESS)
  64 AC_INIT([Pacman Package Manager], [pacman_display_version],
  65         [pacman-dev@archlinux.org], [pacman])
  66 AC_CONFIG_SRCDIR([config.h.in])
  67 AC_CONFIG_HEADERS([config.h])
  68
  69 AC_CANONICAL_HOST
  70 AM_INIT_AUTOMAKE
  71
  72 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  73 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  74
  75 # Set subsitution values for version stuff in Makefiles and anywhere else,
  76 # and put LIB_VERSION in config.h
  77 AC_SUBST(LIB_VERSION)
  78 AC_SUBST(LIB_VERSION_INFO)
  79 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  80
  81 # Help line for root directory
  82 AC_ARG_WITH(root-dir,
  83         AC_HELP_STRING([--with-root-dir=path], [set the location of pacman's root operating directory]),
  84         [ROOTDIR=$withval], [ROOTDIR=/])
  85
  86 # Help line for package extension
  87 AC_ARG_WITH(pkg-ext,
  88         AC_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  89         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  90
  91 # Help line for source package directory
  92 AC_ARG_WITH(src-ext,
  93         AC_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  94         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  95
  96 # Help line for database extension
  97 AC_ARG_WITH(db-ext,
  98         AC_HELP_STRING([--with-db-ext=ext], [set the file extension used by the database]),
  99         [DBEXT=$withval], [DBEXT=.db.tar.gz])
 100
 101 # Help line for documentation
 102 AC_ARG_ENABLE(doc,
 103         AC_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 104         [wantdoc=$enableval], [wantdoc=yes])
 105
 106 # Help line for doxygen
 107 AC_ARG_ENABLE(doxygen,
 108         AC_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 109         [wantdoxygen=$enableval], [wantdoxygen=no])
 110
 111 # Help line for asciidoc
 112 AC_ARG_ENABLE(asciidoc,
 113         AC_HELP_STRING([--enable-asciidoc], [build your own manpages with Asciidoc]),
 114         [wantasciidoc=$enableval], [wantasciidoc=no])
 115
 116 # Help line for debug
 117 AC_ARG_ENABLE(debug,
 118         AC_HELP_STRING([--enable-debug], [enable debugging support]),
 119         [debug=$enableval], [debug=no])
 120
 121 # Help line for pacman.static
 122 AC_ARG_ENABLE(pacman-static,
 123         AC_HELP_STRING([--disable-pacman-static], [do not build static version of pacman]),
 124         [pacmanstatic=$enableval], [pacmanstatic=yes])
 125
 126 # Checks for programs.
 127 AC_PROG_AWK
 128 AC_PROG_CC_C99
 129 AC_PROG_INSTALL
 130 AC_PROG_LN_S
 131 AC_PROG_MAKE_SET
 132 AC_PROG_LIBTOOL
 133 AC_CHECK_PROGS([PYTHON], [python2.5 python2.4 python], [false])
 134
 135 # find installed gettext
 136 AM_GNU_GETTEXT([external])
 137 AM_GNU_GETTEXT_VERSION(0.13.1)
 138
 139 # Check for libarchive
 140 AC_CHECK_LIB([archive], [archive_read_data], , AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 141
 142 # Check for libdownload
 143 AC_CHECK_LIB([download], [downloadParseURL], , AC_MSG_ERROR([libdownload is needed to compile pacman!]))
 144
 145 # Checks for header files.
 146 AC_CHECK_HEADERS([fcntl.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/statvfs.h sys/time.h syslog.h wchar.h])
 147
 148 # Checks for typedefs, structures, and compiler characteristics.
 149 AC_C_INLINE
 150 AC_TYPE_MODE_T
 151 AC_TYPE_OFF_T
 152 AC_TYPE_PID_T
 153 AC_TYPE_SIZE_T
 154 AC_STRUCT_TM
 155 AC_TYPE_UID_T
 156
 157 # Checks for library functions.
 158 AC_FUNC_CLOSEDIR_VOID
 159 AC_FUNC_FORK
 160 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 161 AC_FUNC_MKTIME
 162 AC_TYPE_SIGNAL
 163 AC_CHECK_FUNCS([realpath regcomp strcasecmp strdup strerror strnlen \
 164                                                                 strndup strrchr strsep strstr strverscmp uname geteuid])
 165
 166 # Enable large file support if available
 167 AC_SYS_LARGEFILE
 168
 169 # Check if we can use symbol visibility support in GCC
 170 GCC_VISIBILITY_CC
 171 # Check if we have -fgnu89-inline flag
 172 GCC_GNU89_INLINE_CC
 173
 174 # Host-dependant flags
 175 case "${host}" in
 176         *-*-cygwin*)
 177                 CFLAGS="$CFLAGS -DCYGWIN"
 178                 ;;
 179 esac
 180
 181 # Check for architecture, used in default makepkg.conf
 182 # (Note single space left after CARCHFLAGS)
 183 case "${host}" in
 184         i686-*)
 185                 CARCH="i686"
 186                 CARCHFLAGS="-march=i686 "
 187                 ;;
 188         x86_64-*)
 189                 CARCH="x86_64"
 190                 CARCHFLAGS="-march=x86-64 "
 191                 ;;
 192         ia64-*)
 193                 CARCH="ia64"
 194                 CARCHFLAGS="-march=ia64 "
 195                 ;;
 196         sparc-*)
 197                 CARCH="sparc"
 198                 CARCHFLAGS="-mcpu=v9 "
 199                 ;;
 200         ppc-* | powerpc-*)
 201                 CARCH="ppc"
 202                 CARCHFLAGS="-mcpu=750 "
 203                 ;;
 204         i386-*)
 205                 CARCH="i386"
 206                 CARCHFLAGS="-march=i386 "
 207                 ;;
 208         arm-*)
 209                 CARCH="arm"
 210                 CARCHFLAGS="-march=armv4 "
 211                 ;;
 212         *)
 213                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 214                 CARCH="unknown"
 215                 CARCHFLAGS=""
 216                 ;;
 217 esac
 218
 219 # Now do some things common to all architectures
 220 CHOST="${host}"
 221 AC_SUBST(CARCH)
 222 AC_SUBST(CARCHFLAGS)
 223 AC_SUBST(CHOST)
 224
 225 # Check for documentation support and status
 226 AC_MSG_CHECKING([for building documentation])
 227 if test "x$wantdoc" = "xyes" ; then
 228         AC_MSG_RESULT([yes])
 229         wantdoc=yes
 230 else
 231         AC_MSG_RESULT([no, disabled by configure])
 232         wantdoc=no
 233 fi
 234 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 235
 236 # Check for doxygen support and status
 237 AC_MSG_CHECKING([for doxygen])
 238 if test "x$wantdoxygen" = "xyes" ; then
 239         AC_CHECK_PROGS([DOXYGEN], [doxygen])
 240         if test $DOXYGEN ; then
 241                 AC_MSG_RESULT([yes])
 242                 usedoxygen=yes
 243         else
 244                 AC_MSG_RESULT([no, doxygen missing])
 245                 usedoxygen=no
 246         fi
 247 else
 248         AC_MSG_RESULT([no, disabled by configure])
 249         usedoxygen=no
 250 fi
 251 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 252
 253 # Check for asciidoc support and status
 254 AC_MSG_CHECKING([for asciidoc])
 255 if test "x$wantasciidoc" = "xyes" ; then
 256         AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 257         if test $ASCIIDOC ; then
 258                 AC_MSG_RESULT([yes])
 259                 useasciidoc=yes
 260         else
 261                 AC_MSG_RESULT([no, asciidoc missing])
 262                 useasciidoc=no
 263         fi
 264 else
 265         AC_MSG_RESULT([no, disabled by configure])
 266         useasciidoc=no
 267 fi
 268 AM_CONDITIONAL(USE_ASCIIDOC, test "x$useasciidoc" = "xyes")
 269
 270 # Enable or disable debug code
 271 AC_MSG_CHECKING(for debug mode request)
 272 if test "x$debug" = "xyes" ; then
 273         AC_MSG_RESULT(yes)
 274         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 275         # Check for mcheck
 276         AC_CHECK_HEADERS([mcheck.h])
 277         # Check for -fstack-protector availability
 278         GCC_STACK_PROTECT_LIB
 279         GCC_STACK_PROTECT_CC
 280         CFLAGS="$CFLAGS -Wall -Werror"
 281 else
 282         AC_MSG_RESULT(no)
 283         CFLAGS="$CFLAGS -Wall"
 284 fi
 285
 286 # Enable or disable inclusion of pacman.static
 287 AC_MSG_CHECKING(whether to build pacman.static)
 288 if test "x$pacmanstatic" = "xyes" ; then
 289         AC_MSG_RESULT(yes)
 290         AC_DEFINE([INCLUDE_PACMAN_STATIC], , [Build pacman.static])
 291 else
 292         AC_MSG_RESULT(no)
 293 fi
 294 AM_CONDITIONAL(INCLUDE_PACMAN_STATIC, test "x$pacmanstatic" = "xyes")
 295
 296 # Set root directory
 297 AC_SUBST(ROOTDIR)
 298 # Set package file extension
 299 AC_SUBST(PKGEXT)
 300 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 301 # Set source package file extension
 302 AC_SUBST(SRCEXT)
 303 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 304 # Set database file extension
 305 AC_SUBST(DBEXT)
 306 AC_DEFINE_UNQUOTED([DBEXT], "$DBEXT", [The file extension used by pacman databases])
 307
 308 # Configuration files
 309 AC_CONFIG_FILES([
 310 lib/libalpm/Makefile
 311 lib/libalpm/po/Makefile.in
 312 src/pacman/Makefile
 313 src/util/Makefile
 314 scripts/Makefile
 315 doc/Makefile
 316 etc/Makefile
 317 po/Makefile.in
 318 pactest/Makefile
 319 contrib/Makefile
 320 Makefile
 321 ])
 322 AC_OUTPUT
 323
 324 echo "
 325 pacman_display_version:
 326
 327   Build information:
 328     source code location   : ${srcdir}
 329     prefix                 : ${prefix}
 330     sysconfdir             : $(eval echo ${sysconfdir})
 331        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 332     localstatedir          : $(eval echo ${localstatedir})
 333        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 334        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 335     compiler               : ${CC}
 336     compiler flags         : ${CFLAGS}
 337     defines                : ${DEFS}
 338
 339     Architecture           : ${CARCH}
 340     Architecture flags     : ${CARCHFLAGS}
 341     Host Type              : ${CHOST}
 342
 343     libalpm version        : ${LIB_VERSION}
 344     libalpm version info   : ${LIB_VERSION_INFO}
 345     pacman version         : ${PACKAGE_VERSION}
 346
 347   Directory and file information:
 348     root working directory : ${ROOTDIR}
 349     package extension      : ${PKGEXT}
 350     source pkg extension   : ${SRCEXT}
 351     database extension     : ${DBEXT}
 352
 353   Compilation options:
 354     Run make in doc/ dir   : ${wantdoc}
 355     Doxygen support        : ${usedoxygen}
 356     Asciidoc support       : ${useasciidoc}
 357     debug support          : ${debug}
 358     build pacman.static    : ${pacmanstatic}
 359 "
 360
 361 # vim:set ts=2 sw=2 noet: