configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [7])
  45 m4_define([lib_revision], [1])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [4])
  49 m4_define([pacman_version_minor], [0])
  50 m4_define([pacman_version_micro], [1])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for buildscript filename
  87 AC_ARG_WITH(buildscript,
  88         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  89         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  90
  91 # Help line for using OpenSSL
  92 AC_ARG_WITH(openssl,
  93         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  94         [], [with_openssl=check])
  95
  96 # Help line for using gpgme
  97 AC_ARG_WITH(gpgme,
  98         AS_HELP_STRING([--with-gpgme], [use GPGME for PGP signature verification]),
  99         [], [with_gpgme=check])
 100
 101 # Check for useable libcurl
 102 LIBCURL_CHECK_CONFIG([yes], [7.19.4], [with_libcurl=yes], [with_libcurl=no])
 103
 104 # Help line for documentation
 105 AC_ARG_ENABLE(doc,
 106         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 107         [wantdoc=$enableval], [wantdoc=yes])
 108
 109 # Help line for doxygen
 110 AC_ARG_ENABLE(doxygen,
 111         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 112         [wantdoxygen=$enableval], [wantdoxygen=no])
 113
 114 # Help line for debug
 115 AC_ARG_ENABLE(debug,
 116         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 117         [debug=$enableval], [debug=no])
 118
 119 # Help line for using git version in pacman version string
 120 AC_ARG_ENABLE(git-version,
 121         AS_HELP_STRING([--enable-git-version],
 122                 [enable use of git version in version string if available]),
 123         [wantgitver=$enableval], [wantgitver=no])
 124
 125 # Checks for programs.
 126 AC_PROG_AWK
 127 AC_PROG_CC_C99
 128 AC_PROG_CXX
 129 AC_PROG_INSTALL
 130 AC_PROG_LN_S
 131 AC_PROG_MAKE_SET
 132 AC_PROG_LIBTOOL
 133 AC_PROG_RANLIB
 134 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 135 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 136
 137 # find installed gettext
 138 AM_GNU_GETTEXT([external], [need-ngettext])
 139 AM_GNU_GETTEXT_VERSION(0.13.1)
 140
 141 AC_CHECK_LIB([m], [fabs], ,
 142         AC_MSG_ERROR([libm is needed to compile pacman!]))
 143
 144 # Check for libarchive
 145 AC_CHECK_LIB([archive], [archive_read_data], ,
 146         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 147
 148 # Check for OpenSSL
 149 AC_MSG_CHECKING(whether to link with libssl)
 150 AS_IF([test "x$with_openssl" != "xno"],
 151         [AC_MSG_RESULT(yes)
 152         AC_CHECK_LIB([ssl], [MD5_Final], ,
 153         [if test "x$with_openssl" != "xcheck"; then
 154                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 155         fi],
 156         [-lcrypto])
 157         with_openssl=$ac_cv_lib_ssl_MD5_Final],
 158         AC_MSG_RESULT(no))
 159 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$with_openssl" = "xyes"])
 160
 161 # Check for gpgme
 162 AC_MSG_CHECKING(whether to link with libgpgme)
 163 AS_IF([test "x$with_gpgme" != "xno"],
 164         [AC_MSG_RESULT(yes)
 165         AC_CHECK_LIB([gpgme], [gpgme_check_version], ,
 166         [if test "x$with_gpgme" != "xcheck"; then
 167                 AC_MSG_FAILURE([--with-ggpme was given, but -lgpgme was not found])
 168         fi],
 169         [-lgpgme])
 170         with_gpgme=$ac_cv_lib_gpgme_gpgme_check_version],
 171         AC_MSG_RESULT(no))
 172 AM_CONDITIONAL([HAVE_LIBGPGME], [test "x$with_gpgme" = "xyes"])
 173
 174 # Checks for header files.
 175 AC_CHECK_HEADERS([fcntl.h float.h glob.h libintl.h limits.h locale.h \
 176                   mntent.h stddef.h string.h sys/ioctl.h sys/mount.h \
 177                   sys/param.h sys/statvfs.h sys/time.h sys/types.h \
 178                   sys/ucred.h syslog.h termios.h wchar.h])
 179
 180 # Checks for typedefs, structures, and compiler characteristics.
 181 AC_C_INLINE
 182 AC_TYPE_INT64_T
 183 AC_TYPE_MODE_T
 184 AC_TYPE_OFF_T
 185 AC_TYPE_PID_T
 186 AC_TYPE_SIZE_T
 187 AC_TYPE_SSIZE_T
 188 AC_STRUCT_TM
 189 AC_TYPE_UID_T
 190 AC_STRUCT_DIRENT_D_TYPE
 191 PATH_MAX_DEFINED
 192
 193 # Checks for library functions.
 194 AC_FUNC_FORK
 195 AC_FUNC_GETMNTENT
 196 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 197 AC_FUNC_MALLOC
 198 AC_FUNC_MKTIME
 199 AC_FUNC_STRCOLL
 200 AC_CHECK_FUNCS([dup2 getcwd geteuid getmntinfo gettimeofday memmove memset \
 201                 mkdir realpath regcomp rmdir setenv setlocale strcasecmp \
 202                 strchr strcspn strdup strerror strndup strrchr strsep strstr \
 203                 strtol swprintf tcflush wcwidth uname])
 204 AC_CHECK_MEMBERS([struct stat.st_blksize],,,[[#include <sys/stat.h>]])
 205
 206 # For the diskspace code
 207 FS_STATS_TYPE
 208 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 209 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 210                   #include <sys/mount.h>]])
 211
 212 # Enable large file support if available
 213 AC_SYS_LARGEFILE
 214
 215 # Check if we can use symbol visibility support in GCC
 216 GCC_VISIBILITY_CC
 217 # Check if we have -fgnu89-inline flag
 218 GCC_GNU89_INLINE_CC
 219
 220 # Host-dependant definitions
 221 SIZECMD="stat -L -c %s"
 222 SEDINPLACE="sed -i"
 223 STRIP_BINARIES="--strip-all"
 224 STRIP_SHARED="--strip-unneeded"
 225 STRIP_STATIC="--strip-debug"
 226 case "${host_os}" in
 227         *bsd*)
 228                 SIZECMD="stat -L -f %z"
 229                 SEDINPLACE="sed -i \"\""
 230                 ;;
 231         cygwin*)
 232                 host_os_cygwin=yes
 233                 CFLAGS="$CFLAGS -DCYGWIN"
 234                 ;;
 235         darwin*)
 236                 host_os_darwin=yes
 237                 SIZECMD="/usr/bin/stat -L -f %z"
 238                 SEDINPLACE="/usr/bin/sed -i ''"
 239                 STRIP_BINARIES=""
 240                 STRIP_SHARED="-S"
 241                 STRIP_STATIC="-S"
 242                 ;;
 243 esac
 244
 245 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 246 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 247 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 248 AC_SUBST(SIZECMD)
 249 AC_SUBST(SEDINPLACE)
 250 AC_SUBST(STRIP_BINARIES)
 251 AC_SUBST(STRIP_SHARED)
 252 AC_SUBST(STRIP_STATIC)
 253
 254 # Variables plugged into makepkg.conf
 255 CARCH="${host%%-*}"
 256 CHOST="${host}"
 257 AC_SUBST(CARCH)
 258 AC_SUBST(CHOST)
 259
 260 # Check for documentation support and status
 261 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 262 AC_MSG_CHECKING([for building documentation])
 263 if test "x$wantdoc" = "xyes" ; then
 264         if test $ASCIIDOC ; then
 265                 AC_MSG_RESULT([yes, enabled by configure])
 266         else
 267                 asciidoc="(warning : asciidoc not installed)"
 268                 AC_MSG_RESULT([yes $asciidoc])
 269         fi
 270         wantdoc=yes
 271 else
 272         AC_MSG_RESULT([no, disabled by configure])
 273         wantdoc=no
 274 fi
 275 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 276
 277 # Check for doxygen support and status
 278 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 279 AC_MSG_CHECKING([for doxygen])
 280 if test "x$wantdoxygen" = "xyes" ; then
 281         if test $DOXYGEN ; then
 282                 AC_MSG_RESULT([yes])
 283                 usedoxygen=yes
 284         else
 285                 AC_MSG_RESULT([no, doxygen missing])
 286                 usedoxygen=no
 287         fi
 288 else
 289         AC_MSG_RESULT([no, disabled by configure])
 290         usedoxygen=no
 291 fi
 292 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 293
 294 # Enable or disable debug code
 295 AC_MSG_CHECKING(for debug mode request)
 296 if test "x$debug" = "xyes" ; then
 297         AC_MSG_RESULT(yes)
 298         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 299         # Check for -fstack-protector availability
 300         GCC_STACK_PROTECT_LIB
 301         GCC_STACK_PROTECT_CC
 302         GCC_FORTIFY_SOURCE_CC
 303         CFLAGS="$CFLAGS -g -Wall -Werror"
 304 else
 305         AC_MSG_RESULT(no)
 306         CFLAGS="$CFLAGS -Wall"
 307 fi
 308
 309 # Enable or disable use of git version in pacman version string
 310 AC_MSG_CHECKING(whether to use git version if available)
 311 if test "x$wantgitver" = "xyes" ; then
 312         AC_CHECK_PROGS([GIT], [git])
 313         AC_CHECK_FILE([.git/], hasgitdir=yes)
 314         if test $GIT -a "x$hasgitdir" = "xyes"; then
 315                 AC_MSG_RESULT([yes])
 316                 usegitver=yes
 317                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 318         else
 319                 AC_MSG_RESULT([no, git or .git dir missing])
 320                 usegitver=no
 321         fi
 322 else
 323         AC_MSG_RESULT([no, disabled by configure])
 324         usegitver=no
 325 fi
 326 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 327
 328 # Set root directory
 329 AC_SUBST(ROOTDIR)
 330 # Set package file extension
 331 AC_SUBST(PKGEXT)
 332 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 333 # Set source package file extension
 334 AC_SUBST(SRCEXT)
 335 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 336 # Set makepkg build script name
 337 AC_SUBST(BUILDSCRIPT)
 338 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 339
 340 # Configuration files
 341 AC_CONFIG_FILES([
 342 lib/libalpm/Makefile
 343 lib/libalpm/po/Makefile.in
 344 src/pacman/Makefile
 345 src/pacman/po/Makefile.in
 346 src/util/Makefile
 347 scripts/Makefile
 348 scripts/po/Makefile.in
 349 doc/Makefile
 350 etc/Makefile
 351 test/pacman/Makefile
 352 test/pacman/tests/Makefile
 353 test/util/Makefile
 354 contrib/Makefile
 355 Makefile
 356 ])
 357 AC_OUTPUT
 358
 359 echo "
 360 ${PACKAGE_NAME}:
 361
 362   Build information:
 363     source code location   : ${srcdir}
 364     prefix                 : ${prefix}
 365     sysconfdir             : $(eval echo ${sysconfdir})
 366        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 367     localstatedir          : $(eval echo ${localstatedir})
 368        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 369        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 370
 371     compiler               : ${CC}
 372     preprocessor flags     : ${CPPFLAGS}
 373     compiler flags         : ${CFLAGS}
 374     defines                : ${DEFS}
 375     library flags          : ${LIBS}
 376     linker flags           : ${LDFLAGS}
 377
 378     Architecture           : ${CARCH}
 379     Host Type              : ${CHOST}
 380     Filesize command       : ${SIZECMD}
 381     In-place sed command   : ${SEDINPLACE}
 382
 383     libalpm version        : ${LIB_VERSION}
 384     libalpm version info   : ${LIB_VERSION_INFO}
 385     pacman version         : ${PACKAGE_VERSION}
 386     using git version      : ${usegitver}
 387
 388   Directory and file information:
 389     root working directory : ${ROOTDIR}
 390     package extension      : ${PKGEXT}
 391     source pkg extension   : ${SRCEXT}
 392     build script name      : ${BUILDSCRIPT}
 393
 394   Compilation options:
 395     Use libcurl            : ${with_libcurl}
 396     Use GPGME              : ${with_gpgme}
 397     Use OpenSSL            : ${with_openssl}
 398     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 399     Doxygen support        : ${usedoxygen}
 400     debug support          : ${debug}
 401 "
 402
 403 # vim:set ts=2 sw=2 noet: