configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.60)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [3])
  45 m4_define([lib_revision], [0])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [2])
  50 m4_define([pacman_version_micro], [0])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of pacman's root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for database extension
  87 AC_ARG_WITH(db-ext,
  88         AS_HELP_STRING([--with-db-ext=ext], [set the file extension used by the database]),
  89         [DBEXT=$withval], [DBEXT=.db.tar.gz])
  90
  91 # Help line for libdownload/libfetch
  92 AC_ARG_ENABLE(internal-download,
  93         AS_HELP_STRING([--disable-internal-download], [do not build with libdownload/libfetch support]),
  94         [internaldownload=$enableval], [internaldownload=yes])
  95
  96 # Help line for documentation
  97 AC_ARG_ENABLE(doc,
  98         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
  99         [wantdoc=$enableval], [wantdoc=yes])
 100
 101 # Help line for doxygen
 102 AC_ARG_ENABLE(doxygen,
 103         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 104         [wantdoxygen=$enableval], [wantdoxygen=no])
 105
 106 # Help line for asciidoc
 107 AC_ARG_ENABLE(asciidoc,
 108         AS_HELP_STRING([--enable-asciidoc], [build your own manpages with Asciidoc]),
 109         [wantasciidoc=$enableval], [wantasciidoc=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Checks for programs.
 123 AC_PROG_AWK
 124 AC_PROG_CC_C99
 125 AC_PROG_INSTALL
 126 AC_PROG_LN_S
 127 AC_PROG_MAKE_SET
 128 AC_PROG_LIBTOOL
 129 AC_CHECK_PROGS([PYTHON], [python2.5 python2.4 python], [false])
 130
 131 # find installed gettext
 132 AM_GNU_GETTEXT([external])
 133 AM_GNU_GETTEXT_VERSION(0.13.1)
 134
 135 # Check for libarchive
 136 AC_CHECK_LIB([archive], [archive_read_data], ,
 137         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 138
 139 # Enable or disable usage of libdownload/libfetch
 140 # - this is a nested check- first see if we need a library, if we do then
 141 #   check for libdownload first, then fallback to libfetch, then die
 142 AC_MSG_CHECKING(whether to link with download library)
 143 if test "x$internaldownload" = "xyes" ; then
 144         AC_MSG_RESULT(yes)
 145         AC_DEFINE([INTERNAL_DOWNLOAD], , [Use internal download library])
 146         # Check for a download library if it was actually requested
 147         AC_CHECK_LIB([download], [downloadParseURL], ,
 148                 AC_CHECK_LIB([fetch], [fetchParseURL], ,
 149                         AC_MSG_ERROR([libdownload or libfetch are needed to compile with internal download support])) )
 150 else
 151         AC_MSG_RESULT(no)
 152 fi
 153 AM_CONDITIONAL(INTERNAL_DOWNLOAD, test "x$internaldownload" = "xyes")
 154
 155 # Checks for header files.
 156 AC_CHECK_HEADERS([fcntl.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/param.h sys/statvfs.h sys/syslimits.h sys/time.h syslog.h wchar.h])
 157
 158 # Checks for typedefs, structures, and compiler characteristics.
 159 AC_C_INLINE
 160 AC_TYPE_MODE_T
 161 AC_TYPE_OFF_T
 162 AC_TYPE_PID_T
 163 AC_TYPE_SIZE_T
 164 AC_STRUCT_TM
 165 AC_TYPE_UID_T
 166
 167 # Checks for library functions.
 168 AC_FUNC_FORK
 169 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 170 AC_FUNC_MKTIME
 171 AC_TYPE_SIGNAL
 172 AC_CHECK_FUNCS([geteuid realpath regcomp strcasecmp \
 173                 strndup strrchr strsep swprintf \
 174                 wcwidth uname])
 175
 176 # Enable large file support if available
 177 AC_SYS_LARGEFILE
 178
 179 # Check if we can use symbol visibility support in GCC
 180 GCC_VISIBILITY_CC
 181 # Check if we have -fgnu89-inline flag
 182 GCC_GNU89_INLINE_CC
 183
 184 # Host-dependant definitions
 185 SIZECMD="stat -c %s"
 186 case "${host_os}" in
 187         *bsd*)
 188                 SIZECMD="stat -f %z"
 189                 ;;
 190         cygwin*)
 191                 host_os_cygwin=yes
 192                 CFLAGS="$CFLAGS -DCYGWIN"
 193                 ;;
 194         darwin*)
 195                 host_os_darwin=yes
 196                 SIZECMD="stat -f %z"
 197                 ;;
 198 esac
 199
 200 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 201 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 202 AC_SUBST(SIZECMD)
 203
 204 # Check for architecture, used in default makepkg.conf
 205 # (Note single space left after CARCHFLAGS)
 206 case "${host}" in
 207         i686-*)
 208                 CARCH="i686"
 209                 CARCHFLAGS="-march=i686 "
 210                 ;;
 211         x86_64-*)
 212                 CARCH="x86_64"
 213                 CARCHFLAGS="-march=x86-64 "
 214                 ;;
 215         ia64-*)
 216                 CARCH="ia64"
 217                 CARCHFLAGS="-march=ia64 "
 218                 ;;
 219         sparc-*)
 220                 CARCH="sparc"
 221                 CARCHFLAGS="-mcpu=v9 "
 222                 ;;
 223         ppc-* | powerpc-*)
 224                 CARCH="ppc"
 225                 CARCHFLAGS="-mcpu=750 "
 226                 ;;
 227         i386-*)
 228                 CARCH="i386"
 229                 CARCHFLAGS="-march=i386 "
 230                 ;;
 231         arm-*)
 232                 CARCH="arm"
 233                 CARCHFLAGS="-march=armv4 "
 234                 ;;
 235         *)
 236                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 237                 CARCH="unknown"
 238                 CARCHFLAGS=""
 239                 ;;
 240 esac
 241
 242 # Now do some things common to all architectures
 243 CHOST="${host}"
 244 AC_SUBST(CARCH)
 245 AC_SUBST(CARCHFLAGS)
 246 AC_SUBST(CHOST)
 247
 248 # Check for documentation support and status
 249 AC_MSG_CHECKING([for building documentation])
 250 if test "x$wantdoc" = "xyes" ; then
 251         AC_MSG_RESULT([yes])
 252         wantdoc=yes
 253 else
 254         AC_MSG_RESULT([no, disabled by configure])
 255         wantdoc=no
 256 fi
 257 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 258
 259 # Check for doxygen support and status
 260 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 261 AC_MSG_CHECKING([for doxygen])
 262 if test "x$wantdoxygen" = "xyes" ; then
 263         if test $DOXYGEN ; then
 264                 AC_MSG_RESULT([yes])
 265                 usedoxygen=yes
 266         else
 267                 AC_MSG_RESULT([no, doxygen missing])
 268                 usedoxygen=no
 269         fi
 270 else
 271         AC_MSG_RESULT([no, disabled by configure])
 272         usedoxygen=no
 273 fi
 274 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 275
 276 # Check for asciidoc support and status
 277 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 278 AC_MSG_CHECKING([for asciidoc])
 279 if test "x$wantasciidoc" = "xyes" ; then
 280         if test $ASCIIDOC ; then
 281                 AC_MSG_RESULT([yes])
 282                 useasciidoc=yes
 283         else
 284                 AC_MSG_RESULT([no, asciidoc missing])
 285                 useasciidoc=no
 286         fi
 287 else
 288         AC_MSG_RESULT([no, disabled by configure])
 289         useasciidoc=no
 290 fi
 291 AM_CONDITIONAL(USE_ASCIIDOC, test "x$useasciidoc" = "xyes")
 292
 293 # Enable or disable debug code
 294 AC_MSG_CHECKING(for debug mode request)
 295 if test "x$debug" = "xyes" ; then
 296         AC_MSG_RESULT(yes)
 297         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 298         # Check for mcheck
 299         AC_CHECK_HEADERS([mcheck.h])
 300         # Check for -fstack-protector availability
 301         GCC_STACK_PROTECT_LIB
 302         GCC_STACK_PROTECT_CC
 303         CFLAGS="$CFLAGS -Wall -Werror"
 304 else
 305         AC_MSG_RESULT(no)
 306         CFLAGS="$CFLAGS -Wall"
 307 fi
 308
 309 # Enable or disable use of git version in pacman version string
 310 AC_CHECK_PROGS([GIT], [git])
 311 AC_CHECK_FILE([.git/], hasgitdir=yes)
 312 AC_MSG_CHECKING(whether to use git version if available)
 313 if test "x$wantgitver" = "xyes" ; then
 314         if test $GIT -a "x$hasgitdir" = "xyes"; then
 315                 AC_MSG_RESULT([yes])
 316                 usegitver=yes
 317                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 318         else
 319                 AC_MSG_RESULT([no, git or .git dir missing])
 320                 usegitver=no
 321         fi
 322 else
 323         AC_MSG_RESULT([no, disabled by configure])
 324         usegitver=no
 325 fi
 326 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 327
 328 # Set root directory
 329 AC_SUBST(ROOTDIR)
 330 # Set package file extension
 331 AC_SUBST(PKGEXT)
 332 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 333 # Set source package file extension
 334 AC_SUBST(SRCEXT)
 335 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 336 # Set database file extension
 337 AC_SUBST(DBEXT)
 338 AC_DEFINE_UNQUOTED([DBEXT], "$DBEXT", [The file extension used by pacman databases])
 339
 340 # Configuration files
 341 AC_CONFIG_FILES([
 342 lib/libalpm/Makefile
 343 lib/libalpm/po/Makefile.in
 344 src/pacman/Makefile
 345 src/util/Makefile
 346 scripts/Makefile
 347 doc/Makefile
 348 etc/Makefile
 349 po/Makefile.in
 350 pactest/Makefile
 351 contrib/Makefile
 352 Makefile
 353 ])
 354 AC_OUTPUT
 355
 356 echo "
 357 ${PACKAGE_NAME}:
 358
 359   Build information:
 360     source code location   : ${srcdir}
 361     prefix                 : ${prefix}
 362     sysconfdir             : $(eval echo ${sysconfdir})
 363        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 364     localstatedir          : $(eval echo ${localstatedir})
 365        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 366        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 367     compiler               : ${CC}
 368     compiler flags         : ${CFLAGS}
 369     defines                : ${DEFS}
 370
 371     Architecture           : ${CARCH}
 372     Architecture flags     : ${CARCHFLAGS}
 373     Host Type              : ${CHOST}
 374     Filesize command       : ${SIZECMD}
 375
 376     libalpm version        : ${LIB_VERSION}
 377     libalpm version info   : ${LIB_VERSION_INFO}
 378     pacman version         : ${PACKAGE_VERSION}
 379     using git version      : ${usegitver}
 380
 381   Directory and file information:
 382     root working directory : ${ROOTDIR}
 383     package extension      : ${PKGEXT}
 384     source pkg extension   : ${SRCEXT}
 385     database extension     : ${DBEXT}
 386
 387   Compilation options:
 388     Run make in doc/ dir   : ${wantdoc}
 389     Use download library   : ${internaldownload}
 390     Doxygen support        : ${usedoxygen}
 391     Asciidoc support       : ${useasciidoc}
 392     debug support          : ${debug}
 393 "
 394
 395 # vim:set ts=2 sw=2 noet: