configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.60)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [4])
  45 m4_define([lib_revision], [0])
  46 m4_define([lib_age], [1])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [2])
  50 m4_define([pacman_version_micro], [1])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of pacman's root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for database extension
  87 AC_ARG_WITH(db-ext,
  88         AS_HELP_STRING([--with-db-ext=ext], [set the file extension used by the database]),
  89         [DBEXT=$withval], [DBEXT=.db.tar.gz])
  90
  91 # Help line for libdownload/libfetch
  92 AC_ARG_ENABLE(internal-download,
  93         AS_HELP_STRING([--disable-internal-download], [do not build with libdownload/libfetch support]),
  94         [internaldownload=$enableval], [internaldownload=yes])
  95
  96 # Help line for documentation
  97 AC_ARG_ENABLE(doc,
  98         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
  99         [wantdoc=$enableval], [wantdoc=yes])
 100
 101 # Help line for doxygen
 102 AC_ARG_ENABLE(doxygen,
 103         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 104         [wantdoxygen=$enableval], [wantdoxygen=no])
 105
 106 # Help line for debug
 107 AC_ARG_ENABLE(debug,
 108         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 109         [debug=$enableval], [debug=no])
 110
 111 # Help line for using git version in pacman version string
 112 AC_ARG_ENABLE(git-version,
 113         AS_HELP_STRING([--enable-git-version],
 114                 [enable use of git version in version string if available]),
 115         [wantgitver=$enableval], [wantgitver=no])
 116
 117 # Checks for programs.
 118 AC_PROG_AWK
 119 AC_PROG_CC_C99
 120 AC_PROG_INSTALL
 121 AC_PROG_LN_S
 122 AC_PROG_MAKE_SET
 123 AC_PROG_LIBTOOL
 124 AC_CHECK_PROGS([PYTHON], [python2.5 python2.4 python], [false])
 125
 126 # find installed gettext
 127 AM_GNU_GETTEXT([external])
 128 AM_GNU_GETTEXT_VERSION(0.13.1)
 129
 130 # Check for libarchive
 131 AC_CHECK_LIB([archive], [archive_read_data], ,
 132         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 133
 134 # Enable or disable usage of libdownload/libfetch
 135 # - this is a nested check- first see if we need a library, if we do then
 136 #   check for libdownload first, then fallback to libfetch, then die
 137 AC_MSG_CHECKING(whether to link with download library)
 138 if test "x$internaldownload" = "xyes" ; then
 139         AC_MSG_RESULT(yes)
 140         AC_DEFINE([INTERNAL_DOWNLOAD], , [Use internal download library])
 141         # Check for a download library if it was actually requested
 142         AC_CHECK_LIB([download], [downloadParseURL], ,
 143                 AC_CHECK_LIB([fetch], [fetchParseURL], ,
 144                         AC_MSG_ERROR([libdownload or libfetch are needed to compile with internal download support])) )
 145 else
 146         AC_MSG_RESULT(no)
 147 fi
 148 AM_CONDITIONAL(INTERNAL_DOWNLOAD, test "x$internaldownload" = "xyes")
 149
 150 # Checks for header files.
 151 AC_CHECK_HEADERS([fcntl.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/param.h sys/statvfs.h sys/syslimits.h sys/time.h syslog.h wchar.h])
 152
 153 # Checks for typedefs, structures, and compiler characteristics.
 154 AC_C_INLINE
 155 AC_TYPE_MODE_T
 156 AC_TYPE_OFF_T
 157 AC_TYPE_PID_T
 158 AC_TYPE_SIZE_T
 159 AC_STRUCT_TM
 160 AC_TYPE_UID_T
 161
 162 # Checks for library functions.
 163 AC_FUNC_FORK
 164 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 165 AC_FUNC_MKTIME
 166 AC_TYPE_SIGNAL
 167 AC_CHECK_FUNCS([geteuid realpath regcomp strcasecmp \
 168                 strndup strrchr strsep swprintf \
 169                 wcwidth uname])
 170
 171 # Enable large file support if available
 172 AC_SYS_LARGEFILE
 173
 174 # Check if we can use symbol visibility support in GCC
 175 GCC_VISIBILITY_CC
 176 # Check if we have -fgnu89-inline flag
 177 GCC_GNU89_INLINE_CC
 178
 179 # Host-dependant definitions
 180 SIZECMD="stat -c %s"
 181 case "${host_os}" in
 182         *bsd*)
 183                 SIZECMD="stat -f %z"
 184                 ;;
 185         cygwin*)
 186                 host_os_cygwin=yes
 187                 CFLAGS="$CFLAGS -DCYGWIN"
 188                 ;;
 189         darwin*)
 190                 host_os_darwin=yes
 191                 SIZECMD="stat -f %z"
 192                 ;;
 193 esac
 194
 195 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 196 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 197 AC_SUBST(SIZECMD)
 198
 199 # Check for architecture, used in default makepkg.conf
 200 # (Note single space left after CARCHFLAGS)
 201 case "${host}" in
 202         i686-*)
 203                 CARCH="i686"
 204                 CARCHFLAGS="-march=i686 "
 205                 ;;
 206         x86_64-*)
 207                 CARCH="x86_64"
 208                 CARCHFLAGS="-march=x86-64 "
 209                 ;;
 210         ia64-*)
 211                 CARCH="ia64"
 212                 CARCHFLAGS="-march=ia64 "
 213                 ;;
 214         sparc-*)
 215                 CARCH="sparc"
 216                 CARCHFLAGS="-mcpu=v9 "
 217                 ;;
 218         ppc-* | powerpc-*)
 219                 CARCH="ppc"
 220                 CARCHFLAGS="-mcpu=750 "
 221                 ;;
 222         i386-*)
 223                 CARCH="i386"
 224                 CARCHFLAGS="-march=i386 "
 225                 ;;
 226         arm-*)
 227                 CARCH="arm"
 228                 CARCHFLAGS="-march=armv4 "
 229                 ;;
 230         *)
 231                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 232                 CARCH="unknown"
 233                 CARCHFLAGS=""
 234                 ;;
 235 esac
 236
 237 # Now do some things common to all architectures
 238 CHOST="${host}"
 239 AC_SUBST(CARCH)
 240 AC_SUBST(CARCHFLAGS)
 241 AC_SUBST(CHOST)
 242
 243 # Check for documentation support and status
 244 AC_MSG_CHECKING([for building documentation])
 245 if test "x$wantdoc" = "xyes" ; then
 246         AC_MSG_RESULT([yes])
 247         wantdoc=yes
 248 else
 249         AC_MSG_RESULT([no, disabled by configure])
 250         wantdoc=no
 251 fi
 252 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 253
 254 # Check for doxygen support and status
 255 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 256 AC_MSG_CHECKING([for doxygen])
 257 if test "x$wantdoxygen" = "xyes" ; then
 258         if test $DOXYGEN ; then
 259                 AC_MSG_RESULT([yes])
 260                 usedoxygen=yes
 261         else
 262                 AC_MSG_RESULT([no, doxygen missing])
 263                 usedoxygen=no
 264         fi
 265 else
 266         AC_MSG_RESULT([no, disabled by configure])
 267         usedoxygen=no
 268 fi
 269 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 270
 271 # Enable or disable debug code
 272 AC_MSG_CHECKING(for debug mode request)
 273 if test "x$debug" = "xyes" ; then
 274         AC_MSG_RESULT(yes)
 275         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 276         # Check for mcheck
 277         AC_CHECK_HEADERS([mcheck.h])
 278         # Check for -fstack-protector availability
 279         GCC_STACK_PROTECT_LIB
 280         GCC_STACK_PROTECT_CC
 281         CFLAGS="$CFLAGS -Wall -Werror"
 282 else
 283         AC_MSG_RESULT(no)
 284         CFLAGS="$CFLAGS -Wall"
 285 fi
 286
 287 # Enable or disable use of git version in pacman version string
 288 AC_CHECK_PROGS([GIT], [git])
 289 AC_CHECK_FILE([.git/], hasgitdir=yes)
 290 AC_MSG_CHECKING(whether to use git version if available)
 291 if test "x$wantgitver" = "xyes" ; then
 292         if test $GIT -a "x$hasgitdir" = "xyes"; then
 293                 AC_MSG_RESULT([yes])
 294                 usegitver=yes
 295                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 296         else
 297                 AC_MSG_RESULT([no, git or .git dir missing])
 298                 usegitver=no
 299         fi
 300 else
 301         AC_MSG_RESULT([no, disabled by configure])
 302         usegitver=no
 303 fi
 304 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 305
 306 # Set root directory
 307 AC_SUBST(ROOTDIR)
 308 # Set package file extension
 309 AC_SUBST(PKGEXT)
 310 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 311 # Set source package file extension
 312 AC_SUBST(SRCEXT)
 313 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 314 # Set database file extension
 315 AC_SUBST(DBEXT)
 316 AC_DEFINE_UNQUOTED([DBEXT], "$DBEXT", [The file extension used by pacman databases])
 317
 318 # Configuration files
 319 AC_CONFIG_FILES([
 320 lib/libalpm/Makefile
 321 lib/libalpm/po/Makefile.in
 322 src/pacman/Makefile
 323 src/util/Makefile
 324 scripts/Makefile
 325 doc/Makefile
 326 etc/Makefile
 327 po/Makefile.in
 328 pactest/Makefile
 329 pactest/tests/Makefile
 330 contrib/Makefile
 331 Makefile
 332 ])
 333 AC_OUTPUT
 334
 335 echo "
 336 ${PACKAGE_NAME}:
 337
 338   Build information:
 339     source code location   : ${srcdir}
 340     prefix                 : ${prefix}
 341     sysconfdir             : $(eval echo ${sysconfdir})
 342        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 343     localstatedir          : $(eval echo ${localstatedir})
 344        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 345        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 346     compiler               : ${CC}
 347     compiler flags         : ${CFLAGS}
 348     defines                : ${DEFS}
 349
 350     Architecture           : ${CARCH}
 351     Architecture flags     : ${CARCHFLAGS}
 352     Host Type              : ${CHOST}
 353     Filesize command       : ${SIZECMD}
 354
 355     libalpm version        : ${LIB_VERSION}
 356     libalpm version info   : ${LIB_VERSION_INFO}
 357     pacman version         : ${PACKAGE_VERSION}
 358     using git version      : ${usegitver}
 359
 360   Directory and file information:
 361     root working directory : ${ROOTDIR}
 362     package extension      : ${PKGEXT}
 363     source pkg extension   : ${SRCEXT}
 364     database extension     : ${DBEXT}
 365
 366   Compilation options:
 367     Run make in doc/ dir   : ${wantdoc}
 368     Use download library   : ${internaldownload}
 369     Doxygen support        : ${usedoxygen}
 370     debug support          : ${debug}
 371 "
 372
 373 # vim:set ts=2 sw=2 noet: