configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.60)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [4])
  45 m4_define([lib_revision], [1])
  46 m4_define([lib_age], [1])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [2])
  50 m4_define([pacman_version_micro], [2])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of pacman's root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for database extension
  87 AC_ARG_WITH(db-ext,
  88         AS_HELP_STRING([--with-db-ext=ext], [set the file extension used by the database]),
  89         [DBEXT=$withval], [DBEXT=.db.tar.gz])
  90
  91 # Help line for buildscript filename
  92 AC_ARG_WITH(buildscript,
  93         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  94         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  95
  96 # Help line for libfetch
  97 AC_ARG_ENABLE(internal-download,
  98         AS_HELP_STRING([--disable-internal-download], [do not build with libfetch support]),
  99         [internaldownload=$enableval], [internaldownload=yes])
 100
 101 # Help line for documentation
 102 AC_ARG_ENABLE(doc,
 103         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 104         [wantdoc=$enableval], [wantdoc=yes])
 105
 106 # Help line for doxygen
 107 AC_ARG_ENABLE(doxygen,
 108         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 109         [wantdoxygen=$enableval], [wantdoxygen=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Checks for programs.
 123 AC_PROG_AWK
 124 AC_PROG_CC_C99
 125 AC_PROG_INSTALL
 126 AC_PROG_LN_S
 127 AC_PROG_MAKE_SET
 128 AC_PROG_LIBTOOL
 129 AC_CHECK_PROGS([PYTHON], [python2.6 python2.5 python], [false])
 130
 131 # find installed gettext
 132 AM_GNU_GETTEXT([external])
 133 AM_GNU_GETTEXT_VERSION(0.13.1)
 134
 135 # Check for libarchive
 136 AC_CHECK_LIB([archive], [archive_read_data], ,
 137         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 138
 139 # Enable or disable usage of libfetch
 140 AC_MSG_CHECKING(whether to link with libfetch)
 141 if test "x$internaldownload" = "xyes" ; then
 142         AC_MSG_RESULT(yes)
 143         AC_DEFINE([INTERNAL_DOWNLOAD], , [Use internal download library])
 144         # Check for a download library if it was actually requested
 145         AC_CHECK_LIB([fetch], [fetchParseURL], ,
 146                 AC_MSG_ERROR([libfetch is needed to compile with internal download support]) )
 147 else
 148         AC_MSG_RESULT(no)
 149 fi
 150 AM_CONDITIONAL(INTERNAL_DOWNLOAD, test "x$internaldownload" = "xyes")
 151
 152 # Checks for header files.
 153 AC_CHECK_HEADERS([fcntl.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/param.h sys/statvfs.h sys/syslimits.h sys/time.h syslog.h wchar.h])
 154
 155 # Checks for typedefs, structures, and compiler characteristics.
 156 AC_C_INLINE
 157 AC_TYPE_MODE_T
 158 AC_TYPE_OFF_T
 159 AC_TYPE_PID_T
 160 AC_TYPE_SIZE_T
 161 AC_STRUCT_TM
 162 AC_TYPE_UID_T
 163
 164 # Checks for library functions.
 165 AC_FUNC_FORK
 166 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 167 AC_FUNC_MKTIME
 168 AC_TYPE_SIGNAL
 169 AC_CHECK_FUNCS([geteuid realpath regcomp strcasecmp \
 170                 strndup strrchr strsep swprintf \
 171                 wcwidth uname])
 172
 173 # Enable large file support if available
 174 AC_SYS_LARGEFILE
 175
 176 # Check if we can use symbol visibility support in GCC
 177 GCC_VISIBILITY_CC
 178 # Check if we have -fgnu89-inline flag
 179 GCC_GNU89_INLINE_CC
 180
 181 # Host-dependant definitions
 182 SIZECMD="stat -c %s"
 183 case "${host_os}" in
 184         *bsd*)
 185                 SIZECMD="stat -f %z"
 186                 ;;
 187         cygwin*)
 188                 host_os_cygwin=yes
 189                 CFLAGS="$CFLAGS -DCYGWIN"
 190                 ;;
 191         darwin*)
 192                 host_os_darwin=yes
 193                 SIZECMD="/usr/bin/stat -f %z"
 194                 ;;
 195 esac
 196
 197 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 198 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 199 AC_SUBST(SIZECMD)
 200
 201 # Check for architecture, used in default makepkg.conf
 202 # (Note single space left after CARCHFLAGS)
 203 case "${host}" in
 204         i686-*)
 205                 CARCH="i686"
 206                 CARCHFLAGS="-march=i686 "
 207                 ;;
 208         x86_64-*)
 209                 CARCH="x86_64"
 210                 CARCHFLAGS="-march=x86-64 "
 211                 ;;
 212         ia64-*)
 213                 CARCH="ia64"
 214                 CARCHFLAGS="-march=ia64 "
 215                 ;;
 216         sparc-*)
 217                 CARCH="sparc"
 218                 CARCHFLAGS="-mcpu=v9 "
 219                 ;;
 220         ppc-* | powerpc-*)
 221                 CARCH="ppc"
 222                 CARCHFLAGS="-mcpu=750 "
 223                 ;;
 224         i386-*)
 225                 CARCH="i386"
 226                 CARCHFLAGS="-march=i386 "
 227                 ;;
 228         arm-*)
 229                 CARCH="arm"
 230                 CARCHFLAGS="-march=armv4 "
 231                 ;;
 232         *)
 233                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 234                 CARCH="unknown"
 235                 CARCHFLAGS=""
 236                 ;;
 237 esac
 238
 239 # Now do some things common to all architectures
 240 CHOST="${host}"
 241 AC_SUBST(CARCH)
 242 AC_SUBST(CARCHFLAGS)
 243 AC_SUBST(CHOST)
 244
 245 # Check for documentation support and status
 246 AC_MSG_CHECKING([for building documentation])
 247 if test "x$wantdoc" = "xyes" ; then
 248         AC_MSG_RESULT([yes])
 249         wantdoc=yes
 250 else
 251         AC_MSG_RESULT([no, disabled by configure])
 252         wantdoc=no
 253 fi
 254 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 255
 256 # Check for doxygen support and status
 257 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 258 AC_MSG_CHECKING([for doxygen])
 259 if test "x$wantdoxygen" = "xyes" ; then
 260         if test $DOXYGEN ; then
 261                 AC_MSG_RESULT([yes])
 262                 usedoxygen=yes
 263         else
 264                 AC_MSG_RESULT([no, doxygen missing])
 265                 usedoxygen=no
 266         fi
 267 else
 268         AC_MSG_RESULT([no, disabled by configure])
 269         usedoxygen=no
 270 fi
 271 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 272
 273 # Enable or disable debug code
 274 AC_MSG_CHECKING(for debug mode request)
 275 if test "x$debug" = "xyes" ; then
 276         AC_MSG_RESULT(yes)
 277         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 278         # Check for mcheck
 279         AC_CHECK_HEADERS([mcheck.h])
 280         # Check for -fstack-protector availability
 281         GCC_STACK_PROTECT_LIB
 282         GCC_STACK_PROTECT_CC
 283         CFLAGS="$CFLAGS -Wall -Werror"
 284 else
 285         AC_MSG_RESULT(no)
 286         CFLAGS="$CFLAGS -Wall"
 287 fi
 288
 289 # Enable or disable use of git version in pacman version string
 290 AC_CHECK_PROGS([GIT], [git])
 291 AC_CHECK_FILE([.git/], hasgitdir=yes)
 292 AC_MSG_CHECKING(whether to use git version if available)
 293 if test "x$wantgitver" = "xyes" ; then
 294         if test $GIT -a "x$hasgitdir" = "xyes"; then
 295                 AC_MSG_RESULT([yes])
 296                 usegitver=yes
 297                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 298         else
 299                 AC_MSG_RESULT([no, git or .git dir missing])
 300                 usegitver=no
 301         fi
 302 else
 303         AC_MSG_RESULT([no, disabled by configure])
 304         usegitver=no
 305 fi
 306 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 307
 308 # Set root directory
 309 AC_SUBST(ROOTDIR)
 310 # Set package file extension
 311 AC_SUBST(PKGEXT)
 312 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 313 # Set source package file extension
 314 AC_SUBST(SRCEXT)
 315 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 316 # Set database file extension
 317 AC_SUBST(DBEXT)
 318 AC_DEFINE_UNQUOTED([DBEXT], "$DBEXT", [The file extension used by pacman databases])
 319 # Set makepkg build script name
 320 AC_SUBST(BUILDSCRIPT)
 321 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 322
 323 # Configuration files
 324 AC_CONFIG_FILES([
 325 lib/libalpm/Makefile
 326 lib/libalpm/po/Makefile.in
 327 src/pacman/Makefile
 328 src/util/Makefile
 329 scripts/Makefile
 330 doc/Makefile
 331 etc/Makefile
 332 po/Makefile.in
 333 pactest/Makefile
 334 pactest/tests/Makefile
 335 contrib/Makefile
 336 Makefile
 337 ])
 338 AC_OUTPUT
 339
 340 echo "
 341 ${PACKAGE_NAME}:
 342
 343   Build information:
 344     source code location   : ${srcdir}
 345     prefix                 : ${prefix}
 346     sysconfdir             : $(eval echo ${sysconfdir})
 347        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 348     localstatedir          : $(eval echo ${localstatedir})
 349        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 350        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 351     compiler               : ${CC}
 352     compiler flags         : ${CFLAGS}
 353     defines                : ${DEFS}
 354
 355     Architecture           : ${CARCH}
 356     Architecture flags     : ${CARCHFLAGS}
 357     Host Type              : ${CHOST}
 358     Filesize command       : ${SIZECMD}
 359
 360     libalpm version        : ${LIB_VERSION}
 361     libalpm version info   : ${LIB_VERSION_INFO}
 362     pacman version         : ${PACKAGE_VERSION}
 363     using git version      : ${usegitver}
 364
 365   Directory and file information:
 366     root working directory : ${ROOTDIR}
 367     package extension      : ${PKGEXT}
 368     source pkg extension   : ${SRCEXT}
 369     database extension     : ${DBEXT}
 370     build script name      : ${BUILDSCRIPT}
 371
 372   Compilation options:
 373     Run make in doc/ dir   : ${wantdoc}
 374     Use download library   : ${internaldownload}
 375     Doxygen support        : ${usedoxygen}
 376     debug support          : ${debug}
 377 "
 378
 379 # vim:set ts=2 sw=2 noet: