configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [6])
  45 m4_define([lib_revision], [1])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [5])
  50 m4_define([pacman_version_micro], [1])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for buildscript filename
  87 AC_ARG_WITH(buildscript,
  88         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  89         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  90
  91 # Help line for using OpenSSL
  92 AC_ARG_WITH(openssl,
  93         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  94         [], [with_openssl=check])
  95
  96 # Help line for libcurl
  97 AC_ARG_WITH(curl,
  98         AS_HELP_STRING([--with-curl], [use libcurl as an internal downloader]),
  99         [], [with_curl=check])
 100
 101 # Help line for documentation
 102 AC_ARG_ENABLE(doc,
 103         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 104         [wantdoc=$enableval], [wantdoc=yes])
 105
 106 # Help line for doxygen
 107 AC_ARG_ENABLE(doxygen,
 108         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 109         [wantdoxygen=$enableval], [wantdoxygen=no])
 110
 111 # Help line for debug
 112 AC_ARG_ENABLE(debug,
 113         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 114         [debug=$enableval], [debug=no])
 115
 116 # Help line for using git version in pacman version string
 117 AC_ARG_ENABLE(git-version,
 118         AS_HELP_STRING([--enable-git-version],
 119                 [enable use of git version in version string if available]),
 120         [wantgitver=$enableval], [wantgitver=no])
 121
 122 # Checks for programs.
 123 AC_PROG_AWK
 124 AC_PROG_CC_C99
 125 AC_PROG_INSTALL
 126 AC_PROG_LN_S
 127 AC_PROG_MAKE_SET
 128 AC_PROG_LIBTOOL
 129 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 130 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 131
 132 # find installed gettext
 133 AM_GNU_GETTEXT([external])
 134 AM_GNU_GETTEXT_VERSION(0.13.1)
 135
 136 # Check for libarchive
 137 AC_CHECK_LIB([archive], [archive_read_data], ,
 138         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 139
 140 # Check for OpenSSL
 141 AC_MSG_CHECKING(whether to link with libssl)
 142 AS_IF([test "x$with_openssl" != "xno"],
 143         [AC_MSG_RESULT(yes)
 144         AC_CHECK_LIB([ssl], [MD5_Final], ,
 145         [if test "x$with_openssl" != "xcheck"; then
 146                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 147         fi],
 148         [-lcrypto])],
 149         AC_MSG_RESULT(no))
 150 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$ac_cv_lib_ssl_MD5_Final" = "xyes"])
 151
 152 # Enable or disable usage of libcurl
 153 AC_MSG_CHECKING(whether to link with libcurl)
 154 AS_IF([test "x$with_curl" != "xno"],
 155         [AC_MSG_RESULT(yes)
 156         AC_CHECK_LIB([curl], [curl_easy_perform], ,
 157         [if test "x$with_curl" != "xcheck"; then
 158                 AC_MSG_FAILURE([--with-curl was given, but -lcurl was not found])
 159         fi],
 160         [-lcurl])],
 161         AC_MSG_RESULT(no))
 162 AM_CONDITIONAL([HAVE_LIBCURL], [test "x$ac_cv_lib_curl_curl_easy_perform" = "xyes"])
 163
 164 # Check for gpgme
 165 AC_CHECK_LIB([gpgme], [gpgme_check_version], ,
 166         AC_MSG_ERROR([gpgme is needed to compile pacman!]))
 167
 168 # Checks for header files.
 169 AC_CHECK_HEADERS([fcntl.h glob.h libintl.h locale.h mntent.h string.h \
 170                   sys/ioctl.h sys/mount.h sys/param.h sys/statvfs.h \
 171                   sys/time.h sys/types.h sys/ucred.h syslog.h wchar.h])
 172
 173 # Checks for typedefs, structures, and compiler characteristics.
 174 AC_C_INLINE
 175 AC_TYPE_MODE_T
 176 AC_TYPE_OFF_T
 177 AC_TYPE_PID_T
 178 AC_TYPE_SIZE_T
 179 AC_STRUCT_TM
 180 AC_TYPE_UID_T
 181 AC_STRUCT_DIRENT_D_TYPE
 182 PATH_MAX_DEFINED
 183
 184 # Checks for library functions.
 185 AC_FUNC_FORK
 186 AC_FUNC_GETMNTENT
 187 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 188 AC_FUNC_MKTIME
 189 AC_CHECK_FUNCS([geteuid getmntinfo realpath regcomp strcasecmp \
 190                 strndup strrchr strsep swprintf \
 191                 wcwidth uname])
 192 # For the diskspace code
 193 FS_STATS_TYPE
 194 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 195 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 196                   #include <sys/mount.h>]])
 197
 198 # Enable large file support if available
 199 AC_SYS_LARGEFILE
 200
 201 # Check if we can use symbol visibility support in GCC
 202 GCC_VISIBILITY_CC
 203 # Check if we have -fgnu89-inline flag
 204 GCC_GNU89_INLINE_CC
 205
 206 # Host-dependant definitions
 207 SIZECMD="stat -L -c %s"
 208 SEDINPLACE="sed -i"
 209 STRIP_BINARIES="--strip-all"
 210 STRIP_SHARED="--strip-unneeded"
 211 STRIP_STATIC="--strip-debug"
 212 case "${host_os}" in
 213         *bsd*)
 214                 SIZECMD="stat -L -f %z"
 215                 SEDINPLACE="sed -i ''"
 216                 ;;
 217         cygwin*)
 218                 host_os_cygwin=yes
 219                 CFLAGS="$CFLAGS -DCYGWIN"
 220                 ;;
 221         darwin*)
 222                 host_os_darwin=yes
 223                 SIZECMD="/usr/bin/stat -L -f %z"
 224                 SEDINPLACE="/usr/bin/sed -i ''"
 225                 STRIP_BINARIES=""
 226                 STRIP_SHARED="-S"
 227                 STRIP_STATIC="-S"
 228                 ;;
 229 esac
 230
 231 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 232 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 233 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 234 AC_SUBST(SIZECMD)
 235 AC_SUBST(SEDINPLACE)
 236 AC_SUBST(STRIP_BINARIES)
 237 AC_SUBST(STRIP_SHARED)
 238 AC_SUBST(STRIP_STATIC)
 239
 240 # Check for architecture, used in default makepkg.conf
 241 # (Note single space left after CARCHFLAGS)
 242 case "${host}" in
 243         i686-*)
 244                 CARCH="i686"
 245                 CARCHFLAGS="-march=i686 "
 246                 ;;
 247         x86_64-*)
 248                 CARCH="x86_64"
 249                 CARCHFLAGS="-march=x86-64 "
 250                 ;;
 251         ia64-*)
 252                 CARCH="ia64"
 253                 CARCHFLAGS="-march=ia64 "
 254                 ;;
 255         sparc-*)
 256                 CARCH="sparc"
 257                 CARCHFLAGS="-mcpu=v9 "
 258                 ;;
 259         ppc-* | powerpc-*)
 260                 CARCH="ppc"
 261                 CARCHFLAGS="-mcpu=750 "
 262                 ;;
 263         i386-*)
 264                 CARCH="i386"
 265                 CARCHFLAGS="-march=i386 "
 266                 ;;
 267         arm-*)
 268                 CARCH="arm"
 269                 CARCHFLAGS="-march=armv4 "
 270                 ;;
 271         *)
 272                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 273                 CARCH="unknown"
 274                 CARCHFLAGS=""
 275                 ;;
 276 esac
 277
 278 # Now do some things common to all architectures
 279 CHOST="${host}"
 280 AC_SUBST(CARCH)
 281 AC_SUBST(CARCHFLAGS)
 282 AC_SUBST(CHOST)
 283
 284 # Check for documentation support and status
 285 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 286 AC_MSG_CHECKING([for building documentation])
 287 if test "x$wantdoc" = "xyes" ; then
 288         if test $ASCIIDOC ; then
 289                 AC_MSG_RESULT([yes, enabled by configure])
 290         else
 291                 asciidoc="(warning : asciidoc not installed)"
 292                 AC_MSG_RESULT([yes $asciidoc])
 293         fi
 294         wantdoc=yes
 295 else
 296         AC_MSG_RESULT([no, disabled by configure])
 297         wantdoc=no
 298 fi
 299 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 300
 301 # Check for doxygen support and status
 302 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 303 AC_MSG_CHECKING([for doxygen])
 304 if test "x$wantdoxygen" = "xyes" ; then
 305         if test $DOXYGEN ; then
 306                 AC_MSG_RESULT([yes])
 307                 usedoxygen=yes
 308         else
 309                 AC_MSG_RESULT([no, doxygen missing])
 310                 usedoxygen=no
 311         fi
 312 else
 313         AC_MSG_RESULT([no, disabled by configure])
 314         usedoxygen=no
 315 fi
 316 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 317
 318 # Enable or disable debug code
 319 AC_MSG_CHECKING(for debug mode request)
 320 if test "x$debug" = "xyes" ; then
 321         AC_MSG_RESULT(yes)
 322         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 323         # Check for mcheck
 324         AC_CHECK_HEADERS([mcheck.h])
 325         # Check for -fstack-protector availability
 326         GCC_STACK_PROTECT_LIB
 327         GCC_STACK_PROTECT_CC
 328         GCC_FORTIFY_SOURCE_CC
 329         CFLAGS="$CFLAGS -g -Wall -Werror"
 330 else
 331         AC_MSG_RESULT(no)
 332         CFLAGS="$CFLAGS -Wall"
 333 fi
 334
 335 # Enable or disable use of git version in pacman version string
 336 AC_MSG_CHECKING(whether to use git version if available)
 337 if test "x$wantgitver" = "xyes" ; then
 338         AC_CHECK_PROGS([GIT], [git])
 339         AC_CHECK_FILE([.git/], hasgitdir=yes)
 340         if test $GIT -a "x$hasgitdir" = "xyes"; then
 341                 AC_MSG_RESULT([yes])
 342                 usegitver=yes
 343                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 344         else
 345                 AC_MSG_RESULT([no, git or .git dir missing])
 346                 usegitver=no
 347         fi
 348 else
 349         AC_MSG_RESULT([no, disabled by configure])
 350         usegitver=no
 351 fi
 352 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 353
 354 # Set root directory
 355 AC_SUBST(ROOTDIR)
 356 # Set package file extension
 357 AC_SUBST(PKGEXT)
 358 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 359 # Set source package file extension
 360 AC_SUBST(SRCEXT)
 361 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 362 # Set makepkg build script name
 363 AC_SUBST(BUILDSCRIPT)
 364 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 365
 366 # Configuration files
 367 AC_CONFIG_FILES([
 368 lib/libalpm/Makefile
 369 lib/libalpm/po/Makefile.in
 370 src/pacman/Makefile
 371 src/util/Makefile
 372 scripts/Makefile
 373 doc/Makefile
 374 etc/Makefile
 375 po/Makefile.in
 376 test/pacman/Makefile
 377 test/pacman/tests/Makefile
 378 test/util/Makefile
 379 contrib/Makefile
 380 Makefile
 381 ])
 382 AC_OUTPUT
 383
 384 echo "
 385 ${PACKAGE_NAME}:
 386
 387   Build information:
 388     source code location   : ${srcdir}
 389     prefix                 : ${prefix}
 390     sysconfdir             : $(eval echo ${sysconfdir})
 391        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 392     localstatedir          : $(eval echo ${localstatedir})
 393        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 394        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 395     compiler               : ${CC}
 396     compiler flags         : ${CFLAGS}
 397     defines                : ${DEFS}
 398
 399     Architecture           : ${CARCH}
 400     Architecture flags     : ${CARCHFLAGS}
 401     Host Type              : ${CHOST}
 402     Filesize command       : ${SIZECMD}
 403     In-place sed command   : ${SEDINPLACE}
 404
 405     libalpm version        : ${LIB_VERSION}
 406     libalpm version info   : ${LIB_VERSION_INFO}
 407     pacman version         : ${PACKAGE_VERSION}
 408     using git version      : ${usegitver}
 409
 410   Directory and file information:
 411     root working directory : ${ROOTDIR}
 412     package extension      : ${PKGEXT}
 413     source pkg extension   : ${SRCEXT}
 414     build script name      : ${BUILDSCRIPT}
 415
 416   Compilation options:
 417     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 418     Doxygen support        : ${usedoxygen}
 419     debug support          : ${debug}
 420 "
 421
 422 # vim:set ts=2 sw=2 noet: