configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [7])
  45 m4_define([lib_revision], [1])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [4])
  49 m4_define([pacman_version_minor], [0])
  50 m4_define([pacman_version_micro], [1])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE([1.11])
  61 AM_SILENT_RULES([yes])
  62
  63 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  64 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  65
  66 # Set subsitution values for version stuff in Makefiles and anywhere else,
  67 # and put LIB_VERSION in config.h
  68 AC_SUBST(LIB_VERSION)
  69 AC_SUBST(LIB_VERSION_INFO)
  70 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  71
  72 # Help line for root directory
  73 AC_ARG_WITH(root-dir,
  74         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  75         [ROOTDIR=$withval], [ROOTDIR=/])
  76
  77 # Help line for package extension
  78 AC_ARG_WITH(pkg-ext,
  79         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  80         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  81
  82 # Help line for source package directory
  83 AC_ARG_WITH(src-ext,
  84         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  85         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  86
  87 # Help line for buildscript filename
  88 AC_ARG_WITH(buildscript,
  89         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  90         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  91
  92 # Help line for using OpenSSL
  93 AC_ARG_WITH(openssl,
  94         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  95         [], [with_openssl=check])
  96
  97 # Help line for using gpgme
  98 AC_ARG_WITH(gpgme,
  99         AS_HELP_STRING([--with-gpgme], [use GPGME for PGP signature verification]),
 100         [], [with_gpgme=check])
 101
 102 # Check for useable libcurl
 103 LIBCURL_CHECK_CONFIG([yes], [7.19.4], [with_libcurl=yes], [with_libcurl=no])
 104
 105 # Help line for documentation
 106 AC_ARG_ENABLE(doc,
 107         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 108         [wantdoc=$enableval], [wantdoc=yes])
 109
 110 # Help line for doxygen
 111 AC_ARG_ENABLE(doxygen,
 112         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 113         [wantdoxygen=$enableval], [wantdoxygen=no])
 114
 115 # Help line for debug
 116 AC_ARG_ENABLE(debug,
 117         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 118         [debug=$enableval], [debug=no])
 119
 120 # Help line for using git version in pacman version string
 121 AC_ARG_ENABLE(git-version,
 122         AS_HELP_STRING([--enable-git-version],
 123                 [enable use of git version in version string if available]),
 124         [wantgitver=$enableval], [wantgitver=no])
 125
 126 # Checks for programs.
 127 AC_PROG_AWK
 128 AC_PROG_CC_C99
 129 AC_PROG_CXX
 130 AC_PROG_INSTALL
 131 AC_PROG_LN_S
 132 AC_PROG_MAKE_SET
 133 AC_PROG_LIBTOOL
 134 AC_PROG_RANLIB
 135 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 136 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 137
 138 # find installed gettext
 139 AM_GNU_GETTEXT([external], [need-ngettext])
 140 AM_GNU_GETTEXT_VERSION(0.13.1)
 141
 142 AC_CHECK_LIB([m], [fabs], ,
 143         AC_MSG_ERROR([libm is needed to compile pacman!]))
 144
 145 # Check for libarchive
 146 AC_CHECK_LIB([archive], [archive_read_data], ,
 147         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 148
 149 # Check for OpenSSL
 150 AC_MSG_CHECKING(whether to link with libssl)
 151 AS_IF([test "x$with_openssl" != "xno"],
 152         [AC_MSG_RESULT(yes)
 153         AC_CHECK_LIB([ssl], [MD5_Final], ,
 154         [if test "x$with_openssl" != "xcheck"; then
 155                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 156         fi],
 157         [-lcrypto])
 158         with_openssl=$ac_cv_lib_ssl_MD5_Final],
 159         AC_MSG_RESULT(no))
 160 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$with_openssl" = "xyes"])
 161
 162 # Check for gpgme
 163 AC_MSG_CHECKING(whether to link with libgpgme)
 164 AS_IF([test "x$with_gpgme" != "xno"],
 165         [AC_MSG_RESULT(yes)
 166         AC_CHECK_LIB([gpgme], [gpgme_check_version], ,
 167         [if test "x$with_gpgme" != "xcheck"; then
 168                 AC_MSG_FAILURE([--with-ggpme was given, but -lgpgme was not found])
 169         fi],
 170         [-lgpgme])
 171         with_gpgme=$ac_cv_lib_gpgme_gpgme_check_version],
 172         AC_MSG_RESULT(no))
 173 AM_CONDITIONAL([HAVE_LIBGPGME], [test "x$with_gpgme" = "xyes"])
 174
 175 # Checks for header files.
 176 AC_CHECK_HEADERS([fcntl.h float.h glob.h libintl.h limits.h locale.h \
 177                   mntent.h stddef.h string.h sys/ioctl.h sys/mount.h \
 178                   sys/param.h sys/statvfs.h sys/time.h sys/types.h \
 179                   sys/ucred.h syslog.h termios.h wchar.h])
 180
 181 # Checks for typedefs, structures, and compiler characteristics.
 182 AC_C_INLINE
 183 AC_TYPE_INT64_T
 184 AC_TYPE_MODE_T
 185 AC_TYPE_OFF_T
 186 AC_TYPE_PID_T
 187 AC_TYPE_SIZE_T
 188 AC_TYPE_SSIZE_T
 189 AC_STRUCT_TM
 190 AC_TYPE_UID_T
 191 AC_STRUCT_DIRENT_D_TYPE
 192 PATH_MAX_DEFINED
 193
 194 # Checks for library functions.
 195 AC_FUNC_FORK
 196 AC_FUNC_GETMNTENT
 197 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 198 AC_FUNC_MALLOC
 199 AC_FUNC_MKTIME
 200 AC_FUNC_STRCOLL
 201 AC_CHECK_FUNCS([dup2 getcwd geteuid getmntinfo gettimeofday memmove memset \
 202                 mkdir realpath regcomp rmdir setenv setlocale strcasecmp \
 203                 strchr strcspn strdup strerror strndup strrchr strsep strstr \
 204                 strtol swprintf tcflush wcwidth uname])
 205 AC_CHECK_MEMBERS([struct stat.st_blksize],,,[[#include <sys/stat.h>]])
 206
 207 # For the diskspace code
 208 FS_STATS_TYPE
 209 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 210 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 211                   #include <sys/mount.h>]])
 212
 213 # Enable large file support if available
 214 AC_SYS_LARGEFILE
 215
 216 # Check if we can use symbol visibility support in GCC
 217 GCC_VISIBILITY_CC
 218 # Check if we have -fgnu89-inline flag
 219 GCC_GNU89_INLINE_CC
 220
 221 # Host-dependant definitions
 222 SIZECMD="stat -L -c %s"
 223 SEDINPLACE="sed -i"
 224 STRIP_BINARIES="--strip-all"
 225 STRIP_SHARED="--strip-unneeded"
 226 STRIP_STATIC="--strip-debug"
 227 case "${host_os}" in
 228         *bsd*)
 229                 SIZECMD="stat -L -f %z"
 230                 SEDINPLACE="sed -i \"\""
 231                 ;;
 232         cygwin*)
 233                 host_os_cygwin=yes
 234                 CFLAGS="$CFLAGS -DCYGWIN"
 235                 ;;
 236         darwin*)
 237                 host_os_darwin=yes
 238                 SIZECMD="/usr/bin/stat -L -f %z"
 239                 SEDINPLACE="/usr/bin/sed -i ''"
 240                 STRIP_BINARIES=""
 241                 STRIP_SHARED="-S"
 242                 STRIP_STATIC="-S"
 243                 ;;
 244 esac
 245
 246 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 247 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 248 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 249 AC_SUBST(SIZECMD)
 250 AC_SUBST(SEDINPLACE)
 251 AC_SUBST(STRIP_BINARIES)
 252 AC_SUBST(STRIP_SHARED)
 253 AC_SUBST(STRIP_STATIC)
 254
 255 # Variables plugged into makepkg.conf
 256 CARCH="${host%%-*}"
 257 CHOST="${host}"
 258 AC_SUBST(CARCH)
 259 AC_SUBST(CHOST)
 260
 261 # Check for documentation support and status
 262 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 263 AC_MSG_CHECKING([for building documentation])
 264 if test "x$wantdoc" = "xyes" ; then
 265         if test $ASCIIDOC ; then
 266                 AC_MSG_RESULT([yes, enabled by configure])
 267         else
 268                 asciidoc="(warning : asciidoc not installed)"
 269                 AC_MSG_RESULT([yes $asciidoc])
 270         fi
 271         wantdoc=yes
 272 else
 273         AC_MSG_RESULT([no, disabled by configure])
 274         wantdoc=no
 275 fi
 276 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 277
 278 # Check for doxygen support and status
 279 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 280 AC_MSG_CHECKING([for doxygen])
 281 if test "x$wantdoxygen" = "xyes" ; then
 282         if test $DOXYGEN ; then
 283                 AC_MSG_RESULT([yes])
 284                 usedoxygen=yes
 285         else
 286                 AC_MSG_RESULT([no, doxygen missing])
 287                 usedoxygen=no
 288         fi
 289 else
 290         AC_MSG_RESULT([no, disabled by configure])
 291         usedoxygen=no
 292 fi
 293 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 294
 295 # Enable or disable debug code
 296 AC_MSG_CHECKING(for debug mode request)
 297 if test "x$debug" = "xyes" ; then
 298         AC_MSG_RESULT(yes)
 299         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 300         # Check for -fstack-protector availability
 301         GCC_STACK_PROTECT_LIB
 302         GCC_STACK_PROTECT_CC
 303         GCC_FORTIFY_SOURCE_CC
 304         CFLAGS="$CFLAGS -g -Wall -Werror"
 305 else
 306         AC_MSG_RESULT(no)
 307         CFLAGS="$CFLAGS -Wall"
 308 fi
 309
 310 # Enable or disable use of git version in pacman version string
 311 AC_MSG_CHECKING(whether to use git version if available)
 312 if test "x$wantgitver" = "xyes" ; then
 313         AC_CHECK_PROGS([GIT], [git])
 314         AC_CHECK_FILE([.git/], hasgitdir=yes)
 315         if test $GIT -a "x$hasgitdir" = "xyes"; then
 316                 AC_MSG_RESULT([yes])
 317                 usegitver=yes
 318                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 319         else
 320                 AC_MSG_RESULT([no, git or .git dir missing])
 321                 usegitver=no
 322         fi
 323 else
 324         AC_MSG_RESULT([no, disabled by configure])
 325         usegitver=no
 326 fi
 327 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 328
 329 # Set root directory
 330 AC_SUBST(ROOTDIR)
 331 # Set package file extension
 332 AC_SUBST(PKGEXT)
 333 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 334 # Set source package file extension
 335 AC_SUBST(SRCEXT)
 336 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 337 # Set makepkg build script name
 338 AC_SUBST(BUILDSCRIPT)
 339 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 340
 341 # Configuration files
 342 AC_CONFIG_FILES([
 343 lib/libalpm/Makefile
 344 lib/libalpm/po/Makefile.in
 345 src/pacman/Makefile
 346 src/pacman/po/Makefile.in
 347 src/util/Makefile
 348 scripts/Makefile
 349 scripts/po/Makefile.in
 350 doc/Makefile
 351 etc/Makefile
 352 test/pacman/Makefile
 353 test/pacman/tests/Makefile
 354 test/util/Makefile
 355 contrib/Makefile
 356 Makefile
 357 ])
 358 AC_OUTPUT
 359
 360 echo "
 361 ${PACKAGE_NAME}:
 362
 363   Build information:
 364     source code location   : ${srcdir}
 365     prefix                 : ${prefix}
 366     sysconfdir             : $(eval echo ${sysconfdir})
 367        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 368     localstatedir          : $(eval echo ${localstatedir})
 369        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 370        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 371
 372     compiler               : ${CC}
 373     preprocessor flags     : ${CPPFLAGS}
 374     compiler flags         : ${CFLAGS}
 375     defines                : ${DEFS}
 376     library flags          : ${LIBS}
 377     linker flags           : ${LDFLAGS}
 378
 379     Architecture           : ${CARCH}
 380     Host Type              : ${CHOST}
 381     Filesize command       : ${SIZECMD}
 382     In-place sed command   : ${SEDINPLACE}
 383
 384     libalpm version        : ${LIB_VERSION}
 385     libalpm version info   : ${LIB_VERSION_INFO}
 386     pacman version         : ${PACKAGE_VERSION}
 387     using git version      : ${usegitver}
 388
 389   Directory and file information:
 390     root working directory : ${ROOTDIR}
 391     package extension      : ${PKGEXT}
 392     source pkg extension   : ${SRCEXT}
 393     build script name      : ${BUILDSCRIPT}
 394
 395   Compilation options:
 396     Use libcurl            : ${with_libcurl}
 397     Use GPGME              : ${with_gpgme}
 398     Use OpenSSL            : ${with_openssl}
 399     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 400     Doxygen support        : ${usedoxygen}
 401     debug support          : ${debug}
 402 "
 403
 404 # vim:set ts=2 sw=2 noet: