configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.60)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [5])
  45 m4_define([lib_revision], [1])
  46 m4_define([lib_age], [3])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [1])
  50 m4_define([pacman_version_micro], [4])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of pacman's root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for database extension
  87 AC_ARG_WITH(db-ext,
  88         AS_HELP_STRING([--with-db-ext=ext], [set the file extension used by the database]),
  89         [DBEXT=$withval], [DBEXT=.db.tar.gz])
  90
  91 # Help line for libdownload/libfetch
  92 AC_ARG_ENABLE(internal-download,
  93         AS_HELP_STRING([--disable-internal-download], [do not build with libdownload/libfetch support]),
  94         [internaldownload=$enableval], [internaldownload=yes])
  95
  96 # Help line for documentation
  97 AC_ARG_ENABLE(doc,
  98         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
  99         [wantdoc=$enableval], [wantdoc=yes])
 100
 101 # Help line for doxygen
 102 AC_ARG_ENABLE(doxygen,
 103         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 104         [wantdoxygen=$enableval], [wantdoxygen=no])
 105
 106 # Help line for asciidoc
 107 AC_ARG_ENABLE(asciidoc,
 108         AS_HELP_STRING([--enable-asciidoc], [build your own manpages with Asciidoc]),
 109         [wantasciidoc=$enableval], [wantasciidoc=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Help line for pacman.static
 123 AC_ARG_ENABLE(pacman-static,
 124         AS_HELP_STRING([--disable-pacman-static], [do not build static version of pacman]),
 125         [pacmanstatic=$enableval], [pacmanstatic=yes])
 126
 127 # Checks for programs.
 128 AC_PROG_AWK
 129 AC_PROG_CC_C99
 130 AC_PROG_INSTALL
 131 AC_PROG_LN_S
 132 AC_PROG_MAKE_SET
 133 AC_PROG_LIBTOOL
 134 AC_CHECK_PROGS([PYTHON], [python2.5 python2.4 python], [false])
 135
 136 # find installed gettext
 137 AM_GNU_GETTEXT([external])
 138 AM_GNU_GETTEXT_VERSION(0.13.1)
 139
 140 # Check for libarchive
 141 AC_CHECK_LIB([archive], [archive_read_data], ,
 142         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 143
 144 # Enable or disable usage of libdownload/libfetch
 145 # - this is a nested check- first see if we need a library, if we do then
 146 #   check for libdownload first, then fallback to libfetch, then die
 147 AC_MSG_CHECKING(whether to link with download library)
 148 if test "x$internaldownload" = "xyes" ; then
 149         AC_MSG_RESULT(yes)
 150         AC_DEFINE([INTERNAL_DOWNLOAD], , [Use internal download library])
 151         # Check for a download library if it was actually requested
 152         AC_CHECK_LIB([download], [downloadParseURL], ,
 153                 AC_CHECK_LIB([fetch], [fetchParseURL], ,
 154                         AC_MSG_ERROR([libdownload or libfetch are needed to compile with internal download support])) )
 155 else
 156         AC_MSG_RESULT(no)
 157 fi
 158 AM_CONDITIONAL(INTERNAL_DOWNLOAD, test "x$internaldownload" = "xyes")
 159
 160 # Checks for header files.
 161 AC_CHECK_HEADERS([fcntl.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/param.h sys/statvfs.h sys/syslimits.h sys/time.h syslog.h wchar.h])
 162
 163 # Checks for typedefs, structures, and compiler characteristics.
 164 AC_C_INLINE
 165 AC_TYPE_MODE_T
 166 AC_TYPE_OFF_T
 167 AC_TYPE_PID_T
 168 AC_TYPE_SIZE_T
 169 AC_STRUCT_TM
 170 AC_TYPE_UID_T
 171
 172 # Checks for library functions.
 173 AC_FUNC_FORK
 174 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 175 AC_FUNC_MKTIME
 176 AC_TYPE_SIGNAL
 177 AC_CHECK_FUNCS([geteuid realpath regcomp strcasecmp \
 178                 strndup strrchr strsep strverscmp swprintf \
 179                 wcwidth uname])
 180
 181 # Enable large file support if available
 182 AC_SYS_LARGEFILE
 183
 184 # Check if we can use symbol visibility support in GCC
 185 GCC_VISIBILITY_CC
 186 # Check if we have -fgnu89-inline flag
 187 GCC_GNU89_INLINE_CC
 188
 189 # Host-dependant definitions
 190 case "${host_os}" in
 191         cygwin*)
 192                 host_os_cygwin=yes
 193                 CFLAGS="$CFLAGS -DCYGWIN"
 194                 ;;
 195         darwin*)
 196                 host_os_darwin=yes
 197                 ;;
 198 esac
 199
 200 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 201 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 202
 203 # Check for architecture, used in default makepkg.conf
 204 # (Note single space left after CARCHFLAGS)
 205 case "${host}" in
 206         i686-*)
 207                 CARCH="i686"
 208                 CARCHFLAGS="-march=i686 "
 209                 ;;
 210         x86_64-*)
 211                 CARCH="x86_64"
 212                 CARCHFLAGS="-march=x86-64 "
 213                 ;;
 214         ia64-*)
 215                 CARCH="ia64"
 216                 CARCHFLAGS="-march=ia64 "
 217                 ;;
 218         sparc-*)
 219                 CARCH="sparc"
 220                 CARCHFLAGS="-mcpu=v9 "
 221                 ;;
 222         ppc-* | powerpc-*)
 223                 CARCH="ppc"
 224                 CARCHFLAGS="-mcpu=750 "
 225                 ;;
 226         i386-*)
 227                 CARCH="i386"
 228                 CARCHFLAGS="-march=i386 "
 229                 ;;
 230         arm-*)
 231                 CARCH="arm"
 232                 CARCHFLAGS="-march=armv4 "
 233                 ;;
 234         *)
 235                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 236                 CARCH="unknown"
 237                 CARCHFLAGS=""
 238                 ;;
 239 esac
 240
 241 # Now do some things common to all architectures
 242 CHOST="${host}"
 243 AC_SUBST(CARCH)
 244 AC_SUBST(CARCHFLAGS)
 245 AC_SUBST(CHOST)
 246
 247 # Check for documentation support and status
 248 AC_MSG_CHECKING([for building documentation])
 249 if test "x$wantdoc" = "xyes" ; then
 250         AC_MSG_RESULT([yes])
 251         wantdoc=yes
 252 else
 253         AC_MSG_RESULT([no, disabled by configure])
 254         wantdoc=no
 255 fi
 256 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 257
 258 # Check for doxygen support and status
 259 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 260 AC_MSG_CHECKING([for doxygen])
 261 if test "x$wantdoxygen" = "xyes" ; then
 262         if test $DOXYGEN ; then
 263                 AC_MSG_RESULT([yes])
 264                 usedoxygen=yes
 265         else
 266                 AC_MSG_RESULT([no, doxygen missing])
 267                 usedoxygen=no
 268         fi
 269 else
 270         AC_MSG_RESULT([no, disabled by configure])
 271         usedoxygen=no
 272 fi
 273 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 274
 275 # Check for asciidoc support and status
 276 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 277 AC_MSG_CHECKING([for asciidoc])
 278 if test "x$wantasciidoc" = "xyes" ; then
 279         if test $ASCIIDOC ; then
 280                 AC_MSG_RESULT([yes])
 281                 useasciidoc=yes
 282         else
 283                 AC_MSG_RESULT([no, asciidoc missing])
 284                 useasciidoc=no
 285         fi
 286 else
 287         AC_MSG_RESULT([no, disabled by configure])
 288         useasciidoc=no
 289 fi
 290 AM_CONDITIONAL(USE_ASCIIDOC, test "x$useasciidoc" = "xyes")
 291
 292 # Enable or disable debug code
 293 AC_MSG_CHECKING(for debug mode request)
 294 if test "x$debug" = "xyes" ; then
 295         AC_MSG_RESULT(yes)
 296         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 297         # Check for mcheck
 298         AC_CHECK_HEADERS([mcheck.h])
 299         # Check for -fstack-protector availability
 300         GCC_STACK_PROTECT_LIB
 301         GCC_STACK_PROTECT_CC
 302         CFLAGS="$CFLAGS -Wall -Werror"
 303 else
 304         AC_MSG_RESULT(no)
 305         CFLAGS="$CFLAGS -Wall"
 306 fi
 307
 308 # Enable or disable use of git version in pacman version string
 309 AC_CHECK_PROGS([GIT], [git])
 310 AC_CHECK_FILE([.git/], hasgitdir=yes)
 311 AC_MSG_CHECKING(whether to use git version if available)
 312 if test "x$wantgitver" = "xyes" ; then
 313         if test $GIT -a "x$hasgitdir" = "xyes"; then
 314                 AC_MSG_RESULT([yes])
 315                 usegitver=yes
 316                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 317         else
 318                 AC_MSG_RESULT([no, git or .git dir missing])
 319                 usegitver=no
 320         fi
 321 else
 322         AC_MSG_RESULT([no, disabled by configure])
 323         usegitver=no
 324 fi
 325 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 326
 327 # Enable or disable inclusion of pacman.static
 328 AC_MSG_CHECKING(whether to build pacman.static)
 329 if test "x$pacmanstatic" = "xyes" ; then
 330         AC_MSG_RESULT(yes)
 331         AC_DEFINE([INCLUDE_PACMAN_STATIC], , [Build pacman.static])
 332 else
 333         AC_MSG_RESULT(no)
 334 fi
 335 AM_CONDITIONAL(INCLUDE_PACMAN_STATIC, test "x$pacmanstatic" = "xyes")
 336
 337 # Set root directory
 338 AC_SUBST(ROOTDIR)
 339 # Set package file extension
 340 AC_SUBST(PKGEXT)
 341 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 342 # Set source package file extension
 343 AC_SUBST(SRCEXT)
 344 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 345 # Set database file extension
 346 AC_SUBST(DBEXT)
 347 AC_DEFINE_UNQUOTED([DBEXT], "$DBEXT", [The file extension used by pacman databases])
 348
 349 # Configuration files
 350 AC_CONFIG_FILES([
 351 lib/libalpm/Makefile
 352 lib/libalpm/po/Makefile.in
 353 src/pacman/Makefile
 354 src/util/Makefile
 355 scripts/Makefile
 356 doc/Makefile
 357 etc/Makefile
 358 po/Makefile.in
 359 pactest/Makefile
 360 contrib/Makefile
 361 Makefile
 362 ])
 363 AC_OUTPUT
 364
 365 echo "
 366 ${PACKAGE_NAME}:
 367
 368   Build information:
 369     source code location   : ${srcdir}
 370     prefix                 : ${prefix}
 371     sysconfdir             : $(eval echo ${sysconfdir})
 372        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 373     localstatedir          : $(eval echo ${localstatedir})
 374        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 375        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 376     compiler               : ${CC}
 377     compiler flags         : ${CFLAGS}
 378     defines                : ${DEFS}
 379
 380     Architecture           : ${CARCH}
 381     Architecture flags     : ${CARCHFLAGS}
 382     Host Type              : ${CHOST}
 383
 384     libalpm version        : ${LIB_VERSION}
 385     libalpm version info   : ${LIB_VERSION_INFO}
 386     pacman version         : ${PACKAGE_VERSION}
 387     using git version      : ${usegitver}
 388
 389   Directory and file information:
 390     root working directory : ${ROOTDIR}
 391     package extension      : ${PKGEXT}
 392     source pkg extension   : ${SRCEXT}
 393     database extension     : ${DBEXT}
 394
 395   Compilation options:
 396     Run make in doc/ dir   : ${wantdoc}
 397     Use download library   : ${internaldownload}
 398     Doxygen support        : ${usedoxygen}
 399     Asciidoc support       : ${useasciidoc}
 400     debug support          : ${debug}
 401     build pacman.static    : ${pacmanstatic}
 402 "
 403
 404 # vim:set ts=2 sw=2 noet: