configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.60)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43 #
  44 #   pacman_version_suffix should be similar to one of the following:
  45 #     For beta releases:          [beta2]
  46 #     For code under development: [devel]
  47 #     For production releases:    []
  48
  49 m4_define([lib_current], [5])
  50 m4_define([lib_revision], [1])
  51 m4_define([lib_age], [3])
  52
  53 m4_define([pacman_version_major], [3])
  54 m4_define([pacman_version_minor], [2])
  55 m4_define([pacman_version_micro], [0])
  56 m4_define([pacman_version_suffix], [devel])
  57 m4_define([pacman_version],
  58           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  59 m4_define([pacman_display_version],
  60                                         pacman_version[]m4_ifdef([pacman_version_suffix],[pacman_version_suffix]))
  61
  62 # Autoconf initialization
  63 AC_INIT([Pacman Package Manager], [pacman_display_version],
  64         [pacman-dev@archlinux.org], [pacman])
  65 AC_CONFIG_SRCDIR([config.h.in])
  66 AC_CONFIG_HEADERS([config.h])
  67
  68 AC_CANONICAL_HOST
  69 AM_INIT_AUTOMAKE
  70
  71 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  72 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  73
  74 # Set subsitution values for version stuff in Makefiles and anywhere else,
  75 # and put LIB_VERSION in config.h
  76 AC_SUBST(LIB_VERSION)
  77 AC_SUBST(LIB_VERSION_INFO)
  78 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  79
  80 # Help line for root directory
  81 AC_ARG_WITH(root-dir,
  82         AS_HELP_STRING([--with-root-dir=path], [set the location of pacman's root operating directory]),
  83         [ROOTDIR=$withval], [ROOTDIR=/])
  84
  85 # Help line for package extension
  86 AC_ARG_WITH(pkg-ext,
  87         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  88         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  89
  90 # Help line for source package directory
  91 AC_ARG_WITH(src-ext,
  92         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  93         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  94
  95 # Help line for database extension
  96 AC_ARG_WITH(db-ext,
  97         AS_HELP_STRING([--with-db-ext=ext], [set the file extension used by the database]),
  98         [DBEXT=$withval], [DBEXT=.db.tar.gz])
  99
 100 # Help line for libdownload/libfetch
 101 AC_ARG_ENABLE(internal-download,
 102         AS_HELP_STRING([--disable-internal-download], [do not build with libdownload/libfetch support]),
 103         [internaldownload=$enableval], [internaldownload=yes])
 104
 105 # Help line for documentation
 106 AC_ARG_ENABLE(doc,
 107         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 108         [wantdoc=$enableval], [wantdoc=yes])
 109
 110 # Help line for doxygen
 111 AC_ARG_ENABLE(doxygen,
 112         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 113         [wantdoxygen=$enableval], [wantdoxygen=no])
 114
 115 # Help line for asciidoc
 116 AC_ARG_ENABLE(asciidoc,
 117         AS_HELP_STRING([--enable-asciidoc], [build your own manpages with Asciidoc]),
 118         [wantasciidoc=$enableval], [wantasciidoc=no])
 119
 120 # Help line for debug
 121 AC_ARG_ENABLE(debug,
 122         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 123         [debug=$enableval], [debug=no])
 124
 125 # Help line for pacman.static
 126 AC_ARG_ENABLE(pacman-static,
 127         AS_HELP_STRING([--disable-pacman-static], [do not build static version of pacman]),
 128         [pacmanstatic=$enableval], [pacmanstatic=yes])
 129
 130 # Checks for programs.
 131 AC_PROG_AWK
 132 AC_PROG_CC_C99
 133 AC_PROG_INSTALL
 134 AC_PROG_LN_S
 135 AC_PROG_MAKE_SET
 136 AC_PROG_LIBTOOL
 137 AC_CHECK_PROGS([PYTHON], [python2.5 python2.4 python], [false])
 138
 139 # find installed gettext
 140 AM_GNU_GETTEXT([external])
 141 AM_GNU_GETTEXT_VERSION(0.13.1)
 142
 143 # Check for libarchive
 144 AC_CHECK_LIB([archive], [archive_read_data], ,
 145         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 146
 147 # Enable or disable usage of libdownload/libfetch
 148 # - this is a nested check- first see if we need a library, if we do then
 149 #   check for libdownload first, then fallback to libfetch, then die
 150 AC_MSG_CHECKING(whether to link with download library)
 151 if test "x$internaldownload" = "xyes" ; then
 152         AC_MSG_RESULT(yes)
 153         AC_DEFINE([INTERNAL_DOWNLOAD], , [Use internal download library])
 154         # Check for a download library if it was actually requested
 155         AC_CHECK_LIB([download], [downloadParseURL], ,
 156                 AC_CHECK_LIB([fetch], [fetchParseURL], ,
 157                         AC_MSG_ERROR([libdownload or libfetch are needed to compile with internal download support])) )
 158 else
 159         AC_MSG_RESULT(no)
 160 fi
 161 AM_CONDITIONAL(INTERNAL_DOWNLOAD, test "x$internaldownload" = "xyes")
 162
 163 # Checks for header files.
 164 AC_CHECK_HEADERS([fcntl.h libintl.h limits.h locale.h string.h strings.h sys/ioctl.h sys/param.h sys/statvfs.h sys/syslimits.h sys/time.h syslog.h wchar.h])
 165
 166 # Checks for typedefs, structures, and compiler characteristics.
 167 AC_C_INLINE
 168 AC_TYPE_MODE_T
 169 AC_TYPE_OFF_T
 170 AC_TYPE_PID_T
 171 AC_TYPE_SIZE_T
 172 AC_STRUCT_TM
 173 AC_TYPE_UID_T
 174
 175 # Checks for library functions.
 176 AC_FUNC_FORK
 177 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 178 AC_FUNC_MKTIME
 179 AC_TYPE_SIGNAL
 180 AC_CHECK_FUNCS([geteuid realpath regcomp strcasecmp \
 181                 strndup strrchr strsep strverscmp swprintf \
 182                 wcwidth uname])
 183
 184 # Enable large file support if available
 185 AC_SYS_LARGEFILE
 186
 187 # Check if we can use symbol visibility support in GCC
 188 GCC_VISIBILITY_CC
 189 # Check if we have -fgnu89-inline flag
 190 GCC_GNU89_INLINE_CC
 191
 192 # Host-dependant definitions
 193 case "${host_os}" in
 194         cygwin*)
 195                 host_os_cygwin=yes
 196                 CFLAGS="$CFLAGS -DCYGWIN"
 197                 ;;
 198         darwin*)
 199                 host_os_darwin=yes
 200                 ;;
 201 esac
 202
 203 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 204 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 205
 206 # Check for architecture, used in default makepkg.conf
 207 # (Note single space left after CARCHFLAGS)
 208 case "${host}" in
 209         i686-*)
 210                 CARCH="i686"
 211                 CARCHFLAGS="-march=i686 "
 212                 ;;
 213         x86_64-*)
 214                 CARCH="x86_64"
 215                 CARCHFLAGS="-march=x86-64 "
 216                 ;;
 217         ia64-*)
 218                 CARCH="ia64"
 219                 CARCHFLAGS="-march=ia64 "
 220                 ;;
 221         sparc-*)
 222                 CARCH="sparc"
 223                 CARCHFLAGS="-mcpu=v9 "
 224                 ;;
 225         ppc-* | powerpc-*)
 226                 CARCH="ppc"
 227                 CARCHFLAGS="-mcpu=750 "
 228                 ;;
 229         i386-*)
 230                 CARCH="i386"
 231                 CARCHFLAGS="-march=i386 "
 232                 ;;
 233         arm-*)
 234                 CARCH="arm"
 235                 CARCHFLAGS="-march=armv4 "
 236                 ;;
 237         *)
 238                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 239                 CARCH="unknown"
 240                 CARCHFLAGS=""
 241                 ;;
 242 esac
 243
 244 # Now do some things common to all architectures
 245 CHOST="${host}"
 246 AC_SUBST(CARCH)
 247 AC_SUBST(CARCHFLAGS)
 248 AC_SUBST(CHOST)
 249
 250 # Check for documentation support and status
 251 AC_MSG_CHECKING([for building documentation])
 252 if test "x$wantdoc" = "xyes" ; then
 253         AC_MSG_RESULT([yes])
 254         wantdoc=yes
 255 else
 256         AC_MSG_RESULT([no, disabled by configure])
 257         wantdoc=no
 258 fi
 259 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 260
 261 # Check for doxygen support and status
 262 AC_MSG_CHECKING([for doxygen])
 263 if test "x$wantdoxygen" = "xyes" ; then
 264         AC_CHECK_PROGS([DOXYGEN], [doxygen])
 265         if test $DOXYGEN ; then
 266                 AC_MSG_RESULT([yes])
 267                 usedoxygen=yes
 268         else
 269                 AC_MSG_RESULT([no, doxygen missing])
 270                 usedoxygen=no
 271         fi
 272 else
 273         AC_MSG_RESULT([no, disabled by configure])
 274         usedoxygen=no
 275 fi
 276 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 277
 278 # Check for asciidoc support and status
 279 AC_MSG_CHECKING([for asciidoc])
 280 if test "x$wantasciidoc" = "xyes" ; then
 281         AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 282         if test $ASCIIDOC ; then
 283                 AC_MSG_RESULT([yes])
 284                 useasciidoc=yes
 285         else
 286                 AC_MSG_RESULT([no, asciidoc missing])
 287                 useasciidoc=no
 288         fi
 289 else
 290         AC_MSG_RESULT([no, disabled by configure])
 291         useasciidoc=no
 292 fi
 293 AM_CONDITIONAL(USE_ASCIIDOC, test "x$useasciidoc" = "xyes")
 294
 295 # Enable or disable debug code
 296 AC_MSG_CHECKING(for debug mode request)
 297 if test "x$debug" = "xyes" ; then
 298         AC_MSG_RESULT(yes)
 299         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 300         # Check for mcheck
 301         AC_CHECK_HEADERS([mcheck.h])
 302         # Check for -fstack-protector availability
 303         GCC_STACK_PROTECT_LIB
 304         GCC_STACK_PROTECT_CC
 305         CFLAGS="$CFLAGS -Wall -Werror"
 306 else
 307         AC_MSG_RESULT(no)
 308         CFLAGS="$CFLAGS -Wall"
 309 fi
 310
 311 # Enable or disable inclusion of pacman.static
 312 AC_MSG_CHECKING(whether to build pacman.static)
 313 if test "x$pacmanstatic" = "xyes" ; then
 314         AC_MSG_RESULT(yes)
 315         AC_DEFINE([INCLUDE_PACMAN_STATIC], , [Build pacman.static])
 316 else
 317         AC_MSG_RESULT(no)
 318 fi
 319 AM_CONDITIONAL(INCLUDE_PACMAN_STATIC, test "x$pacmanstatic" = "xyes")
 320
 321 # Set root directory
 322 AC_SUBST(ROOTDIR)
 323 # Set package file extension
 324 AC_SUBST(PKGEXT)
 325 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 326 # Set source package file extension
 327 AC_SUBST(SRCEXT)
 328 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 329 # Set database file extension
 330 AC_SUBST(DBEXT)
 331 AC_DEFINE_UNQUOTED([DBEXT], "$DBEXT", [The file extension used by pacman databases])
 332
 333 # Configuration files
 334 AC_CONFIG_FILES([
 335 lib/libalpm/Makefile
 336 lib/libalpm/po/Makefile.in
 337 src/pacman/Makefile
 338 src/util/Makefile
 339 scripts/Makefile
 340 doc/Makefile
 341 etc/Makefile
 342 po/Makefile.in
 343 pactest/Makefile
 344 contrib/Makefile
 345 Makefile
 346 ])
 347 AC_OUTPUT
 348
 349 echo "
 350 pacman_display_version:
 351
 352   Build information:
 353     source code location   : ${srcdir}
 354     prefix                 : ${prefix}
 355     sysconfdir             : $(eval echo ${sysconfdir})
 356        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 357     localstatedir          : $(eval echo ${localstatedir})
 358        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 359        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 360     compiler               : ${CC}
 361     compiler flags         : ${CFLAGS}
 362     defines                : ${DEFS}
 363
 364     Architecture           : ${CARCH}
 365     Architecture flags     : ${CARCHFLAGS}
 366     Host Type              : ${CHOST}
 367
 368     libalpm version        : ${LIB_VERSION}
 369     libalpm version info   : ${LIB_VERSION_INFO}
 370     pacman version         : ${PACKAGE_VERSION}
 371
 372   Directory and file information:
 373     root working directory : ${ROOTDIR}
 374     package extension      : ${PKGEXT}
 375     source pkg extension   : ${SRCEXT}
 376     database extension     : ${DBEXT}
 377
 378   Compilation options:
 379     Run make in doc/ dir   : ${wantdoc}
 380     Use download library   : ${internaldownload}
 381     Doxygen support        : ${usedoxygen}
 382     Asciidoc support       : ${useasciidoc}
 383     debug support          : ${debug}
 384     build pacman.static    : ${pacmanstatic}
 385 "
 386
 387 # vim:set ts=2 sw=2 noet: