configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.60)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [5])
  45 m4_define([lib_revision], [1])
  46 m4_define([lib_age], [3])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [1])
  50 m4_define([pacman_version_micro], [4])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of pacman's root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for database extension
  87 AC_ARG_WITH(db-ext,
  88         AS_HELP_STRING([--with-db-ext=ext], [set the file extension used by the database]),
  89         [DBEXT=$withval], [DBEXT=.db.tar.gz])
  90
  91 # Help line for libdownload/libfetch
  92 AC_ARG_ENABLE(internal-download,
  93         AS_HELP_STRING([--disable-internal-download], [do not build with libdownload/libfetch support]),
  94         [internaldownload=$enableval], [internaldownload=yes])
  95
  96 # Help line for documentation
  97 AC_ARG_ENABLE(doc,
  98         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
  99         [wantdoc=$enableval], [wantdoc=yes])
 100
 101 # Help line for doxygen
 102 AC_ARG_ENABLE(doxygen,
 103         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 104         [wantdoxygen=$enableval], [wantdoxygen=no])
 105
 106 # Help line for asciidoc
 107 AC_ARG_ENABLE(asciidoc,
 108         AS_HELP_STRING([--enable-asciidoc], [build your own manpages with Asciidoc]),
 109         [wantasciidoc=$enableval], [wantasciidoc=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Checks for programs.
 123 AC_PROG_AWK
 124 AC_PROG_CC_C99
 125 AC_PROG_INSTALL
 126 AC_PROG_LN_S
 127 AC_PROG_MAKE_SET
 128 AC_PROG_LIBTOOL
 129 AC_CHECK_PROGS([PYTHON], [python2.5 python2.4 python], [false])
 130
 131 # find installed gettext
 132 AM_GNU_GETTEXT([external])
 133 AM_GNU_GETTEXT_VERSION(0.13.1)
 134
 135 # Check for libarchive
 136 AC_CHECK_LIB([archive], [archive_read_data], ,
 137         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 138
 139 # Enable or disable usage of libdownload/libfetch
 140 # - this is a nested check- first see if we need a library, if we do then
 141 #   check for libdownload first, then fallback to libfetch, then die
 142 AC_MSG_CHECKING(whether to link with download library)
 143 if test "x$internaldownload" = "xyes" ; then
 144         AC_MSG_RESULT(yes)
 145         AC_DEFINE([INTERNAL_DOWNLOAD], , [Use internal download library])
 146         # Check for a download library if it was actually requested
 147         AC_CHECK_LIB([download], [downloadParseURL], ,
 148                 AC_CHECK_LIB([fetch], [fetchParseURL], ,
 149                         AC_MSG_ERROR([libdownload or libfetch are needed to compile with internal download support])) )
 150 else
 151         AC_MSG_RESULT(no)
 152 fi
 153 AM_CONDITIONAL(INTERNAL_DOWNLOAD, test "x$internaldownload" = "xyes")
 154
 155 # Checks for header files.
 156 AC_CHECK_HEADERS([fcntl.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/param.h sys/statvfs.h sys/syslimits.h sys/time.h syslog.h wchar.h])
 157
 158 # Checks for typedefs, structures, and compiler characteristics.
 159 AC_C_INLINE
 160 AC_TYPE_MODE_T
 161 AC_TYPE_OFF_T
 162 AC_TYPE_PID_T
 163 AC_TYPE_SIZE_T
 164 AC_STRUCT_TM
 165 AC_TYPE_UID_T
 166
 167 # Checks for library functions.
 168 AC_FUNC_FORK
 169 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 170 AC_FUNC_MKTIME
 171 AC_TYPE_SIGNAL
 172 AC_CHECK_FUNCS([geteuid realpath regcomp strcasecmp \
 173                 strndup strrchr strsep swprintf \
 174                 wcwidth uname])
 175
 176 # Enable large file support if available
 177 AC_SYS_LARGEFILE
 178
 179 # Check if we can use symbol visibility support in GCC
 180 GCC_VISIBILITY_CC
 181 # Check if we have -fgnu89-inline flag
 182 GCC_GNU89_INLINE_CC
 183
 184 # Host-dependant definitions
 185 case "${host_os}" in
 186         cygwin*)
 187                 host_os_cygwin=yes
 188                 CFLAGS="$CFLAGS -DCYGWIN"
 189                 ;;
 190         darwin*)
 191                 host_os_darwin=yes
 192                 ;;
 193 esac
 194
 195 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 196 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 197
 198 # Check for architecture, used in default makepkg.conf
 199 # (Note single space left after CARCHFLAGS)
 200 case "${host}" in
 201         i686-*)
 202                 CARCH="i686"
 203                 CARCHFLAGS="-march=i686 "
 204                 ;;
 205         x86_64-*)
 206                 CARCH="x86_64"
 207                 CARCHFLAGS="-march=x86-64 "
 208                 ;;
 209         ia64-*)
 210                 CARCH="ia64"
 211                 CARCHFLAGS="-march=ia64 "
 212                 ;;
 213         sparc-*)
 214                 CARCH="sparc"
 215                 CARCHFLAGS="-mcpu=v9 "
 216                 ;;
 217         ppc-* | powerpc-*)
 218                 CARCH="ppc"
 219                 CARCHFLAGS="-mcpu=750 "
 220                 ;;
 221         i386-*)
 222                 CARCH="i386"
 223                 CARCHFLAGS="-march=i386 "
 224                 ;;
 225         arm-*)
 226                 CARCH="arm"
 227                 CARCHFLAGS="-march=armv4 "
 228                 ;;
 229         *)
 230                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 231                 CARCH="unknown"
 232                 CARCHFLAGS=""
 233                 ;;
 234 esac
 235
 236 # Now do some things common to all architectures
 237 CHOST="${host}"
 238 AC_SUBST(CARCH)
 239 AC_SUBST(CARCHFLAGS)
 240 AC_SUBST(CHOST)
 241
 242 # Check for documentation support and status
 243 AC_MSG_CHECKING([for building documentation])
 244 if test "x$wantdoc" = "xyes" ; then
 245         AC_MSG_RESULT([yes])
 246         wantdoc=yes
 247 else
 248         AC_MSG_RESULT([no, disabled by configure])
 249         wantdoc=no
 250 fi
 251 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 252
 253 # Check for doxygen support and status
 254 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 255 AC_MSG_CHECKING([for doxygen])
 256 if test "x$wantdoxygen" = "xyes" ; then
 257         if test $DOXYGEN ; then
 258                 AC_MSG_RESULT([yes])
 259                 usedoxygen=yes
 260         else
 261                 AC_MSG_RESULT([no, doxygen missing])
 262                 usedoxygen=no
 263         fi
 264 else
 265         AC_MSG_RESULT([no, disabled by configure])
 266         usedoxygen=no
 267 fi
 268 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 269
 270 # Check for asciidoc support and status
 271 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 272 AC_MSG_CHECKING([for asciidoc])
 273 if test "x$wantasciidoc" = "xyes" ; then
 274         if test $ASCIIDOC ; then
 275                 AC_MSG_RESULT([yes])
 276                 useasciidoc=yes
 277         else
 278                 AC_MSG_RESULT([no, asciidoc missing])
 279                 useasciidoc=no
 280         fi
 281 else
 282         AC_MSG_RESULT([no, disabled by configure])
 283         useasciidoc=no
 284 fi
 285 AM_CONDITIONAL(USE_ASCIIDOC, test "x$useasciidoc" = "xyes")
 286
 287 # Enable or disable debug code
 288 AC_MSG_CHECKING(for debug mode request)
 289 if test "x$debug" = "xyes" ; then
 290         AC_MSG_RESULT(yes)
 291         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 292         # Check for mcheck
 293         AC_CHECK_HEADERS([mcheck.h])
 294         # Check for -fstack-protector availability
 295         GCC_STACK_PROTECT_LIB
 296         GCC_STACK_PROTECT_CC
 297         CFLAGS="$CFLAGS -Wall -Werror"
 298 else
 299         AC_MSG_RESULT(no)
 300         CFLAGS="$CFLAGS -Wall"
 301 fi
 302
 303 # Enable or disable use of git version in pacman version string
 304 AC_CHECK_PROGS([GIT], [git])
 305 AC_CHECK_FILE([.git/], hasgitdir=yes)
 306 AC_MSG_CHECKING(whether to use git version if available)
 307 if test "x$wantgitver" = "xyes" ; then
 308         if test $GIT -a "x$hasgitdir" = "xyes"; then
 309                 AC_MSG_RESULT([yes])
 310                 usegitver=yes
 311                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 312         else
 313                 AC_MSG_RESULT([no, git or .git dir missing])
 314                 usegitver=no
 315         fi
 316 else
 317         AC_MSG_RESULT([no, disabled by configure])
 318         usegitver=no
 319 fi
 320 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 321
 322 # Set root directory
 323 AC_SUBST(ROOTDIR)
 324 # Set package file extension
 325 AC_SUBST(PKGEXT)
 326 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 327 # Set source package file extension
 328 AC_SUBST(SRCEXT)
 329 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 330 # Set database file extension
 331 AC_SUBST(DBEXT)
 332 AC_DEFINE_UNQUOTED([DBEXT], "$DBEXT", [The file extension used by pacman databases])
 333
 334 # Configuration files
 335 AC_CONFIG_FILES([
 336 lib/libalpm/Makefile
 337 lib/libalpm/po/Makefile.in
 338 src/pacman/Makefile
 339 src/util/Makefile
 340 scripts/Makefile
 341 doc/Makefile
 342 etc/Makefile
 343 po/Makefile.in
 344 pactest/Makefile
 345 contrib/Makefile
 346 Makefile
 347 ])
 348 AC_OUTPUT
 349
 350 echo "
 351 ${PACKAGE_NAME}:
 352
 353   Build information:
 354     source code location   : ${srcdir}
 355     prefix                 : ${prefix}
 356     sysconfdir             : $(eval echo ${sysconfdir})
 357        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 358     localstatedir          : $(eval echo ${localstatedir})
 359        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 360        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 361     compiler               : ${CC}
 362     compiler flags         : ${CFLAGS}
 363     defines                : ${DEFS}
 364
 365     Architecture           : ${CARCH}
 366     Architecture flags     : ${CARCHFLAGS}
 367     Host Type              : ${CHOST}
 368
 369     libalpm version        : ${LIB_VERSION}
 370     libalpm version info   : ${LIB_VERSION_INFO}
 371     pacman version         : ${PACKAGE_VERSION}
 372     using git version      : ${usegitver}
 373
 374   Directory and file information:
 375     root working directory : ${ROOTDIR}
 376     package extension      : ${PKGEXT}
 377     source pkg extension   : ${SRCEXT}
 378     database extension     : ${DBEXT}
 379
 380   Compilation options:
 381     Run make in doc/ dir   : ${wantdoc}
 382     Use download library   : ${internaldownload}
 383     Doxygen support        : ${usedoxygen}
 384     Asciidoc support       : ${useasciidoc}
 385     debug support          : ${debug}
 386 "
 387
 388 # vim:set ts=2 sw=2 noet: