configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [5])
  45 m4_define([lib_revision], [2])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [4])
  50 m4_define([pacman_version_micro], [2])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for buildscript filename
  87 AC_ARG_WITH(buildscript,
  88         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  89         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  90
  91 # Help line for using OpenSSL
  92 AC_ARG_WITH(openssl,
  93         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  94         [], [with_openssl=check])
  95
  96 # Help line for libfetch
  97 AC_ARG_WITH(fetch,
  98         AS_HELP_STRING([--with-fetch], [use libfetch as an internal downloader]),
  99         [], [with_fetch=check])
 100
 101 # Help line for documentation
 102 AC_ARG_ENABLE(doc,
 103         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 104         [wantdoc=$enableval], [wantdoc=yes])
 105
 106 # Help line for doxygen
 107 AC_ARG_ENABLE(doxygen,
 108         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 109         [wantdoxygen=$enableval], [wantdoxygen=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Checks for programs.
 123 AC_PROG_AWK
 124 AC_PROG_CC_C99
 125 AC_PROG_INSTALL
 126 AC_PROG_LN_S
 127 AC_PROG_MAKE_SET
 128 AC_PROG_LIBTOOL
 129 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 130 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 131
 132 # find installed gettext
 133 AM_GNU_GETTEXT([external])
 134 AM_GNU_GETTEXT_VERSION(0.13.1)
 135
 136 # Check for lm
 137 AC_CHECK_LIB([m], [ceil])
 138
 139 # Check for libarchive
 140 AC_CHECK_LIB([archive], [archive_read_data], ,
 141         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 142
 143 # Check for OpenSSL
 144 AC_MSG_CHECKING(whether to link with libssl)
 145 AS_IF([test "x$with_openssl" != "xno"],
 146         [AC_MSG_RESULT(yes)
 147         AC_CHECK_LIB([ssl], [MD5_Final], ,
 148         [if test "x$with_openssl" != "xcheck"; then
 149                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 150         fi],
 151         [-lcrypto])],
 152         AC_MSG_RESULT(no))
 153 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$ac_cv_lib_ssl_MD5_Final" = "xyes"])
 154
 155 # Enable or disable usage of libfetch
 156 AC_MSG_CHECKING(whether to link with libfetch)
 157 AS_IF([test "x$with_fetch" != "xno"],
 158         [AC_MSG_RESULT(yes)
 159         AC_CHECK_LIB([fetch], [fetchParseURL], ,
 160         [if test "x$with_fetch" != "xcheck"; then
 161                 AC_MSG_FAILURE([--with-fetch was given, but -lfetch was not found])
 162         fi],
 163         [-lcrypto -ldl])
 164         # Check if libfetch supports connnection caching which we use
 165         AS_IF([test "x$ac_cv_lib_fetch_fetchParseURL" = "xyes"],
 166         [AC_CHECK_DECL(fetchConnectionCacheInit, ,
 167                 AC_MSG_ERROR([libfetch must be version 2.28 or greater]),
 168                 [#include <fetch.h>])
 169         ])
 170         ],
 171         AC_MSG_RESULT(no))
 172 AM_CONDITIONAL([HAVE_LIBFETCH], [test "x$ac_cv_lib_fetch_fetchParseURL" = "xyes"])
 173
 174 # Checks for header files.
 175 AC_CHECK_HEADERS([fcntl.h glob.h libintl.h limits.h locale.h mntent.h string.h strings.h \
 176                   sys/ioctl.h sys/mount.h sys/param.h sys/statvfs.h sys/syslimits.h \
 177                   sys/time.h sys/types.h sys/ucred.h syslog.h wchar.h])
 178
 179 # Checks for typedefs, structures, and compiler characteristics.
 180 AC_C_INLINE
 181 AC_TYPE_MODE_T
 182 AC_TYPE_OFF_T
 183 AC_TYPE_PID_T
 184 AC_TYPE_SIZE_T
 185 AC_STRUCT_TM
 186 AC_TYPE_UID_T
 187 AC_STRUCT_DIRENT_D_TYPE
 188
 189 # Checks for library functions.
 190 AC_FUNC_FORK
 191 AC_FUNC_GETMNTENT
 192 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 193 AC_FUNC_MKTIME
 194 AC_CHECK_FUNCS([geteuid getmntinfo realpath regcomp strcasecmp \
 195                 strndup strrchr strsep swprintf \
 196                 wcwidth uname])
 197 # For the diskspace code
 198 FS_STATS_TYPE
 199 # Enable large file support if available
 200 AC_SYS_LARGEFILE
 201
 202 # Check if we can use symbol visibility support in GCC
 203 GCC_VISIBILITY_CC
 204 # Check if we have -fgnu89-inline flag
 205 GCC_GNU89_INLINE_CC
 206
 207 # Host-dependant definitions
 208 SIZECMD="stat -L -c %s"
 209 SEDINPLACE="sed -i"
 210 STRIP_BINARIES="--strip-all"
 211 STRIP_SHARED="--strip-unneeded"
 212 STRIP_STATIC="--strip-debug"
 213 case "${host_os}" in
 214         *bsd*)
 215                 SIZECMD="stat -L -f %z"
 216                 SEDINPLACE="sed -i ''"
 217                 ;;
 218         cygwin*)
 219                 host_os_cygwin=yes
 220                 CFLAGS="$CFLAGS -DCYGWIN"
 221                 ;;
 222         darwin*)
 223                 host_os_darwin=yes
 224                 SIZECMD="/usr/bin/stat -L -f %z"
 225                 SEDINPLACE="/usr/bin/sed -i ''"
 226                 STRIP_BINARIES=""
 227                 STRIP_SHARED="-S"
 228                 STRIP_STATIC="-S"
 229                 ;;
 230 esac
 231
 232 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 233 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 234 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 235 AC_SUBST(SIZECMD)
 236 AC_SUBST(SEDINPLACE)
 237 AC_SUBST(STRIP_BINARIES)
 238 AC_SUBST(STRIP_SHARED)
 239 AC_SUBST(STRIP_STATIC)
 240
 241 # Check for architecture, used in default makepkg.conf
 242 # (Note single space left after CARCHFLAGS)
 243 case "${host}" in
 244         i686-*)
 245                 CARCH="i686"
 246                 CARCHFLAGS="-march=i686 "
 247                 ;;
 248         x86_64-*)
 249                 CARCH="x86_64"
 250                 CARCHFLAGS="-march=x86-64 "
 251                 ;;
 252         ia64-*)
 253                 CARCH="ia64"
 254                 CARCHFLAGS="-march=ia64 "
 255                 ;;
 256         sparc-*)
 257                 CARCH="sparc"
 258                 CARCHFLAGS="-mcpu=v9 "
 259                 ;;
 260         ppc-* | powerpc-*)
 261                 CARCH="ppc"
 262                 CARCHFLAGS="-mcpu=750 "
 263                 ;;
 264         i386-*)
 265                 CARCH="i386"
 266                 CARCHFLAGS="-march=i386 "
 267                 ;;
 268         arm-*)
 269                 CARCH="arm"
 270                 CARCHFLAGS="-march=armv4 "
 271                 ;;
 272         *)
 273                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 274                 CARCH="unknown"
 275                 CARCHFLAGS=""
 276                 ;;
 277 esac
 278
 279 # Now do some things common to all architectures
 280 CHOST="${host}"
 281 AC_SUBST(CARCH)
 282 AC_SUBST(CARCHFLAGS)
 283 AC_SUBST(CHOST)
 284
 285 # Check for documentation support and status
 286 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 287 AC_MSG_CHECKING([for building documentation])
 288 if test "x$wantdoc" = "xyes" ; then
 289         if test $ASCIIDOC ; then
 290                 AC_MSG_RESULT([yes, enabled by configure])
 291         else
 292                 asciidoc="(warning : asciidoc not installed)"
 293                 AC_MSG_RESULT([yes $asciidoc])
 294         fi
 295         wantdoc=yes
 296 else
 297         AC_MSG_RESULT([no, disabled by configure])
 298         wantdoc=no
 299 fi
 300 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 301
 302 # Check for doxygen support and status
 303 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 304 AC_MSG_CHECKING([for doxygen])
 305 if test "x$wantdoxygen" = "xyes" ; then
 306         if test $DOXYGEN ; then
 307                 AC_MSG_RESULT([yes])
 308                 usedoxygen=yes
 309         else
 310                 AC_MSG_RESULT([no, doxygen missing])
 311                 usedoxygen=no
 312         fi
 313 else
 314         AC_MSG_RESULT([no, disabled by configure])
 315         usedoxygen=no
 316 fi
 317 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 318
 319 # Enable or disable debug code
 320 AC_MSG_CHECKING(for debug mode request)
 321 if test "x$debug" = "xyes" ; then
 322         AC_MSG_RESULT(yes)
 323         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 324         # Check for mcheck
 325         AC_CHECK_HEADERS([mcheck.h])
 326         # Check for -fstack-protector availability
 327         GCC_STACK_PROTECT_LIB
 328         GCC_STACK_PROTECT_CC
 329         GCC_FORTIFY_SOURCE_CC
 330         CFLAGS="$CFLAGS -g -Wall -Werror"
 331 else
 332         AC_MSG_RESULT(no)
 333         CFLAGS="$CFLAGS -Wall"
 334 fi
 335
 336 # Enable or disable use of git version in pacman version string
 337 AC_MSG_CHECKING(whether to use git version if available)
 338 if test "x$wantgitver" = "xyes" ; then
 339         AC_CHECK_PROGS([GIT], [git])
 340         AC_CHECK_FILE([.git/], hasgitdir=yes)
 341         if test $GIT -a "x$hasgitdir" = "xyes"; then
 342                 AC_MSG_RESULT([yes])
 343                 usegitver=yes
 344                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 345         else
 346                 AC_MSG_RESULT([no, git or .git dir missing])
 347                 usegitver=no
 348         fi
 349 else
 350         AC_MSG_RESULT([no, disabled by configure])
 351         usegitver=no
 352 fi
 353 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 354
 355 # Set root directory
 356 AC_SUBST(ROOTDIR)
 357 # Set package file extension
 358 AC_SUBST(PKGEXT)
 359 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 360 # Set source package file extension
 361 AC_SUBST(SRCEXT)
 362 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 363 # Set makepkg build script name
 364 AC_SUBST(BUILDSCRIPT)
 365 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 366
 367 # Configuration files
 368 AC_CONFIG_FILES([
 369 lib/libalpm/Makefile
 370 lib/libalpm/po/Makefile.in
 371 src/pacman/Makefile
 372 src/util/Makefile
 373 scripts/Makefile
 374 doc/Makefile
 375 etc/Makefile
 376 po/Makefile.in
 377 test/pacman/Makefile
 378 test/pacman/tests/Makefile
 379 test/util/Makefile
 380 contrib/Makefile
 381 Makefile
 382 ])
 383 AC_OUTPUT
 384
 385 echo "
 386 ${PACKAGE_NAME}:
 387
 388   Build information:
 389     source code location   : ${srcdir}
 390     prefix                 : ${prefix}
 391     sysconfdir             : $(eval echo ${sysconfdir})
 392        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 393     localstatedir          : $(eval echo ${localstatedir})
 394        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 395        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 396     compiler               : ${CC}
 397     compiler flags         : ${CFLAGS}
 398     defines                : ${DEFS}
 399
 400     Architecture           : ${CARCH}
 401     Architecture flags     : ${CARCHFLAGS}
 402     Host Type              : ${CHOST}
 403     Filesize command       : ${SIZECMD}
 404     In-place sed command   : ${SEDINPLACE}
 405
 406     libalpm version        : ${LIB_VERSION}
 407     libalpm version info   : ${LIB_VERSION_INFO}
 408     pacman version         : ${PACKAGE_VERSION}
 409     using git version      : ${usegitver}
 410
 411   Directory and file information:
 412     root working directory : ${ROOTDIR}
 413     package extension      : ${PKGEXT}
 414     source pkg extension   : ${SRCEXT}
 415     build script name      : ${BUILDSCRIPT}
 416
 417   Compilation options:
 418     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 419     Doxygen support        : ${usedoxygen}
 420     debug support          : ${debug}
 421 "
 422
 423 # vim:set ts=2 sw=2 noet: