configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [5])
  45 m4_define([lib_revision], [3])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [4])
  50 m4_define([pacman_version_micro], [3])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for buildscript filename
  87 AC_ARG_WITH(buildscript,
  88         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  89         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  90
  91 # Help line for using OpenSSL
  92 AC_ARG_WITH(openssl,
  93         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  94         [], [with_openssl=check])
  95
  96 # Help line for libfetch
  97 AC_ARG_WITH(fetch,
  98         AS_HELP_STRING([--with-fetch], [use libfetch as an internal downloader]),
  99         [], [with_fetch=check])
 100
 101 # Help line for documentation
 102 AC_ARG_ENABLE(doc,
 103         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 104         [wantdoc=$enableval], [wantdoc=yes])
 105
 106 # Help line for doxygen
 107 AC_ARG_ENABLE(doxygen,
 108         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 109         [wantdoxygen=$enableval], [wantdoxygen=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Checks for programs.
 123 AC_PROG_AWK
 124 AC_PROG_CC_C99
 125 AC_PROG_INSTALL
 126 AC_PROG_LN_S
 127 AC_PROG_MAKE_SET
 128 AC_PROG_LIBTOOL
 129 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 130 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 131
 132 # find installed gettext
 133 AM_GNU_GETTEXT([external])
 134 AM_GNU_GETTEXT_VERSION(0.13.1)
 135
 136 # Check for libarchive
 137 AC_CHECK_LIB([archive], [archive_read_data], ,
 138         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 139
 140 # Check for OpenSSL
 141 AC_MSG_CHECKING(whether to link with libssl)
 142 AS_IF([test "x$with_openssl" != "xno"],
 143         [AC_MSG_RESULT(yes)
 144         AC_CHECK_LIB([ssl], [MD5_Final], ,
 145         [if test "x$with_openssl" != "xcheck"; then
 146                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 147         fi],
 148         [-lcrypto])],
 149         AC_MSG_RESULT(no))
 150 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$ac_cv_lib_ssl_MD5_Final" = "xyes"])
 151
 152 # Enable or disable usage of libfetch
 153 AC_MSG_CHECKING(whether to link with libfetch)
 154 AS_IF([test "x$with_fetch" != "xno"],
 155         [AC_MSG_RESULT(yes)
 156         AC_CHECK_LIB([fetch], [fetchParseURL], ,
 157         [if test "x$with_fetch" != "xcheck"; then
 158                 AC_MSG_FAILURE([--with-fetch was given, but -lfetch was not found])
 159         fi],
 160         [-lcrypto -ldl])
 161         # Check if libfetch supports connnection caching which we use
 162         AS_IF([test "x$ac_cv_lib_fetch_fetchParseURL" = "xyes"],
 163         [AC_CHECK_DECL(fetchConnectionCacheInit, ,
 164                 AC_MSG_ERROR([libfetch must be version 2.28 or greater]),
 165                 [#include <fetch.h>])
 166         ])
 167         ],
 168         AC_MSG_RESULT(no))
 169 AM_CONDITIONAL([HAVE_LIBFETCH], [test "x$ac_cv_lib_fetch_fetchParseURL" = "xyes"])
 170
 171 # Checks for header files.
 172 AC_CHECK_HEADERS([fcntl.h glob.h libintl.h locale.h mntent.h string.h \
 173                   sys/ioctl.h sys/mount.h sys/param.h sys/statvfs.h \
 174                   sys/time.h sys/types.h sys/ucred.h syslog.h wchar.h])
 175
 176 # Checks for typedefs, structures, and compiler characteristics.
 177 AC_C_INLINE
 178 AC_TYPE_MODE_T
 179 AC_TYPE_OFF_T
 180 AC_TYPE_PID_T
 181 AC_TYPE_SIZE_T
 182 AC_STRUCT_TM
 183 AC_TYPE_UID_T
 184 AC_STRUCT_DIRENT_D_TYPE
 185 PATH_MAX_DEFINED
 186
 187 # Checks for library functions.
 188 AC_FUNC_FORK
 189 AC_FUNC_GETMNTENT
 190 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 191 AC_FUNC_MKTIME
 192 AC_CHECK_FUNCS([geteuid getmntinfo realpath regcomp strcasecmp \
 193                 strndup strrchr strsep swprintf \
 194                 wcwidth uname])
 195 # For the diskspace code
 196 FS_STATS_TYPE
 197 # Enable large file support if available
 198 AC_SYS_LARGEFILE
 199
 200 # Check if we can use symbol visibility support in GCC
 201 GCC_VISIBILITY_CC
 202 # Check if we have -fgnu89-inline flag
 203 GCC_GNU89_INLINE_CC
 204
 205 # Host-dependant definitions
 206 SIZECMD="stat -L -c %s"
 207 SEDINPLACE="sed -i"
 208 STRIP_BINARIES="--strip-all"
 209 STRIP_SHARED="--strip-unneeded"
 210 STRIP_STATIC="--strip-debug"
 211 case "${host_os}" in
 212         *bsd*)
 213                 SIZECMD="stat -L -f %z"
 214                 SEDINPLACE="sed -i ''"
 215                 ;;
 216         cygwin*)
 217                 host_os_cygwin=yes
 218                 CFLAGS="$CFLAGS -DCYGWIN"
 219                 ;;
 220         darwin*)
 221                 host_os_darwin=yes
 222                 SIZECMD="/usr/bin/stat -L -f %z"
 223                 SEDINPLACE="/usr/bin/sed -i ''"
 224                 STRIP_BINARIES=""
 225                 STRIP_SHARED="-S"
 226                 STRIP_STATIC="-S"
 227                 ;;
 228 esac
 229
 230 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 231 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 232 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 233 AC_SUBST(SIZECMD)
 234 AC_SUBST(SEDINPLACE)
 235 AC_SUBST(STRIP_BINARIES)
 236 AC_SUBST(STRIP_SHARED)
 237 AC_SUBST(STRIP_STATIC)
 238
 239 # Check for architecture, used in default makepkg.conf
 240 # (Note single space left after CARCHFLAGS)
 241 case "${host}" in
 242         i686-*)
 243                 CARCH="i686"
 244                 CARCHFLAGS="-march=i686 "
 245                 ;;
 246         x86_64-*)
 247                 CARCH="x86_64"
 248                 CARCHFLAGS="-march=x86-64 "
 249                 ;;
 250         ia64-*)
 251                 CARCH="ia64"
 252                 CARCHFLAGS="-march=ia64 "
 253                 ;;
 254         sparc-*)
 255                 CARCH="sparc"
 256                 CARCHFLAGS="-mcpu=v9 "
 257                 ;;
 258         ppc-* | powerpc-*)
 259                 CARCH="ppc"
 260                 CARCHFLAGS="-mcpu=750 "
 261                 ;;
 262         i386-*)
 263                 CARCH="i386"
 264                 CARCHFLAGS="-march=i386 "
 265                 ;;
 266         arm-*)
 267                 CARCH="arm"
 268                 CARCHFLAGS="-march=armv4 "
 269                 ;;
 270         *)
 271                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 272                 CARCH="unknown"
 273                 CARCHFLAGS=""
 274                 ;;
 275 esac
 276
 277 # Now do some things common to all architectures
 278 CHOST="${host}"
 279 AC_SUBST(CARCH)
 280 AC_SUBST(CARCHFLAGS)
 281 AC_SUBST(CHOST)
 282
 283 # Check for documentation support and status
 284 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 285 AC_MSG_CHECKING([for building documentation])
 286 if test "x$wantdoc" = "xyes" ; then
 287         if test $ASCIIDOC ; then
 288                 AC_MSG_RESULT([yes, enabled by configure])
 289         else
 290                 asciidoc="(warning : asciidoc not installed)"
 291                 AC_MSG_RESULT([yes $asciidoc])
 292         fi
 293         wantdoc=yes
 294 else
 295         AC_MSG_RESULT([no, disabled by configure])
 296         wantdoc=no
 297 fi
 298 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 299
 300 # Check for doxygen support and status
 301 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 302 AC_MSG_CHECKING([for doxygen])
 303 if test "x$wantdoxygen" = "xyes" ; then
 304         if test $DOXYGEN ; then
 305                 AC_MSG_RESULT([yes])
 306                 usedoxygen=yes
 307         else
 308                 AC_MSG_RESULT([no, doxygen missing])
 309                 usedoxygen=no
 310         fi
 311 else
 312         AC_MSG_RESULT([no, disabled by configure])
 313         usedoxygen=no
 314 fi
 315 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 316
 317 # Enable or disable debug code
 318 AC_MSG_CHECKING(for debug mode request)
 319 if test "x$debug" = "xyes" ; then
 320         AC_MSG_RESULT(yes)
 321         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 322         # Check for mcheck
 323         AC_CHECK_HEADERS([mcheck.h])
 324         # Check for -fstack-protector availability
 325         GCC_STACK_PROTECT_LIB
 326         GCC_STACK_PROTECT_CC
 327         GCC_FORTIFY_SOURCE_CC
 328         CFLAGS="$CFLAGS -g -Wall -Werror"
 329 else
 330         AC_MSG_RESULT(no)
 331         CFLAGS="$CFLAGS -Wall"
 332 fi
 333
 334 # Enable or disable use of git version in pacman version string
 335 AC_MSG_CHECKING(whether to use git version if available)
 336 if test "x$wantgitver" = "xyes" ; then
 337         AC_CHECK_PROGS([GIT], [git])
 338         AC_CHECK_FILE([.git/], hasgitdir=yes)
 339         if test $GIT -a "x$hasgitdir" = "xyes"; then
 340                 AC_MSG_RESULT([yes])
 341                 usegitver=yes
 342                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 343         else
 344                 AC_MSG_RESULT([no, git or .git dir missing])
 345                 usegitver=no
 346         fi
 347 else
 348         AC_MSG_RESULT([no, disabled by configure])
 349         usegitver=no
 350 fi
 351 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 352
 353 # Set root directory
 354 AC_SUBST(ROOTDIR)
 355 # Set package file extension
 356 AC_SUBST(PKGEXT)
 357 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 358 # Set source package file extension
 359 AC_SUBST(SRCEXT)
 360 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 361 # Set makepkg build script name
 362 AC_SUBST(BUILDSCRIPT)
 363 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 364
 365 # Configuration files
 366 AC_CONFIG_FILES([
 367 lib/libalpm/Makefile
 368 lib/libalpm/po/Makefile.in
 369 src/pacman/Makefile
 370 src/util/Makefile
 371 scripts/Makefile
 372 doc/Makefile
 373 etc/Makefile
 374 po/Makefile.in
 375 test/pacman/Makefile
 376 test/pacman/tests/Makefile
 377 test/util/Makefile
 378 contrib/Makefile
 379 Makefile
 380 ])
 381 AC_OUTPUT
 382
 383 echo "
 384 ${PACKAGE_NAME}:
 385
 386   Build information:
 387     source code location   : ${srcdir}
 388     prefix                 : ${prefix}
 389     sysconfdir             : $(eval echo ${sysconfdir})
 390        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 391     localstatedir          : $(eval echo ${localstatedir})
 392        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 393        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 394     compiler               : ${CC}
 395     compiler flags         : ${CFLAGS}
 396     defines                : ${DEFS}
 397
 398     Architecture           : ${CARCH}
 399     Architecture flags     : ${CARCHFLAGS}
 400     Host Type              : ${CHOST}
 401     Filesize command       : ${SIZECMD}
 402     In-place sed command   : ${SEDINPLACE}
 403
 404     libalpm version        : ${LIB_VERSION}
 405     libalpm version info   : ${LIB_VERSION_INFO}
 406     pacman version         : ${PACKAGE_VERSION}
 407     using git version      : ${usegitver}
 408
 409   Directory and file information:
 410     root working directory : ${ROOTDIR}
 411     package extension      : ${PKGEXT}
 412     source pkg extension   : ${SRCEXT}
 413     build script name      : ${BUILDSCRIPT}
 414
 415   Compilation options:
 416     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 417     Doxygen support        : ${usedoxygen}
 418     debug support          : ${debug}
 419 "
 420
 421 # vim:set ts=2 sw=2 noet: