configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [5])
  45 m4_define([lib_revision], [3])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [4])
  50 m4_define([pacman_version_micro], [3])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for buildscript filename
  87 AC_ARG_WITH(buildscript,
  88         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  89         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  90
  91 # Help line for using OpenSSL
  92 AC_ARG_WITH(openssl,
  93         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  94         [], [with_openssl=check])
  95
  96 # Help line for libfetch
  97 AC_ARG_WITH(fetch,
  98         AS_HELP_STRING([--with-fetch], [use libfetch as an internal downloader]),
  99         [], [with_fetch=check])
 100
 101 # Help line for documentation
 102 AC_ARG_ENABLE(doc,
 103         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 104         [wantdoc=$enableval], [wantdoc=yes])
 105
 106 # Help line for doxygen
 107 AC_ARG_ENABLE(doxygen,
 108         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 109         [wantdoxygen=$enableval], [wantdoxygen=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Checks for programs.
 123 AC_PROG_AWK
 124 AC_PROG_CC_C99
 125 AC_PROG_INSTALL
 126 AC_PROG_LN_S
 127 AC_PROG_MAKE_SET
 128 AC_PROG_LIBTOOL
 129 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 130 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 131
 132 # find installed gettext
 133 AM_GNU_GETTEXT([external])
 134 AM_GNU_GETTEXT_VERSION(0.13.1)
 135
 136 # Check for libarchive
 137 AC_CHECK_LIB([archive], [archive_read_data], ,
 138         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 139
 140 # Check for OpenSSL
 141 AC_MSG_CHECKING(whether to link with libssl)
 142 AS_IF([test "x$with_openssl" != "xno"],
 143         [AC_MSG_RESULT(yes)
 144         AC_CHECK_LIB([ssl], [MD5_Final], ,
 145         [if test "x$with_openssl" != "xcheck"; then
 146                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 147         fi],
 148         [-lcrypto])],
 149         AC_MSG_RESULT(no))
 150 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$ac_cv_lib_ssl_MD5_Final" = "xyes"])
 151
 152 # Enable or disable usage of libfetch
 153 AC_MSG_CHECKING(whether to link with libfetch)
 154 AS_IF([test "x$with_fetch" != "xno"],
 155         [AC_MSG_RESULT(yes)
 156         AC_CHECK_LIB([fetch], [fetchParseURL], ,
 157         [if test "x$with_fetch" != "xcheck"; then
 158                 AC_MSG_FAILURE([--with-fetch was given, but -lfetch was not found])
 159         fi],
 160         [-lcrypto -ldl])
 161         # Check if libfetch supports connnection caching which we use
 162         AS_IF([test "x$ac_cv_lib_fetch_fetchParseURL" = "xyes"],
 163         [AC_CHECK_DECL(fetchConnectionCacheInit, ,
 164                 AC_MSG_ERROR([libfetch must be version 2.28 or greater]),
 165                 [#include <fetch.h>])
 166         ])
 167         ],
 168         AC_MSG_RESULT(no))
 169 AM_CONDITIONAL([HAVE_LIBFETCH], [test "x$ac_cv_lib_fetch_fetchParseURL" = "xyes"])
 170
 171 # Checks for header files.
 172 AC_CHECK_HEADERS([fcntl.h glob.h libintl.h locale.h mntent.h string.h \
 173                   sys/ioctl.h sys/mount.h sys/param.h sys/statvfs.h \
 174                   sys/time.h sys/types.h sys/ucred.h syslog.h wchar.h])
 175
 176 # Checks for typedefs, structures, and compiler characteristics.
 177 AC_C_INLINE
 178 AC_TYPE_MODE_T
 179 AC_TYPE_OFF_T
 180 AC_TYPE_PID_T
 181 AC_TYPE_SIZE_T
 182 AC_STRUCT_TM
 183 AC_TYPE_UID_T
 184 AC_STRUCT_DIRENT_D_TYPE
 185 PATH_MAX_DEFINED
 186
 187 # Checks for library functions.
 188 AC_FUNC_FORK
 189 AC_FUNC_GETMNTENT
 190 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 191 AC_FUNC_MKTIME
 192 AC_CHECK_FUNCS([geteuid getmntinfo realpath regcomp strcasecmp \
 193                 strndup strrchr strsep swprintf \
 194                 wcwidth uname])
 195 # For the diskspace code
 196 FS_STATS_TYPE
 197 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 198 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 199                   #include <sys/mount.h>]])
 200
 201 # Enable large file support if available
 202 AC_SYS_LARGEFILE
 203
 204 # Check if we can use symbol visibility support in GCC
 205 GCC_VISIBILITY_CC
 206 # Check if we have -fgnu89-inline flag
 207 GCC_GNU89_INLINE_CC
 208
 209 # Host-dependant definitions
 210 SIZECMD="stat -L -c %s"
 211 SEDINPLACE="sed -i"
 212 STRIP_BINARIES="--strip-all"
 213 STRIP_SHARED="--strip-unneeded"
 214 STRIP_STATIC="--strip-debug"
 215 case "${host_os}" in
 216         *bsd*)
 217                 SIZECMD="stat -L -f %z"
 218                 SEDINPLACE="sed -i ''"
 219                 ;;
 220         cygwin*)
 221                 host_os_cygwin=yes
 222                 CFLAGS="$CFLAGS -DCYGWIN"
 223                 ;;
 224         darwin*)
 225                 host_os_darwin=yes
 226                 SIZECMD="/usr/bin/stat -L -f %z"
 227                 SEDINPLACE="/usr/bin/sed -i ''"
 228                 STRIP_BINARIES=""
 229                 STRIP_SHARED="-S"
 230                 STRIP_STATIC="-S"
 231                 ;;
 232 esac
 233
 234 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 235 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 236 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 237 AC_SUBST(SIZECMD)
 238 AC_SUBST(SEDINPLACE)
 239 AC_SUBST(STRIP_BINARIES)
 240 AC_SUBST(STRIP_SHARED)
 241 AC_SUBST(STRIP_STATIC)
 242
 243 # Check for architecture, used in default makepkg.conf
 244 # (Note single space left after CARCHFLAGS)
 245 case "${host}" in
 246         i686-*)
 247                 CARCH="i686"
 248                 CARCHFLAGS="-march=i686 "
 249                 ;;
 250         x86_64-*)
 251                 CARCH="x86_64"
 252                 CARCHFLAGS="-march=x86-64 "
 253                 ;;
 254         ia64-*)
 255                 CARCH="ia64"
 256                 CARCHFLAGS="-march=ia64 "
 257                 ;;
 258         sparc-*)
 259                 CARCH="sparc"
 260                 CARCHFLAGS="-mcpu=v9 "
 261                 ;;
 262         ppc-* | powerpc-*)
 263                 CARCH="ppc"
 264                 CARCHFLAGS="-mcpu=750 "
 265                 ;;
 266         i386-*)
 267                 CARCH="i386"
 268                 CARCHFLAGS="-march=i386 "
 269                 ;;
 270         arm-*)
 271                 CARCH="arm"
 272                 CARCHFLAGS="-march=armv4 "
 273                 ;;
 274         *)
 275                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 276                 CARCH="unknown"
 277                 CARCHFLAGS=""
 278                 ;;
 279 esac
 280
 281 # Now do some things common to all architectures
 282 CHOST="${host}"
 283 AC_SUBST(CARCH)
 284 AC_SUBST(CARCHFLAGS)
 285 AC_SUBST(CHOST)
 286
 287 # Check for documentation support and status
 288 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 289 AC_MSG_CHECKING([for building documentation])
 290 if test "x$wantdoc" = "xyes" ; then
 291         if test $ASCIIDOC ; then
 292                 AC_MSG_RESULT([yes, enabled by configure])
 293         else
 294                 asciidoc="(warning : asciidoc not installed)"
 295                 AC_MSG_RESULT([yes $asciidoc])
 296         fi
 297         wantdoc=yes
 298 else
 299         AC_MSG_RESULT([no, disabled by configure])
 300         wantdoc=no
 301 fi
 302 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 303
 304 # Check for doxygen support and status
 305 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 306 AC_MSG_CHECKING([for doxygen])
 307 if test "x$wantdoxygen" = "xyes" ; then
 308         if test $DOXYGEN ; then
 309                 AC_MSG_RESULT([yes])
 310                 usedoxygen=yes
 311         else
 312                 AC_MSG_RESULT([no, doxygen missing])
 313                 usedoxygen=no
 314         fi
 315 else
 316         AC_MSG_RESULT([no, disabled by configure])
 317         usedoxygen=no
 318 fi
 319 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 320
 321 # Enable or disable debug code
 322 AC_MSG_CHECKING(for debug mode request)
 323 if test "x$debug" = "xyes" ; then
 324         AC_MSG_RESULT(yes)
 325         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 326         # Check for mcheck
 327         AC_CHECK_HEADERS([mcheck.h])
 328         # Check for -fstack-protector availability
 329         GCC_STACK_PROTECT_LIB
 330         GCC_STACK_PROTECT_CC
 331         GCC_FORTIFY_SOURCE_CC
 332         CFLAGS="$CFLAGS -g -Wall -Werror"
 333 else
 334         AC_MSG_RESULT(no)
 335         CFLAGS="$CFLAGS -Wall"
 336 fi
 337
 338 # Enable or disable use of git version in pacman version string
 339 AC_MSG_CHECKING(whether to use git version if available)
 340 if test "x$wantgitver" = "xyes" ; then
 341         AC_CHECK_PROGS([GIT], [git])
 342         AC_CHECK_FILE([.git/], hasgitdir=yes)
 343         if test $GIT -a "x$hasgitdir" = "xyes"; then
 344                 AC_MSG_RESULT([yes])
 345                 usegitver=yes
 346                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 347         else
 348                 AC_MSG_RESULT([no, git or .git dir missing])
 349                 usegitver=no
 350         fi
 351 else
 352         AC_MSG_RESULT([no, disabled by configure])
 353         usegitver=no
 354 fi
 355 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 356
 357 # Set root directory
 358 AC_SUBST(ROOTDIR)
 359 # Set package file extension
 360 AC_SUBST(PKGEXT)
 361 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 362 # Set source package file extension
 363 AC_SUBST(SRCEXT)
 364 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 365 # Set makepkg build script name
 366 AC_SUBST(BUILDSCRIPT)
 367 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 368
 369 # Configuration files
 370 AC_CONFIG_FILES([
 371 lib/libalpm/Makefile
 372 lib/libalpm/po/Makefile.in
 373 src/pacman/Makefile
 374 src/util/Makefile
 375 scripts/Makefile
 376 doc/Makefile
 377 etc/Makefile
 378 po/Makefile.in
 379 test/pacman/Makefile
 380 test/pacman/tests/Makefile
 381 test/util/Makefile
 382 contrib/Makefile
 383 Makefile
 384 ])
 385 AC_OUTPUT
 386
 387 echo "
 388 ${PACKAGE_NAME}:
 389
 390   Build information:
 391     source code location   : ${srcdir}
 392     prefix                 : ${prefix}
 393     sysconfdir             : $(eval echo ${sysconfdir})
 394        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 395     localstatedir          : $(eval echo ${localstatedir})
 396        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 397        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 398     compiler               : ${CC}
 399     compiler flags         : ${CFLAGS}
 400     defines                : ${DEFS}
 401
 402     Architecture           : ${CARCH}
 403     Architecture flags     : ${CARCHFLAGS}
 404     Host Type              : ${CHOST}
 405     Filesize command       : ${SIZECMD}
 406     In-place sed command   : ${SEDINPLACE}
 407
 408     libalpm version        : ${LIB_VERSION}
 409     libalpm version info   : ${LIB_VERSION_INFO}
 410     pacman version         : ${PACKAGE_VERSION}
 411     using git version      : ${usegitver}
 412
 413   Directory and file information:
 414     root working directory : ${ROOTDIR}
 415     package extension      : ${PKGEXT}
 416     source pkg extension   : ${SRCEXT}
 417     build script name      : ${BUILDSCRIPT}
 418
 419   Compilation options:
 420     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 421     Doxygen support        : ${usedoxygen}
 422     debug support          : ${debug}
 423 "
 424
 425 # vim:set ts=2 sw=2 noet: