configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [6])
  45 m4_define([lib_revision], [3])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [5])
  50 m4_define([pacman_version_micro], [3])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for buildscript filename
  87 AC_ARG_WITH(buildscript,
  88         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  89         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  90
  91 # Help line for using OpenSSL
  92 AC_ARG_WITH(openssl,
  93         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  94         [], [with_openssl=check])
  95
  96 # Help line for libfetch
  97 AC_ARG_WITH(fetch,
  98         AS_HELP_STRING([--with-fetch], [use libfetch as an internal downloader]),
  99         [], [with_fetch=check])
 100
 101 # Help line for documentation
 102 AC_ARG_ENABLE(doc,
 103         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 104         [wantdoc=$enableval], [wantdoc=yes])
 105
 106 # Help line for doxygen
 107 AC_ARG_ENABLE(doxygen,
 108         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 109         [wantdoxygen=$enableval], [wantdoxygen=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Checks for programs.
 123 AC_PROG_AWK
 124 AC_PROG_CC_C99
 125 AC_PROG_INSTALL
 126 AC_PROG_LN_S
 127 AC_PROG_MAKE_SET
 128 AC_PROG_LIBTOOL
 129 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 130 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 131
 132 # find installed gettext
 133 AM_GNU_GETTEXT([external])
 134 AM_GNU_GETTEXT_VERSION(0.13.1)
 135
 136 # Check for libarchive
 137 AC_CHECK_LIB([archive], [archive_read_data], ,
 138         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 139
 140 # Check for OpenSSL
 141 AC_MSG_CHECKING(whether to link with libssl)
 142 AS_IF([test "x$with_openssl" != "xno"],
 143         [AC_MSG_RESULT(yes)
 144         AC_CHECK_LIB([ssl], [MD5_Final], ,
 145         [if test "x$with_openssl" != "xcheck"; then
 146                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 147         fi],
 148         [-lcrypto])],
 149         AC_MSG_RESULT(no))
 150 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$ac_cv_lib_ssl_MD5_Final" = "xyes"])
 151
 152 # Enable or disable usage of libfetch
 153 AC_MSG_CHECKING(whether to link with libfetch)
 154 AS_IF([test "x$with_fetch" != "xno"],
 155         [AC_MSG_RESULT(yes)
 156         AC_CHECK_LIB([fetch], [fetchParseURL], ,
 157         [if test "x$with_fetch" != "xcheck"; then
 158                 AC_MSG_FAILURE([--with-fetch was given, but -lfetch was not found])
 159         fi],
 160         [-lcrypto -ldl])
 161         # Check if libfetch supports connnection caching which we use
 162         AS_IF([test "x$ac_cv_lib_fetch_fetchParseURL" = "xyes"],
 163         [AC_CHECK_DECL(fetchConnectionCacheInit, ,
 164                 AC_MSG_ERROR([libfetch must be version 2.28 or greater]),
 165                 [#include <fetch.h>])
 166         ])
 167         ],
 168         AC_MSG_RESULT(no))
 169 AM_CONDITIONAL([HAVE_LIBFETCH], [test "x$ac_cv_lib_fetch_fetchParseURL" = "xyes"])
 170
 171 # Checks for header files.
 172 AC_CHECK_HEADERS([fcntl.h glob.h libintl.h locale.h mntent.h string.h \
 173                   sys/ioctl.h sys/mount.h sys/param.h sys/statvfs.h \
 174                   sys/time.h sys/types.h sys/ucred.h syslog.h termios.h \
 175                   wchar.h])
 176
 177 # Checks for typedefs, structures, and compiler characteristics.
 178 AC_C_INLINE
 179 AC_TYPE_MODE_T
 180 AC_TYPE_OFF_T
 181 AC_TYPE_PID_T
 182 AC_TYPE_SIZE_T
 183 AC_STRUCT_TM
 184 AC_TYPE_UID_T
 185 AC_STRUCT_DIRENT_D_TYPE
 186 PATH_MAX_DEFINED
 187
 188 # Checks for library functions.
 189 AC_FUNC_FORK
 190 AC_FUNC_GETMNTENT
 191 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 192 AC_FUNC_MKTIME
 193 AC_CHECK_FUNCS([geteuid getmntinfo realpath regcomp strcasecmp \
 194                 strndup strrchr strsep swprintf tcflush \
 195                 wcwidth uname])
 196 # For the diskspace code
 197 FS_STATS_TYPE
 198 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 199 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 200                   #include <sys/mount.h>]])
 201
 202 # Enable large file support if available
 203 AC_SYS_LARGEFILE
 204
 205 # Check if we can use symbol visibility support in GCC
 206 GCC_VISIBILITY_CC
 207 # Check if we have -fgnu89-inline flag
 208 GCC_GNU89_INLINE_CC
 209
 210 # Host-dependant definitions
 211 SIZECMD="stat -L -c %s"
 212 SEDINPLACE="sed -i"
 213 STRIP_BINARIES="--strip-all"
 214 STRIP_SHARED="--strip-unneeded"
 215 STRIP_STATIC="--strip-debug"
 216 case "${host_os}" in
 217         *bsd*)
 218                 SIZECMD="stat -L -f %z"
 219                 SEDINPLACE="sed -i ''"
 220                 ;;
 221         cygwin*)
 222                 host_os_cygwin=yes
 223                 CFLAGS="$CFLAGS -DCYGWIN"
 224                 ;;
 225         darwin*)
 226                 host_os_darwin=yes
 227                 SIZECMD="/usr/bin/stat -L -f %z"
 228                 SEDINPLACE="/usr/bin/sed -i ''"
 229                 STRIP_BINARIES=""
 230                 STRIP_SHARED="-S"
 231                 STRIP_STATIC="-S"
 232                 ;;
 233 esac
 234
 235 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 236 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 237 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 238 AC_SUBST(SIZECMD)
 239 AC_SUBST(SEDINPLACE)
 240 AC_SUBST(STRIP_BINARIES)
 241 AC_SUBST(STRIP_SHARED)
 242 AC_SUBST(STRIP_STATIC)
 243
 244 # Check for architecture, used in default makepkg.conf
 245 # (Note single space left after CARCHFLAGS)
 246 case "${host}" in
 247         i686-*)
 248                 CARCH="i686"
 249                 CARCHFLAGS="-march=i686 "
 250                 ;;
 251         x86_64-*)
 252                 CARCH="x86_64"
 253                 CARCHFLAGS="-march=x86-64 "
 254                 ;;
 255         ia64-*)
 256                 CARCH="ia64"
 257                 CARCHFLAGS="-march=ia64 "
 258                 ;;
 259         sparc-*)
 260                 CARCH="sparc"
 261                 CARCHFLAGS="-mcpu=v9 "
 262                 ;;
 263         ppc-* | powerpc-*)
 264                 CARCH="ppc"
 265                 CARCHFLAGS="-mcpu=750 "
 266                 ;;
 267         i386-*)
 268                 CARCH="i386"
 269                 CARCHFLAGS="-march=i386 "
 270                 ;;
 271         arm-*)
 272                 CARCH="arm"
 273                 CARCHFLAGS="-march=armv4 "
 274                 ;;
 275         *)
 276                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 277                 CARCH="unknown"
 278                 CARCHFLAGS=""
 279                 ;;
 280 esac
 281
 282 # Now do some things common to all architectures
 283 CHOST="${host}"
 284 AC_SUBST(CARCH)
 285 AC_SUBST(CARCHFLAGS)
 286 AC_SUBST(CHOST)
 287
 288 # Check for documentation support and status
 289 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 290 AC_MSG_CHECKING([for building documentation])
 291 if test "x$wantdoc" = "xyes" ; then
 292         if test $ASCIIDOC ; then
 293                 AC_MSG_RESULT([yes, enabled by configure])
 294         else
 295                 asciidoc="(warning : asciidoc not installed)"
 296                 AC_MSG_RESULT([yes $asciidoc])
 297         fi
 298         wantdoc=yes
 299 else
 300         AC_MSG_RESULT([no, disabled by configure])
 301         wantdoc=no
 302 fi
 303 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 304
 305 # Check for doxygen support and status
 306 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 307 AC_MSG_CHECKING([for doxygen])
 308 if test "x$wantdoxygen" = "xyes" ; then
 309         if test $DOXYGEN ; then
 310                 AC_MSG_RESULT([yes])
 311                 usedoxygen=yes
 312         else
 313                 AC_MSG_RESULT([no, doxygen missing])
 314                 usedoxygen=no
 315         fi
 316 else
 317         AC_MSG_RESULT([no, disabled by configure])
 318         usedoxygen=no
 319 fi
 320 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 321
 322 # Enable or disable debug code
 323 AC_MSG_CHECKING(for debug mode request)
 324 if test "x$debug" = "xyes" ; then
 325         AC_MSG_RESULT(yes)
 326         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 327         # Check for mcheck
 328         AC_CHECK_HEADERS([mcheck.h])
 329         # Check for -fstack-protector availability
 330         GCC_STACK_PROTECT_LIB
 331         GCC_STACK_PROTECT_CC
 332         GCC_FORTIFY_SOURCE_CC
 333         CFLAGS="$CFLAGS -g -Wall -Werror"
 334 else
 335         AC_MSG_RESULT(no)
 336         CFLAGS="$CFLAGS -Wall"
 337 fi
 338
 339 # Enable or disable use of git version in pacman version string
 340 AC_MSG_CHECKING(whether to use git version if available)
 341 if test "x$wantgitver" = "xyes" ; then
 342         AC_CHECK_PROGS([GIT], [git])
 343         AC_CHECK_FILE([.git/], hasgitdir=yes)
 344         if test $GIT -a "x$hasgitdir" = "xyes"; then
 345                 AC_MSG_RESULT([yes])
 346                 usegitver=yes
 347                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 348         else
 349                 AC_MSG_RESULT([no, git or .git dir missing])
 350                 usegitver=no
 351         fi
 352 else
 353         AC_MSG_RESULT([no, disabled by configure])
 354         usegitver=no
 355 fi
 356 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 357
 358 # Set root directory
 359 AC_SUBST(ROOTDIR)
 360 # Set package file extension
 361 AC_SUBST(PKGEXT)
 362 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 363 # Set source package file extension
 364 AC_SUBST(SRCEXT)
 365 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 366 # Set makepkg build script name
 367 AC_SUBST(BUILDSCRIPT)
 368 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 369
 370 # Configuration files
 371 AC_CONFIG_FILES([
 372 lib/libalpm/Makefile
 373 lib/libalpm/po/Makefile.in
 374 src/pacman/Makefile
 375 src/util/Makefile
 376 scripts/Makefile
 377 doc/Makefile
 378 etc/Makefile
 379 po/Makefile.in
 380 test/pacman/Makefile
 381 test/pacman/tests/Makefile
 382 test/util/Makefile
 383 contrib/Makefile
 384 Makefile
 385 ])
 386 AC_OUTPUT
 387
 388 echo "
 389 ${PACKAGE_NAME}:
 390
 391   Build information:
 392     source code location   : ${srcdir}
 393     prefix                 : ${prefix}
 394     sysconfdir             : $(eval echo ${sysconfdir})
 395        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 396     localstatedir          : $(eval echo ${localstatedir})
 397        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 398        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 399     compiler               : ${CC}
 400     compiler flags         : ${CFLAGS}
 401     defines                : ${DEFS}
 402
 403     Architecture           : ${CARCH}
 404     Architecture flags     : ${CARCHFLAGS}
 405     Host Type              : ${CHOST}
 406     Filesize command       : ${SIZECMD}
 407     In-place sed command   : ${SEDINPLACE}
 408
 409     libalpm version        : ${LIB_VERSION}
 410     libalpm version info   : ${LIB_VERSION_INFO}
 411     pacman version         : ${PACKAGE_VERSION}
 412     using git version      : ${usegitver}
 413
 414   Directory and file information:
 415     root working directory : ${ROOTDIR}
 416     package extension      : ${PKGEXT}
 417     source pkg extension   : ${SRCEXT}
 418     build script name      : ${BUILDSCRIPT}
 419
 420   Compilation options:
 421     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 422     Doxygen support        : ${usedoxygen}
 423     debug support          : ${debug}
 424 "
 425
 426 # vim:set ts=2 sw=2 noet: