configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [6])
  45 m4_define([lib_revision], [2])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [5])
  50 m4_define([pacman_version_micro], [2])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for buildscript filename
  87 AC_ARG_WITH(buildscript,
  88         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  89         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  90
  91 # Help line for using OpenSSL
  92 AC_ARG_WITH(openssl,
  93         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  94         [], [with_openssl=check])
  95
  96 # Check for useable libcurl
  97 LIBCURL_CHECK_CONFIG([yes], [7.19.4])
  98
  99 # Help line for documentation
 100 AC_ARG_ENABLE(doc,
 101         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 102         [wantdoc=$enableval], [wantdoc=yes])
 103
 104 # Help line for doxygen
 105 AC_ARG_ENABLE(doxygen,
 106         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 107         [wantdoxygen=$enableval], [wantdoxygen=no])
 108
 109 # Help line for debug
 110 AC_ARG_ENABLE(debug,
 111         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 112         [debug=$enableval], [debug=no])
 113
 114 # Help line for using git version in pacman version string
 115 AC_ARG_ENABLE(git-version,
 116         AS_HELP_STRING([--enable-git-version],
 117                 [enable use of git version in version string if available]),
 118         [wantgitver=$enableval], [wantgitver=no])
 119
 120 # Checks for programs.
 121 AC_PROG_AWK
 122 AC_PROG_CC_C99
 123 AC_PROG_INSTALL
 124 AC_PROG_LN_S
 125 AC_PROG_MAKE_SET
 126 AC_PROG_LIBTOOL
 127 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 128 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 129
 130 # find installed gettext
 131 AM_GNU_GETTEXT([external])
 132 AM_GNU_GETTEXT_VERSION(0.13.1)
 133
 134 AC_CHECK_LIB([m], [fabs], ,
 135         AC_MSG_ERROR([libm is needed to compile pacman!]))
 136
 137 # Check for libarchive
 138 AC_CHECK_LIB([archive], [archive_read_data], ,
 139         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 140
 141 # Check for OpenSSL
 142 AC_MSG_CHECKING(whether to link with libssl)
 143 AS_IF([test "x$with_openssl" != "xno"],
 144         [AC_MSG_RESULT(yes)
 145         AC_CHECK_LIB([ssl], [MD5_Final], ,
 146         [if test "x$with_openssl" != "xcheck"; then
 147                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 148         fi],
 149         [-lcrypto])],
 150         AC_MSG_RESULT(no))
 151 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$ac_cv_lib_ssl_MD5_Final" = "xyes"])
 152
 153 # Check for gpgme
 154 AC_CHECK_LIB([gpgme], [gpgme_check_version], ,
 155         AC_MSG_ERROR([gpgme is needed to compile pacman!]))
 156
 157 # Checks for header files.
 158 AC_CHECK_HEADERS([fcntl.h glob.h libintl.h locale.h mntent.h string.h \
 159                   sys/ioctl.h sys/mount.h sys/param.h sys/statvfs.h \
 160                   sys/time.h sys/types.h sys/ucred.h syslog.h termios.h \
 161                   wchar.h])
 162
 163 # Checks for typedefs, structures, and compiler characteristics.
 164 AC_C_INLINE
 165 AC_TYPE_MODE_T
 166 AC_TYPE_OFF_T
 167 AC_TYPE_PID_T
 168 AC_TYPE_SIZE_T
 169 AC_STRUCT_TM
 170 AC_TYPE_UID_T
 171 AC_STRUCT_DIRENT_D_TYPE
 172 PATH_MAX_DEFINED
 173
 174 # Checks for library functions.
 175 AC_FUNC_FORK
 176 AC_FUNC_GETMNTENT
 177 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 178 AC_FUNC_MKTIME
 179 AC_CHECK_FUNCS([geteuid getmntinfo realpath regcomp strcasecmp \
 180                 strndup strrchr strsep swprintf tcflush \
 181                 wcwidth uname])
 182 # For the diskspace code
 183 FS_STATS_TYPE
 184 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 185 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 186                   #include <sys/mount.h>]])
 187
 188 # Enable large file support if available
 189 AC_SYS_LARGEFILE
 190
 191 # Check if we can use symbol visibility support in GCC
 192 GCC_VISIBILITY_CC
 193 # Check if we have -fgnu89-inline flag
 194 GCC_GNU89_INLINE_CC
 195
 196 # Host-dependant definitions
 197 SIZECMD="stat -L -c %s"
 198 SEDINPLACE="sed -i"
 199 STRIP_BINARIES="--strip-all"
 200 STRIP_SHARED="--strip-unneeded"
 201 STRIP_STATIC="--strip-debug"
 202 case "${host_os}" in
 203         *bsd*)
 204                 SIZECMD="stat -L -f %z"
 205                 SEDINPLACE="sed -i ''"
 206                 ;;
 207         cygwin*)
 208                 host_os_cygwin=yes
 209                 CFLAGS="$CFLAGS -DCYGWIN"
 210                 ;;
 211         darwin*)
 212                 host_os_darwin=yes
 213                 SIZECMD="/usr/bin/stat -L -f %z"
 214                 SEDINPLACE="/usr/bin/sed -i ''"
 215                 STRIP_BINARIES=""
 216                 STRIP_SHARED="-S"
 217                 STRIP_STATIC="-S"
 218                 ;;
 219 esac
 220
 221 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 222 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 223 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 224 AC_SUBST(SIZECMD)
 225 AC_SUBST(SEDINPLACE)
 226 AC_SUBST(STRIP_BINARIES)
 227 AC_SUBST(STRIP_SHARED)
 228 AC_SUBST(STRIP_STATIC)
 229
 230 # Check for architecture, used in default makepkg.conf
 231 # (Note single space left after CARCHFLAGS)
 232 case "${host}" in
 233         i686-*)
 234                 CARCH="i686"
 235                 CARCHFLAGS="-march=i686 "
 236                 ;;
 237         x86_64-*)
 238                 CARCH="x86_64"
 239                 CARCHFLAGS="-march=x86-64 "
 240                 ;;
 241         ia64-*)
 242                 CARCH="ia64"
 243                 CARCHFLAGS="-march=ia64 "
 244                 ;;
 245         sparc-*)
 246                 CARCH="sparc"
 247                 CARCHFLAGS="-mcpu=v9 "
 248                 ;;
 249         ppc-* | powerpc-*)
 250                 CARCH="ppc"
 251                 CARCHFLAGS="-mcpu=750 "
 252                 ;;
 253         i386-*)
 254                 CARCH="i386"
 255                 CARCHFLAGS="-march=i386 "
 256                 ;;
 257         arm-*)
 258                 CARCH="arm"
 259                 CARCHFLAGS="-march=armv4 "
 260                 ;;
 261         *)
 262                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 263                 CARCH="unknown"
 264                 CARCHFLAGS=""
 265                 ;;
 266 esac
 267
 268 # Now do some things common to all architectures
 269 CHOST="${host}"
 270 AC_SUBST(CARCH)
 271 AC_SUBST(CARCHFLAGS)
 272 AC_SUBST(CHOST)
 273
 274 # Check for documentation support and status
 275 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 276 AC_MSG_CHECKING([for building documentation])
 277 if test "x$wantdoc" = "xyes" ; then
 278         if test $ASCIIDOC ; then
 279                 AC_MSG_RESULT([yes, enabled by configure])
 280         else
 281                 asciidoc="(warning : asciidoc not installed)"
 282                 AC_MSG_RESULT([yes $asciidoc])
 283         fi
 284         wantdoc=yes
 285 else
 286         AC_MSG_RESULT([no, disabled by configure])
 287         wantdoc=no
 288 fi
 289 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 290
 291 # Check for doxygen support and status
 292 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 293 AC_MSG_CHECKING([for doxygen])
 294 if test "x$wantdoxygen" = "xyes" ; then
 295         if test $DOXYGEN ; then
 296                 AC_MSG_RESULT([yes])
 297                 usedoxygen=yes
 298         else
 299                 AC_MSG_RESULT([no, doxygen missing])
 300                 usedoxygen=no
 301         fi
 302 else
 303         AC_MSG_RESULT([no, disabled by configure])
 304         usedoxygen=no
 305 fi
 306 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 307
 308 # Enable or disable debug code
 309 AC_MSG_CHECKING(for debug mode request)
 310 if test "x$debug" = "xyes" ; then
 311         AC_MSG_RESULT(yes)
 312         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 313         # Check for mcheck
 314         AC_CHECK_HEADERS([mcheck.h])
 315         # Check for -fstack-protector availability
 316         GCC_STACK_PROTECT_LIB
 317         GCC_STACK_PROTECT_CC
 318         GCC_FORTIFY_SOURCE_CC
 319         CFLAGS="$CFLAGS -g -Wall -Werror"
 320 else
 321         AC_MSG_RESULT(no)
 322         CFLAGS="$CFLAGS -Wall"
 323 fi
 324
 325 # Enable or disable use of git version in pacman version string
 326 AC_MSG_CHECKING(whether to use git version if available)
 327 if test "x$wantgitver" = "xyes" ; then
 328         AC_CHECK_PROGS([GIT], [git])
 329         AC_CHECK_FILE([.git/], hasgitdir=yes)
 330         if test $GIT -a "x$hasgitdir" = "xyes"; then
 331                 AC_MSG_RESULT([yes])
 332                 usegitver=yes
 333                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 334         else
 335                 AC_MSG_RESULT([no, git or .git dir missing])
 336                 usegitver=no
 337         fi
 338 else
 339         AC_MSG_RESULT([no, disabled by configure])
 340         usegitver=no
 341 fi
 342 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 343
 344 # Set root directory
 345 AC_SUBST(ROOTDIR)
 346 # Set package file extension
 347 AC_SUBST(PKGEXT)
 348 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 349 # Set source package file extension
 350 AC_SUBST(SRCEXT)
 351 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 352 # Set makepkg build script name
 353 AC_SUBST(BUILDSCRIPT)
 354 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 355
 356 # Configuration files
 357 AC_CONFIG_FILES([
 358 lib/libalpm/Makefile
 359 lib/libalpm/po/Makefile.in
 360 src/pacman/Makefile
 361 src/util/Makefile
 362 scripts/Makefile
 363 doc/Makefile
 364 etc/Makefile
 365 po/Makefile.in
 366 test/pacman/Makefile
 367 test/pacman/tests/Makefile
 368 test/util/Makefile
 369 contrib/Makefile
 370 Makefile
 371 ])
 372 AC_OUTPUT
 373
 374 echo "
 375 ${PACKAGE_NAME}:
 376
 377   Build information:
 378     source code location   : ${srcdir}
 379     prefix                 : ${prefix}
 380     sysconfdir             : $(eval echo ${sysconfdir})
 381        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 382     localstatedir          : $(eval echo ${localstatedir})
 383        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 384        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 385     compiler               : ${CC}
 386     compiler flags         : ${CFLAGS}
 387     defines                : ${DEFS}
 388
 389     Architecture           : ${CARCH}
 390     Architecture flags     : ${CARCHFLAGS}
 391     Host Type              : ${CHOST}
 392     Filesize command       : ${SIZECMD}
 393     In-place sed command   : ${SEDINPLACE}
 394
 395     libalpm version        : ${LIB_VERSION}
 396     libalpm version info   : ${LIB_VERSION_INFO}
 397     pacman version         : ${PACKAGE_VERSION}
 398     using git version      : ${usegitver}
 399
 400   Directory and file information:
 401     root working directory : ${ROOTDIR}
 402     package extension      : ${PKGEXT}
 403     source pkg extension   : ${SRCEXT}
 404     build script name      : ${BUILDSCRIPT}
 405
 406   Compilation options:
 407     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 408     Doxygen support        : ${usedoxygen}
 409     debug support          : ${debug}
 410 "
 411
 412 # vim:set ts=2 sw=2 noet: